1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
|
*DECK NXTLHT
FUNCTION NXTLHT(IPRINT,ITST ,NDIM ,MXMESH,LINMAX,
> MESH ,ORITRK,DIRTRK,DCMESH,TRKLIM,
> NBCOR ,NBSINT,ISINT ,TRKLSI)
*
*----------
*
*Purpose:
* To track a triangular hexagon in 2-D or 3-D geometry
* using the NXT tracking procedure.
*
*Copyright:
* Copyright (C) 2010 Ecole Polytechnique de Montreal
* This library is free software; you can redistribute it and/or
* modify it under the terms of the GNU Lesser General Public
* License as published by the Free Software Foundation; either
* version 2.1 of the License, or (at your option) any later version.
*
*Author(s): G. Marleau.
*
*Parameters: input
* IPRINT print level.
* ITST type of tracking, where:
* =-1 only the exact geometry
* is considered taking into account the
* submesh in each direction;
* = 0 only the global geometry
* is considered without taking into account the
* submesh in each direction;
* = 1 both the global
* geometry (as a first step) and the exact geometry
* are considered taking into account the
* submesh in each direction.
* NDIM dimension of problem.
* MXMESH maximum number of spatial subdivision in
* $U$, $V$, $Z$ and $W$.
* LINMAX maximum number of segments in a track.
* MESH effective number of spatial subdivision in
* each direction ($U$, $W$, $Z$ and $W$).
* ORITRK a point on the track (origin). The triangular hexagon is
* assumed centered at the origin.
* DIRTRK the track direction (director cosines).
* DCMESH spatial description of the triangular hexagon.
* TRKLIM beginning and end of track in this cell.
*
*Parameters: output
* NXTLHT number of side intersections.
* NBCOR number of corner found for each external faces.
* NBSINT number of surface crossed by track.
* ISINT direction of plane intersected and
* the surfaces crossed by the track.
* TRKLSI the surface intersection distance.
*
*Reference:
* G. Marleau,
* New Geometries Processing in DRAGON: The NXT: Module,
* Report IGE-260, Polytechnique Montreal,
* Montreal, 2005.
*
*----------
*
IMPLICIT NONE
*----
* Subroutine arguments
*----
INTEGER IPRINT,ITST,NDIM,MXMESH,LINMAX
INTEGER MESH(NDIM)
DOUBLE PRECISION ORITRK(NDIM),DIRTRK(NDIM),
> DCMESH(-1:MXMESH,5),TRKLIM(2)
INTEGER NBCOR(2),NBSINT
INTEGER ISINT(0:5,LINMAX)
DOUBLE PRECISION TRKLSI(LINMAX)
INTEGER NXTLHT
*----
* Local parameters
*----
INTEGER IOUT
CHARACTER NAMSBR*6
PARAMETER (IOUT=6,NAMSBR='NXTLHT')
DOUBLE PRECISION DCUTOF,DZERO,DONE
PARAMETER (DCUTOF=1.0D-9,DZERO=0.0D0,DONE=1.0D0)
*----
* Local variables
*----
INTEGER ITC,IEL,KDIR,IDIR,IFRST,ILAST,INEXT(5),IFACE,
> ISF(5),ISL(5),KEL,JEL,IDIRS,MESHL(5)
DOUBLE PRECISION DEP,SLP,TRKDIS,DISF,DISL
DOUBLE PRECISION XXX,YYY
*----
* Data
*----
CHARACTER CDIR(5)*1
DOUBLE PRECISION VNORMD(3,5)
SAVE CDIR,VNORMD
DATA CDIR /'U','V','Z','R','W'/
DATA VNORMD /
> 1.0D0,0.0D0 ,0.0D0,
> 0.5D0,0.866025403784439D0 ,0.0D0,
> 0.0D0,0.0D0 ,1.0D0,
> 1.0D0,0.0D0 ,0.0D0,
> 0.5D0,-0.866025403784439D0,0.0D0/
*----
* Verify ITST option and reset to default value if invalid
*----
IF(ITST .LT. -1 .OR. ITST .GT. 1) THEN
*----
* Reset ITST=1 (complete analysis) if the value of ITST is invalid
*----
ITST=1
ENDIF
*----
* Initialise output vectors
*----
NBCOR(1)=0
NBCOR(2)=0
MESHL(1)=MESH(1)
MESHL(2)=MESH(1)
MESHL(3)=MESH(3)
MESHL(5)=MESH(1)
DISF=0.0D0
DISL=0.0D0
ISINT(0:5,:LINMAX)=0
TRKLSI(:LINMAX)=DZERO
*----
* U,V and W MESH identical
*----
DO ITC=0,MESH(1)
DCMESH(ITC,2)=DCMESH(ITC,1)
DCMESH(ITC,5)=DCMESH(ITC,1)
ENDDO
*----
* Print header if required
*----
IF(IPRINT .GE. 100) THEN
WRITE(IOUT,6000) NAMSBR
WRITE(IOUT,6011) 'mesh'//CDIR(1)//'={ '
WRITE(IOUT,6012) (DCMESH(ITC,1),ITC=0,MESHL(1))
WRITE(IOUT,6013)
WRITE(IOUT,6011) 'mesh'//CDIR(2)//'={ '
WRITE(IOUT,6012) (DCMESH(ITC,2),ITC=0,MESHL(2))
WRITE(IOUT,6013)
WRITE(IOUT,6011) 'mesh'//CDIR(5)//'={ '
WRITE(IOUT,6012) (DCMESH(ITC,5),ITC=0,MESHL(5))
WRITE(IOUT,6013)
IF(NDIM .EQ. 3) THEN
WRITE(IOUT,6011) 'mesh'//CDIR(3)//'={ '
WRITE(IOUT,6012) (DCMESH(ITC,3),ITC=0,MESHL(3))
WRITE(IOUT,6013)
ENDIF
WRITE(IOUT,6016) 'Htrackorigin={ '
WRITE(IOUT,6012) ORITRK
WRITE(IOUT,6013)
WRITE(IOUT,6016) 'Htrackdirection={ '
WRITE(IOUT,6012) DIRTRK
WRITE(IOUT,6013)
ENDIF
* write(6,*) 'TRKLIM = ',TRKLIM(1),TRKLIM(2)
*----
* Scan over directions
*----
IEL=0
DO IDIR=1,5
ISF(IDIR)=0
ISL(IDIR)=0
IF(IDIR .EQ. 4) GO TO 100
DEP=DZERO
SLP=DZERO
DO ITC=1,3
DEP=DEP+ORITRK(ITC)*VNORMD(ITC,IDIR)
SLP=SLP+DIRTRK(ITC)*VNORMD(ITC,IDIR)
ENDDO
IF(IDIR .EQ. 3 .AND. NDIM .NE. 3) GO TO 100
*----
* Select planes order in direction IDIR (forward or backward)
*----
IF(SLP .LT. 0) THEN
INEXT(IDIR)=-1
IFRST=MESHL(IDIR)+1
ILAST=1
ELSE
INEXT(IDIR)=1
IFRST=1
ILAST=MESHL(IDIR)+1
ENDIF
*----
* Scan over planes in direction IDIR
*----
* write(6,'(A10,5X,4I10,2F20.10)')' Direction=',IDIR,IFRST,ILAST,
* > INEXT(IDIR),DEP,SLP
DO IFACE=IFRST,ILAST,INEXT(IDIR)
*----
* Compute track length required to reach a face
*----
IF(ABS(SLP) .LT. DCUTOF) CALL XABORT(NAMSBR//
> ': line parallel to face not yet programmed')
TRKDIS=(DCMESH(IFACE-1,IDIR)-DEP)/SLP
XXX=ABS(TRKLIM(1)-TRKDIS)
YYY=ABS(TRKLIM(2)-TRKDIS)
* write(6,'(A10,I10,4F20.10)')
* > 'Face ',IFACE,DCMESH(IFACE-1,IDIR),TRKDIS,XXX,YYY
*----
* Store point only if it is inside cell
*----
IF(XXX .LT. DCUTOF .OR. YYY .LT. DCUTOF) THEN
* write(6,*) 'Intersection at ',TRKDIS,' for outer face'
KEL=IEL
DO JEL=1,IEL
IF(TRKDIS .LT. TRKLSI(JEL)) THEN
DO KEL=IEL,JEL,-1
TRKLSI(KEL+1)=TRKLSI(KEL)
DO ITC=0,5
ISINT(ITC,KEL+1)=ISINT(ITC,KEL)
ISINT(ITC,KEL)=0
ENDDO
ENDDO
KEL=JEL-1
GO TO 111
ENDIF
ENDDO
111 CONTINUE
TRKLSI(KEL+1)=TRKDIS
ISINT(0,KEL+1)=INEXT(IDIR)*IDIR
ISINT(IDIR,KEL+1)=IFACE
* write(6,*) KEL+1,ISINT(0,KEL+1),ISINT(IDIR,KEL+1)
IEL=IEL+1
ELSE IF(TRKDIS .LT. TRKLIM(1) ) THEN
*----
*GMC Corriger pour direction de la ligne
*----
IF(ISF(IDIR) .EQ. 0) THEN
ISF(IDIR)=IFACE+MIN(INEXT(IDIR),0)
DISF=TRKDIS
ELSE IF(TRKDIS .GT. DISF) THEN
ISF(IDIR)=IFACE+MIN(INEXT(IDIR),0)
DISF=TRKDIS
ENDIF
* write(6,*) 'Before 1 ',ISF(IDIR),DISF
ELSE IF(TRKDIS .GT. TRKLIM(2) ) THEN
*----
*GMC Corriger pour direction de la ligne
*----
IF(ISL(IDIR) .EQ. 0) THEN
ISL(IDIR)=IFACE-MAX(INEXT(IDIR),0)
DISL=TRKDIS
ELSE IF(TRKDIS .LT. DISL) THEN
ISL(IDIR)=IFACE-MAX(INEXT(IDIR),0)
DISL=TRKDIS
ENDIF
* write(6,*) 'After 2 ',ISL(IDIR),DISF
ELSE
*----
* Store point in adequate order in TRKLIS
*----
* write(6,*) 'Intersection at ',TRKDIS,' inside cell'
KEL=IEL
DO JEL=1,IEL
IF(TRKDIS .LT. TRKLSI(JEL)) THEN
DO KEL=IEL,JEL,-1
TRKLSI(KEL+1)=TRKLSI(KEL)
DO ITC=0,5
ISINT(ITC,KEL+1)=ISINT(ITC,KEL)
ISINT(ITC,KEL)=0
ENDDO
ENDDO
KEL=JEL-1
GO TO 110
ENDIF
ENDDO
110 CONTINUE
TRKLSI(KEL+1)=TRKDIS
ISINT(0,KEL+1)=INEXT(IDIR)*IDIR
ISINT(IDIR,KEL+1)=IFACE
* write(6,*) KEL+1,ISINT(0,KEL+1),ISINT(IDIR,KEL+1)
IEL=IEL+1
ENDIF
ENDDO
100 CONTINUE
ENDDO
NBSINT=IEL
IF(IPRINT .GE. 100) THEN
WRITE(IOUT,6016) 'HtrackIntA={ '
DO JEL=1,NBSINT-1
WRITE(IOUT,6014) TRKLSI(JEL),
> (ISINT(IDIR,JEL),IDIR=0,5)
ENDDO
JEL=NBSINT
WRITE(IOUT,6015) TRKLSI(JEL),
> (ISINT(IDIR,JEL),IDIR=0,5)
ENDIF
*----
* Process corners inside cell
*----
KEL=1
DO JEL=2,NBSINT
XXX=ABS(TRKLSI(JEL)-TRKLSI(KEL))
IF(XXX .LT. DCUTOF) THEN
ISINT(0,KEL)=5
IDIR=ABS(ISINT(0,JEL))
ISINT(IDIR,KEL)=ISINT(IDIR,JEL)
ELSE
KEL=KEL+1
TRKLSI(KEL)=TRKLSI(JEL)
DO IDIR=0,5
ISINT(IDIR,KEL)=ISINT(IDIR,JEL)
ENDDO
ENDIF
ENDDO
NBSINT=KEL
IF(IPRINT .GE. 100) THEN
WRITE(IOUT,6016) 'HtrackIntB={ '
DO JEL=1,NBSINT-1
WRITE(IOUT,6014) TRKLSI(JEL),
> (ISINT(IDIR,JEL),IDIR=0,5)
ENDDO
JEL=NBSINT
WRITE(IOUT,6015) TRKLSI(JEL),
> (ISINT(IDIR,JEL),IDIR=0,5)
ENDIF
*----
* Identify final faces
*----
JEL=NBSINT
IDIR=ABS(ISINT(0,JEL))
ISINT(0,JEL+1)=ISINT(0,JEL)
TRKLSI(JEL+1)=TRKLSI(JEL)
NBCOR(2)=1
DO IDIRS=1,5
IF(IDIRS .EQ. IDIR) THEN
IF(ISINT(IDIRS,JEL) .EQ. 1) THEN
ISINT(IDIRS,JEL+1)=-1
ELSE
ISINT(IDIRS,JEL+1)=-2
ENDIF
ELSE
ISINT(IDIRS,JEL+1)=ISL(IDIRS)
ENDIF
ENDDO
*----
* Regions
*----
DO JEL=NBSINT,2,-1
TRKLSI(JEL)=TRKLSI(JEL)-TRKLSI(JEL-1)
IDIR=ABS(ISINT(0,JEL))
IF(IDIR .EQ. 5) THEN
DO IDIRS=1,5
KDIR=ISINT(IDIRS,JEL)
IF(KDIR .NE. 0) THEN
ISINT(IDIRS,JEL)=KDIR-MAX(INEXT(IDIRS),0)
ELSE
ISINT(IDIRS,JEL)=ISINT(IDIRS,JEL+1)
ENDIF
ENDDO
ELSE
DO IDIRS=1,5
IF(IDIRS .EQ. IDIR) THEN
ISINT(IDIRS,JEL)=ISINT(IDIRS,JEL)-MAX(INEXT(IDIR),0)
ELSE
ISINT(IDIRS,JEL)=ISINT(IDIRS,JEL+1)
ENDIF
ENDDO
ENDIF
ENDDO
*----
* Identify initial faces
*----
JEL=1
IDIR=ABS(ISINT(0,JEL))
NBCOR(1)=1
DO IDIRS=1,5
IF(IDIRS .EQ. IDIR) THEN
IF(ISINT(IDIRS,JEL) .EQ. 1) THEN
ISINT(IDIRS,JEL)=-1
ELSE
ISINT(IDIRS,JEL)=-2
ENDIF
ELSE
ISINT(IDIRS,JEL)=ISF(IDIRS)
ENDIF
ENDDO
NBSINT=NBSINT
*----
* Print final track information
*----
IF(IPRINT .GT. 100) THEN
WRITE(IOUT,6011) 'Initial face '
JEL=1
WRITE(IOUT,6010) TRKLSI(JEL),
> (ISINT(IDIR,JEL),IDIR=1,5)
WRITE(IOUT,6011) 'Regions '
DO JEL=2,NBSINT
WRITE(IOUT,6010) TRKLSI(JEL),
> (ISINT(IDIR,JEL),IDIR=1,5)
ENDDO
WRITE(IOUT,6011) 'Final face '
JEL=NBSINT+1
WRITE(IOUT,6010) TRKLSI(JEL),
> (ISINT(IDIR,JEL),IDIR=1,5)
WRITE(IOUT,6001) NAMSBR
ENDIF
NXTLHT=NBSINT
RETURN
*----
* Output formats
*----
6000 FORMAT('(* Output from --',A6,'-- follows ')
6001 FORMAT(' Output from --',A6,'-- completed *)')
6010 FORMAT(1X,F25.16,6I10)
6011 FORMAT(A20)
6012 FORMAT(6(1X,F25.16,:,','))
6013 FORMAT('};')
6014 FORMAT(('{',F25.16,6(',',I5),'},'))
6015 FORMAT(('{',F25.16,9(',',I5),'}};'))
6016 FORMAT(A20)
END
|
