blob: 6eb0f8f46e1480d698ab8ac892b6bd122ccaaee3 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
|
*----
* TEST CASE TCWU12
* WLUP JEFF3.1 XMAS Library
* GENERATE A LIBRARY USING INFO AND OTHER OPTIONS
*
* REF: None
*
*----
* Define variables and initialize
* Coolant properties
* a) Input
* TempCool = Coolant temperature (K)
* Purity = D2/(D2+H1) Weight % ratio in Coolant
* b) Output
* DensCool = Coolant Density (g/cm**3)
* WH1C = H1 Weight % in Coolant
* WD2C = D2 Weight % in Coolant
* WO16C = O16 Weight % in Coolant
* Fuel properties
* a) Input
* TempFuel = Fuel temperature (K)
* Enrichment = U235/(U235+U238) Weight % ratio in Fuel
* DensFuel = Fuel Density (g/cm**3)
* b) Output
* WU235F = U235 Weight % in Fuel
* WU238F = U238 Weight % in Fuel
* WO16F = O16 Weight % in Fuel
*----
REAL
TempCool Purity TempFuel Enrichment DensFuel :=
560.66 99.95 941.29 0.72 10.437501 ;
REAL
WH1C WD2C WO16C DensCool
WU235F WU238F WO16F ;
*----
* Define STRUCTURES and MODULES used
*----
LINKED_LIST
LIBRARY ISOT ;
MODULE
LIB: INFO: END: ;
PROCEDURE assertS ;
*----
* Get Coolant properties
*----
ECHO
"Input - Coolant temperature (K) " TempCool ;
ECHO
"Input - D2/(D2+H1) Weight % ratio in Coolant" Purity ;
INFO: ::
TMP: <<TempCool>> K
PUR: <<Purity>> WGT%
CALC DENS WATER >>DensCool<<
LIB: WIMSD4 FIL: WLUP172
ISO: 3 '3001' '3002' '6016'
CALC WGT% D2O >>WH1C<< >>WD2C<< >>WO16C<<
;
ECHO
"Output - Coolant Density (g/cm**3)" DensCool ;
ECHO
"Output - H1 Weight % in Coolant " WH1C ;
ECHO
"Output - D2 Weight % in Coolant " WD2C ;
ECHO
"Output - O16 Weight % in Coolant " WO16C ;
*----
* Get Fuel properties
*----
ECHO
"Input - Fuel temperature (K) " TempFuel ;
ECHO
"Input - U235/(U235+U238) Weight % ratio in Fuel" Enrichment ;
ECHO
"Input - Fuel Density (g/cm**3) " DensFuel ;
INFO: ::
ENR: <<Enrichment>> WGT%
LIB: WIMSD4 FIL: WLUP172
ISO: 3 '2235' '8238' '6016'
CALC WGT% UO2 >>WU235F<< >>WU238F<< >>WO16F<<
;
ECHO
"Output - U235 Weight % in Fuel" WU235F ;
ECHO
"Output - U238 Weight % in Fuel" WU238F ;
ECHO
"Output - O16 Weight % in Fuel " WO16F ;
*----
* Microscopic cross sections from file WLUP172 format WIMSD4
*----
LIBRARY := LIB: ::
NMIX 5 CTRA WIMS
MIXS LIB: WIMSD4 FIL: WLUP172
MIX 1 <<TempCool>> <<DensCool>> O16 = '6016' <<WO16C>>
D2D2O = '3002' <<WD2C>> H1H2O = '3001' <<WH1C>>
MIX 2 <<TempFuel>> <<DensCool>> O16 = '6016' <<WO16C>>
D2D2O = '3002' <<WD2C>> H1H2O = '3001' <<WH1C>>
MIX 3 <<TempFuel>> <<DensFuel>> O16 = '6016' <<WO16F>>
U235 = '2235' <<WU235F>> 1
U238 = '8238' <<WU238F>> 1
MIX 4 COMB 2 0.5 0 0.5
MIX 5 COMB 3 0.1 3 0.9
;
ISOT := LIBRARY :: STEP UP ISOTOPESLIST STEP AT 15 ; (*U238 0005*)
assertS ISOT :: NG 35 2.234762E-01 ;
ECHO "test TCWU12 completed" ;
END: ;
QUIT "LIST" .
|
