blob: 3b70ad1c5ae12875a4e001a8a5947f3fdf21f871 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
|
set term qt persist
set title ARG1
exp_keff=real(system("cat results/explicit.out | grep 'Combined k-effective' | cut -d '=' -f 2 | cut -d '+' -f 1 | sed 's/ //g'"))
exp_pm=real(system("cat results/explicit.out | grep 'Combined k-effective' | cut -d '=' -f 2 | cut -d '-' -f 2 | sed 's/ //g'"))
exp_ppm=exp_keff+exp_pm
exp_mpm=exp_keff-exp_pm
vwh_keff=real(system("cat results/vwh.out | grep 'Combined k-effective' | cut -d '=' -f 2 | cut -d '+' -f 1 | sed 's/ //g'"))
vwh_pm=real(system("cat results/vwh.out | grep 'Combined k-effective' | cut -d '=' -f 2 | cut -d '-' -f 2 | sed 's/ //g'"))
vwh_ppm=vwh_keff+vwh_pm
vwh_mpm=vwh_keff-vwh_pm
set arrow from graph 0, first exp_keff to graph 1, first exp_keff nohead front lc rgb "red" dt 2
set arrow from graph 0, first vwh_keff to graph 1, first vwh_keff nohead front lc rgb "blue" dt 2
set object 1 rectangle from graph 0, first exp_mpm to graph 1, first exp_ppm back fc rgb "red" fillstyle pattern 4 noborder
set object 2 rectangle from graph 0, first vwh_mpm to graph 1, first vwh_ppm back fc rgb "blue" fillstyle pattern 4 noborder
if (ARG1 eq "uo2") {
set yrange [1.36:1.5]
}
if (ARG1 eq "uc010") {
set yrange [1.5:1.64]
}
if (ARG1 eq "uco20") {
set yrange [1.55:1.72]
}
if (ARG1 eq "un") {
set yrange [0.68:0.82]
}
set format y "%.5f"
set style fill pattern 4 noborder
set ylabel "k_{eff}"
set xlabel "RPT/RRPT Radius [cm]"
plot "results/rpt_table" using 1:2:3 with yerrorlines pt 0 dt 2 title "RPT K_{eff}", \
"results/rrpt_table" using 1:2:3 with yerrorlines pt 0 dt 2 title "RRPT K_{eff}", \
keyentry with lines title "Explicit K_{eff}" lc rgb "red" dt 2, \
keyentry with lines title "VWH K_{eff}" lc rgb "blue" dt 2
|
