1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
600
601
602
603
604
605
606
607
608
609
610
611
612
613
614
615
616
617
618
619
620
621
622
623
624
625
626
627
628
629
630
631
632
633
634
635
636
637
638
639
640
641
642
643
644
645
646
647
648
649
650
651
652
653
654
655
656
657
658
659
660
661
662
663
664
665
666
667
668
669
670
671
672
673
674
675
676
677
678
679
680
681
682
683
684
685
686
687
688
689
690
691
692
693
694
695
696
697
698
699
700
701
702
703
704
705
706
707
708
709
710
711
712
713
714
715
716
717
718
719
720
721
722
723
724
725
726
727
728
729
730
731
732
733
734
735
736
737
738
739
740
741
742
743
744
745
746
747
748
749
750
751
752
753
754
755
756
757
758
759
760
761
762
763
764
765
766
767
768
769
770
771
772
773
774
775
776
777
|
*DECK LIBWIM
SUBROUTINE LIBWIM(IPLIB,IPRINT,NAMFIL,NGROUP,NBISO,NL,ISONAM,
> ISONRF,IPISO,ISHINA,TN,SN,SB,MASKI,NGF,NGFR)
*
*-----------------------------------------------------------------------
*
*Purpose:
* Transcription of the interpolated microscopic xs read from a
* microscopic xs library in WIMS-AECL format to LCM data structures.
*
*Copyright:
* Copyright (C) 2002 Ecole Polytechnique de Montreal
* This library is free software; you can redistribute it and/or
* modify it under the terms of the GNU Lesser General Public
* License as published by the Free Software Foundation; either
* version 2.1 of the License, or (at your option) any later version
*
*Author(s): G. Marleau
*
*Parameters: input
* IPLIB pointer to the internal library.
* IPRINT print flag.
* NAMFIL WIMS-EACL file name.
* NGROUP number of groups.
* NBISO number of isotopes.
* NL number of Legendre scattering order:
* =1 isotropic;
* =2 linearly anisotropic.
* ISONAM local isotope names.
* ISONRF library isotope names.
* IPISO pointer array towards microlib isotopes.
* ISHINA self-shielding isotope names.
* TN isotope tempterature.
* SN dilution xs.
* SB Livolant-Jeanpierre dilution xs.
* MASKI logical mask for processing isotope.
*
*Parameters: output
* NGF number of fast groups without self-shielding.
* NGFR number of fast and resonance groups.
*
*-----------------------------------------------------------------------
*
USE GANLIB
IMPLICIT NONE
*----
* SUBROUTINE ARGUMENTS
*----
INTEGER NDPROC
PARAMETER (NDPROC=11)
TYPE(C_PTR) IPLIB,IPISO(NBISO)
INTEGER IPRINT,NGROUP,NBISO,NL,ISONAM(3,NBISO),ISONRF(3,NBISO),
> ISHINA(3,NBISO),NGF,NGFR
CHARACTER NAMFIL*8
LOGICAL MASKI(NBISO)
REAL TN(NBISO),SN(NGROUP,NBISO),SB(NGROUP,NBISO)
*----
* FUNCTIONS
*----
DOUBLE PRECISION XDRCST
*----
* INTERNAL PARAMETERS
*----
INTEGER IOUT,ITLIB,MAXRES,MAXTEM,MAXDIL,NOTX
REAL CONVM
PARAMETER (IOUT=6,ITLIB=1,MAXRES=50,MAXTEM=20,MAXDIL=20,NOTX=-1)
*----
* LOCAL VARIABLES
*----
CHARACTER NAMDXS(NDPROC)*8,HNAMIS*12,HNISOR*12,HSHIR*8,
> README*96,FMT*6
INTEGER IHGAR(24),IP1,NPROC,IUNIT,KDROPN,II,NEL,NGR,NGTHER,
> MXSCT,NGX,IG,ILOCX,ILOCY,ILOCS,NRDT,JSO,ITC,IDRES,IEL,
> IRISO,IENDF,NF,NSCT,NTMP,IREC,JJJ,IACT,ITMP,ITXS,NTYP,
> LSUBTR,LSUBZ,LRESND,IGRF,IGR,NRES,IGF,JRES,KRES,NTMPR,
> NDILR,NTD,ITT,IRRICS,ILL,IGRL,IG1,IP0
REAL TMPT(MAXTEM),DILT(MAXTEM),RS1(3*MAXRES),XSCOR(4),
> AWJSO,RIND,XRS1,ASIGPL
DOUBLE PRECISION TERP(MAXTEM)
TYPE(C_PTR) KPLIB
*----
* WIMS-AECL LIBRARY PARAMETERS
* IUTYPE : TYPE OF FILE = 4 (DA)
* LRIND : LENGHT RECORD ON DA FILE = 256
* IACTO : OPEN ACTION = 2 (READ ONLY)
* IACTC : CLOSE ACTION = 2 (KEEP)
* MAXISO : MAX. NB. OF ISO = 246
* NCT : NUMBER OF C*8 IN TITLE = 10
* LPZ : LENGTH OF WIMS PARAMETER ARRAY = 9
* LMASTB : LENGTH OF MST TAB = MAXISO+9
* LMASIN : LENGTH OF MST IDX = LMASTB-4
* LGENTB : LENGTH OF GEN TAB = 6
* LGENIN : LENGTH OF GEN IDX = LGENTB
* LSUBTB : LENGTH OF SUB TAB = 6*MAXTEM+21-5+12
* LSUBIN : LENGTH OF SUB IDX = LSUBTB-12
* LRESTB : LENGTH OF RES TAB = 5*MAXRES
* LRESIN : LENGTH OF RES IDX = LRESIN
* MASTER : MASTER INDEX ARRAY
* GENINX : GENERAL INDEX ARRAY
* SUBINX : SUB INDEX ARRAY GENERAL
* SUBINR : SUB INDEX ARRAY RESONANCE
* RESINX : RESONANCE INDEX ARRAY
* IWISO : ID OF ISOTOPE
* CWISO : ISOTOPE NAMES
* MASTER : MASTER INDEX ARRAY
* GENINX : GENERAL INDEX ARRAY
* SUBINX : SUB INDEX ARRAY
*----
INTEGER IUTYPE,LRIND,IACTO,IACTC,MAXISO,NCT,LPZ,LMASTB,
> LMASIN,LGENTB,LGENIN,LSUBTB,LSUBIN,LRESTB,
> LRESIN,ILONG,ITYLCM
PARAMETER (IUTYPE=4,LRIND=256,IACTO=2,IACTC=1,
> MAXISO=246,NCT=10,LPZ=9,LMASTB=MAXISO+9,
> LMASIN=LMASTB-4,LGENTB=6,LGENIN=LGENTB,
> LSUBTB=6*MAXTEM+28,LSUBIN=LSUBTB-12,
> LRESTB=MAXRES*5,LRESIN=LRESTB)
CHARACTER CWISO(MAXISO)*8,CTITLE(NCT)*8
INTEGER MASTER(LMASTB),GENINX(LGENTB),SUBINX(LSUBTB),
> SUBINR(LSUBTB),RESINX(LRESTB),NXS(MAXTEM),
> ITITLE(2*NCT),NPZ(LPZ),IWISO(2*MAXISO)
REAL AWR
INTEGER IPRLOC
EQUIVALENCE (SUBINX(LSUBIN+3),AWR)
*----
* ALLOCATABLE ARRAYS
*----
INTEGER, ALLOCATABLE, DIMENSION(:) :: ITYPRO
REAL, ALLOCATABLE, DIMENSION(:) :: DELTA,XSSCMP,ENER,TMPXS,TMPSC,
> RRI,RIT,DSIGPL
REAL, ALLOCATABLE, DIMENSION(:,:) :: XSREC,XSOUT,GAR
REAL, ALLOCATABLE, DIMENSION(:,:,:) :: SCAT
*----
* DATA
*----
SAVE NAMDXS
DATA NAMDXS /'NTOT0 ','TRANC ','NUSIGF ','NFTOT ',
> 'CHI ','NU ','NG ','N2N ',
> 'NGOLD ','NWT0 ','H-FACTOR'/
*----
* SCRATCH STORAGE ALLOCATION
* ITYPRO cross section processed
* DELTA lethergy
* XSREC general xs vector
* SCAT complete scattering matrix SCAT(JG,IG) (from IG to JG)
* XSSCMP compress scattering for transfer
* XSOUT self shielding parameter
* GAR intermediate xs vector:
* GAR(I,1): library fission spectrum;
* GAR(I,2): potential scattering xs
*----
ALLOCATE(ITYPRO(NL))
ALLOCATE(DELTA(NGROUP),XSREC(NGROUP,NDPROC+NL),
> SCAT(NGROUP,NGROUP,NL),XSSCMP(NGROUP*(NGROUP+2)),
> XSOUT(NGROUP,7),GAR(NGROUP,2))
*----
* OPEN WIMSLIB AND READ TITLE
* READ GENERAL DIMENSIONING
*----
IPRLOC=IPRINT
IF(IPRINT .LT. 20) IPRLOC=0
CONVM=REAL(XDRCST('Neutron mass','amu'))
IP0=NDPROC+1
IP1=NDPROC+2
NPROC=NDPROC+NL
IUNIT=KDROPN(NAMFIL,IACTO,IUTYPE,LRIND)
IF(IUNIT.LE.0) CALL XABORT('LIBWIM: WIMS-AECL LIBRARY '//
> NAMFIL//' CANNOT BE OPENED FOR MIXS')
CALL OPNIND(IUNIT,MASTER,LMASTB)
CALL REDIND(IUNIT,MASTER,LMASIN,GENINX,LGENTB,1)
CALL REDIND(IUNIT,MASTER,LMASIN,ITITLE,2*NCT,2)
CALL UPCKIC(ITITLE(1),CTITLE(1),NCT)
WRITE(README(9:96),'(6H FROM ,10A8,A2)')
> (CTITLE(II),II=1,NCT),' '
IF(IPRINT.GE.5) THEN
WRITE(IOUT,6000) NAMFIL
WRITE(IOUT,'(1X,10A8)') (CTITLE(II),II=1,NCT)
ENDIF
CALL REDIND(IUNIT,GENINX,LGENIN,NPZ,LPZ,1)
IF(NPZ(2).NE.NGROUP) THEN
WRITE(IOUT,9001) NGROUP,NPZ(2)
CALL XABORT('LIBWIM: INVALID NUMBER OF GROUPS')
ENDIF
NEL=NPZ(1)
NGF=NPZ(4)
NGR=NPZ(5)
NGTHER=NPZ(6)
NGFR=NGF+NGR
MXSCT=NGROUP*(NGROUP+2)
IF(NGFR+NGTHER.NE.NGROUP) THEN
WRITE(IOUT,9001) NGROUP,NGFR+NGTHER
CALL XABORT('LIBWIM: INVALID NUMBER OF GROUPS')
ENDIF
IF(NEL.GT.MAXISO) THEN
WRITE(IOUT,9003) MAXISO,NEL
CALL XABORT('LIBWIM: INVALID NUMBER OF ISOTOPES')
ENDIF
ALLOCATE(DSIGPL(NGR))
*----
* READ ISOTOPES NAMES
*----
CALL REDIND(IUNIT,GENINX,LGENIN,IWISO,2*NEL,3)
CALL UPCKIC(IWISO(1),CWISO(1),NEL)
CALL REDIND(IUNIT,GENINX,LGENIN,IWISO,NEL,2)
*----
* READ GROUP STRUCTURE
*----
ALLOCATE(ENER(NGROUP+1))
CALL REDIND(IUNIT,GENINX,LGENIN,ENER,NGROUP+1,4)
IF(ENER(NGROUP+1).EQ.0.0) ENER(NGROUP+1)=1.0E-5
CALL LCMPUT(IPLIB,'ENERGY',NGROUP+1,2,ENER)
NGX=0
DO 100 IG=1,NGROUP
IF(NGX.EQ.0.AND.ENER(IG+1).LT.4.0) NGX=IG-1
DELTA(IG)=LOG(ENER(IG)/ENER(IG+1))
100 CONTINUE
CALL LCMPUT(IPLIB,'DELTAU',NGROUP,2,DELTA)
DEALLOCATE(ENER)
*----
* INITIALIZE ALL XSREC
* READ FISSION SPECTRUM
*----
GAR(:NGROUP,1)=0.0
CALL REDIND(IUNIT,GENINX,LGENIN,GAR(:,1),NPZ(3),5)
*----
* ALLOCATE MEMORY FOR TEMPERATURE DEPENDENT XS
* AND FOR RESONANCE CALCULATION
*----
ALLOCATE(TMPXS(5*NGROUP),TMPSC(NGROUP*NGROUP),
> RRI(MAXDIL*MAXTEM*2),RIT(MAXDIL))
ILOCX=0
ILOCY=NGFR
ILOCS=0
NRDT=NGTHER-1
*----
* READ THROUGH DRAGON FILE AND ACCUMULATE CROSS SECTIONS FOR
* CROSS SECTION ARE SAVED ONLY IF ISOTOPE IS USED
*----
DO 110 JSO=1,NBISO
IF(.NOT.MASKI(JSO)) GO TO 115
*----
* LOCATE ISOTOPE
*----
WRITE(HNAMIS,'(3A4)') (ISONAM(ITC,JSO),ITC=1,3)
WRITE(HNISOR,'(3A4)') (ISONRF(ITC,JSO),ITC=1,3)
WRITE(HSHIR,'(2A4)') (ISHINA(ITC,JSO),ITC=1,2)
IDRES=INDEX(HSHIR,'.')
IF(IDRES.GT.0) THEN
WRITE(FMT,'(2H(F,I1,3H.1))') IDRES+1
READ(HSHIR,FMT) RIND
ENDIF
IRISO=0
DO 120 IEL=1,NEL
IF(CWISO(IEL).EQ.HNISOR(1:8)) THEN
IRISO=IEL
IF(IDRES.EQ.0) THEN
RIND=FLOAT(IWISO(IRISO))
ENDIF
GO TO 125
ENDIF
120 CONTINUE
WRITE(IOUT,9002) HNISOR,NAMFIL
CALL XABORT('LIBWIM: ISOTOPE NOT FOUND ON LIBRARY')
125 CONTINUE
IF(IPRINT.GE.5) WRITE(IOUT,6001) HNAMIS
XSREC(:NGROUP,:NPROC)=0.0
SCAT(:NGROUP,:NGROUP,:NL)=0.0
*----
* READ SUB INDEX ASSOCIATED WITH ISOTOPE
*----
CALL REDIND(IUNIT,MASTER,LMASIN,SUBINX,LSUBTB,IRISO+4)
*----
* FOR ENDF/B-VI LIBRARY : IENDF = 2
* FOR ENDF/B-V LIBRARY : IENDF = 1
* FOR WINFRITH LIBRARY : IENDF = 0
*----
IENDF=SUBINX(LSUBIN+12)
AWJSO=AWR/CONVM
*----
* FAST AND/OR RESONANCE XS
*----
CALL REDIND(IUNIT,SUBINX,LSUBIN,XSREC(NGF+1:,9),NGR,9)
DSIGPL(:NGR)=0.0
IF(IENDF.EQ.0) THEN
CALL REDIND(IUNIT,SUBINX,LSUBIN,GAR(NGF+1:,2),NGR,2)
DO 130 IG=NGF+1,NGFR
DSIGPL(IG-NGF)=GAR(IG,2)*XSREC(IG,9)
130 CONTINUE
ENDIF
CALL REDIND(IUNIT,SUBINX,LSUBIN,XSREC(:,8),NGF,13)
NF=SUBINX(LSUBIN+5)
IF(NF.GT.1) THEN
CALL REDIND(IUNIT,SUBINX,LSUBIN,XSREC(:,3),NGFR,10)
CALL REDIND(IUNIT,SUBINX,LSUBIN,XSREC(:,4),NGFR,12)
DO 135 IG=1,NGROUP
XSREC(IG,5)=GAR(IG,1)
135 CONTINUE
ENDIF
NSCT=SUBINX(LSUBIN+8)
IF(NSCT.GT.MXSCT) THEN
WRITE(IOUT,9004) NSCT,MXSCT
CALL XABORT('LIBWIM: INVALID SCATTERING MATRIX -E/0')
ENDIF
*----
* READ AND DECOMPRESS P0 SCATTERING CROSS SECTIONS
* COMPUTE TOTAL P0 SCATTERING OUT OF GROUP
*----
CALL REDIND(IUNIT,SUBINX,LSUBIN,XSSCMP,NSCT,14)
CALL LIBWSC(NGROUP,1,NGFR,NSCT,XSSCMP,SCAT(1,1,1),XSREC(1,IP0))
*----
* FOR IENDF=2 READ XS FOR NG AND TOTAL
* FOR IENDF=0,1 READ XS FOR NG AND TRANSPORT
*----
IF(IENDF.GE.2) THEN
*----
* READ TOTAL XS FOR IENDF=2
*----
CALL REDIND(IUNIT,SUBINX,LSUBIN,XSREC(:,2),NGFR,5)
CALL REDIND(IUNIT,SUBINX,LSUBIN,XSREC(:,7),NGFR,5)
ELSE
*----
* COMPUTE TOTAL XS FOR IENDF=0,1
*----
CALL REDIND(IUNIT,SUBINX,LSUBIN,XSREC(:,2),NGFR,4)
CALL REDIND(IUNIT,SUBINX,LSUBIN,XSREC(:,7),NGFR,6)
ENDIF
*----
* THERMAL XS
*----
NTMP=SUBINX(LSUBIN+6)
IF(NTMP.GT.MAXTEM) THEN
CALL XABORT('LIBWIM: INVALID MAXTEM FOR P0.')
ENDIF
CALL REDIND(IUNIT,SUBINX,LSUBIN,NXS,NTMP,3)
CALL REDIND(IUNIT,SUBINX,LSUBIN,TMPT,NTMP,15)
IREC=16
IF(NTMP.EQ.1) THEN
IF(IPRINT.GE.100) THEN
WRITE(IOUT,6200) TN(JSO)
ENDIF
IREC=IREC+2
IF(NF.GT.1) THEN
CALL REDIND(IUNIT,SUBINX,LSUBIN,XSREC(NGFR+1:,3),
> NGTHER,IREC)
CALL REDIND(IUNIT,SUBINX,LSUBIN,XSREC(NGFR+1:,4),
> NGTHER,IREC+1)
ENDIF
IREC=IREC+2
IF(NXS(1).GT.MXSCT) THEN
WRITE(IOUT,9004) NXS(1),MXSCT
CALL XABORT('LIBWIM: INVALID SCATTERING MATRIX -T/0')
ENDIF
CALL REDIND(IUNIT,SUBINX,LSUBIN,XSSCMP,NXS(1),IREC)
IREC=IREC+1
*----
* DECOMPRESS P0 SCATTERING CROSS SECTIONS AND COMPUTE
* P0 SCATTERING OUT OF GROUP
*----
CALL LIBWSC(NGROUP,NGFR+1,NGROUP,NXS(1),XSSCMP,
> SCAT(1,1,1),XSREC(1,IP0))
IF(IENDF.GE.2) THEN
CALL REDIND(IUNIT,SUBINX,LSUBIN,XSREC(NGFR+1:,2),
> NGTHER,IREC-4)
ELSE
CALL REDIND(IUNIT,SUBINX,LSUBIN,XSREC(NGFR+1:,2),
> NGTHER,IREC-5)
ENDIF
CALL REDIND(IUNIT,SUBINX,LSUBIN,XSREC(NGFR+1:,7),
> NGTHER,IREC-4)
ELSE IF(NTMP.GT.1) THEN
*----
* AVALUATE LAGRANGIAN INTERPOLATION FACTOR FOR
* AVAILABLE TEMPERATURES (ORDER NOTX) AND INTERPOLATE.
*----
CALL LIBLEX(NTMP,TN(JSO),TMPT,NOTX,TERP)
IF(IPRINT.GE.100) THEN
WRITE(IOUT,6201) TN(JSO)
WRITE(IOUT,6202) (TMPT(JJJ),JJJ=1,NTMP)
WRITE(IOUT,6203) (TERP(JJJ),JJJ=1,NTMP)
ENDIF
NRDT=NGTHER-1
IACT=1
DO 140 ITMP=1,NTMP
IF(TERP(ITMP).EQ.0.0D0) THEN
IREC=IREC+5
ELSE
IREC=IREC+2
IF(NF.GT.1) THEN
CALL REDIND(IUNIT,SUBINX,LSUBIN,TMPXS(ILOCY+2*NGROUP+1:),
> NGTHER,IREC)
CALL REDIND(IUNIT,SUBINX,LSUBIN,TMPXS(ILOCY+3*NGROUP+1:),
> NGTHER,IREC+1)
ELSE
TMPXS(ILOCY+2*NGROUP+1:ILOCY+2*NGROUP+NGTHER)=0.0
TMPXS(ILOCY+3*NGROUP+1:ILOCY+3*NGROUP+NGTHER)=0.0
ENDIF
IREC=IREC+2
IF(NXS(ITMP).GT.MXSCT) THEN
WRITE(IOUT,9004) NXS(ITMP),MXSCT
CALL XABORT('LIBWIM: INVALID SCATTERING MATRIX -T/0')
ENDIF
CALL REDIND(IUNIT,SUBINX,LSUBIN,XSSCMP,NXS(ITMP),IREC)
IREC=IREC+1
*----
* DECOMPRESS P0 SCATTERING CROSS SECTIONS AND COMPUTE
* P0 SCATTERING OUT OF GROUP
*----
CALL LIBWSC(NGROUP,NGFR+1,NGROUP,NXS(ITMP),XSSCMP,
> TMPSC(ILOCS+1),TMPXS(ILOCX+4*NGROUP+1))
IF(IENDF.GE.2) THEN
CALL REDIND(IUNIT,SUBINX,LSUBIN,TMPXS(ILOCY+1:),
> NGTHER,IREC-4)
ELSE
CALL REDIND(IUNIT,SUBINX,LSUBIN,TMPXS(ILOCY+1:),
> NGTHER,IREC-5)
ENDIF
CALL REDIND(IUNIT,SUBINX,LSUBIN,TMPXS(ILOCY+NGROUP+1:),
> NGTHER,IREC-4)
ITXS=1
CALL LIBWTE(IACT,ITXS,NGROUP,NGTHER,1,NF,TERP(ITMP),
> SCAT(1,1,1),XSREC(1,IP0),XSREC(1,7),
> XSREC(1,3),XSREC(1,4),XSREC(1,2),TMPXS,TMPSC)
IACT=2
ENDIF
140 CONTINUE
ENDIF
*----
* BUILT CROSS SECTION FROM INFORMATION IN NG WHICH IS
* CURRENTLY ABSORPTION AND SCATTERING OUT OF GROUP
* COMPUTE REAL NG CROSS SECTION WHICH IS
* CURRENT NG (ABSORPTION)-FISSION+N2N
* SINCE ABSORPTION IS DEFINED AS
* TOTAL-SIGS WHERE SIGS CONTAINE 2*N2N SINCE A N2N CONTRIBUTION
* PRODUCES AN EQUIVALENT OF 2 NEUTRON BY DIFFUSION
*----
DO 150 IG=1,NGROUP
XSREC(IG,1)=XSREC(IG,7)+XSREC(IG,IP0)
IF(NF.GT.1) THEN
XSREC(IG,7)=XSREC(IG,7)+XSREC(IG,8)-XSREC(IG,4)
ELSE
XSREC(IG,7)=XSREC(IG,7)+XSREC(IG,8)
ENDIF
IF(XSREC(IG,4).NE.0) THEN
XSREC(IG,6)=XSREC(IG,3)/XSREC(IG,4)
ELSE
XSREC(IG,6)=0
ENDIF
150 CONTINUE
IF(IENDF.LT.2) THEN
*----
* COMPUTE TRANSPORT CORRECTION AND STORE IN TRAN
*----
DO 151 IG=1,NGROUP
XSREC(IG,2)=XSREC(IG,1)-XSREC(IG,2)
151 CONTINUE
ENDIF
*----
* SELF SHIELDING DATA
*----
NTYP=1
XSCOR(1)=0.0
IF(SUBINX(LSUBIN+5).EQ.3) THEN
NTYP=2
XSCOR(2)=0.0
ENDIF
*----
* MODIFIED SUB IDX LENGTH FOR RESONANCE
*----
LSUBTR=NGR+7
LSUBZ=NGR+1
CALL REDIND(IUNIT,MASTER,LMASIN,SUBINR,LSUBTR,NEL+5)
*----
* MODIFIED RES IDX LENGTH FOR RESONANCE
*----
LRESND=SUBINR(NGR+6)
IF(NTYP.EQ.2.AND.SUBINR(NGR+7).EQ.1) THEN
NTYP=3
XSCOR(3)=0.0
ENDIF
XSCOR(4)=0.0
IGRF=NGF
KRES=0
DO 300 IGR=1,NGR
IGRF=IGRF+1
CALL REDIND(IUNIT,SUBINR,LSUBZ,RESINX,LRESND+1,IGR)
NRES=RESINX(LRESND+1)
IF(NRES.GT.MAXRES) THEN
WRITE(IOUT,9005) NRES,MAXRES
CALL XABORT('LIBWIM: INVALID NUMBER OF RESONANCE')
ENDIF
IF(IGR.EQ.1) THEN
CALL REDIND(IUNIT,RESINX,LRESND,RS1,3*NRES,1)
DO 314 IGF=1,NGFR
XSOUT(IGF,3)=XSREC(IGF,IP0)
XSOUT(IGF,4)=1.0
XSOUT(IGF,5)=1.0
314 CONTINUE
*----
* IDENTIFY SELF SHIELDING RESONNANT ISOTOPE
*----
DO 310 JRES=1,NRES
IF(IDRES.EQ.0) THEN
XRS1=FLOAT(INT((RS1(3*(JRES-1)+1)+0.01)*10.)
> -INT(RS1(3*(JRES-1)+1)+0.01)*10)/10.+0.02
XRS1=ABS(RS1(3*(JRES-1)+1)-XRS1-RIND)
ELSE
XRS1=ABS(RS1(3*(JRES-1)+1)-RIND)
ENDIF
IF(XRS1.LE.0.01) THEN
KRES=JRES
NTMPR=INT(RS1(3*(KRES-1)+2)+0.1)
NDILR=INT(RS1(3*(KRES-1)+3)+0.1)
IF(NTMPR.GT.MAXTEM) THEN
WRITE(IOUT,9006) NTMPR,MAXTEM
CALL XABORT('LIBWIM: INVALID NUMBER OF RES TEMP')
ELSE IF(NDILR.GT.MAXTEM) THEN
WRITE(IOUT,9007) NDILR,MAXTEM
CALL XABORT('LIBWIM: INVALID NUMBER OF RES DIL')
ENDIF
NTD=NDILR*NTMPR
IF(IPRINT.GE.5) THEN
WRITE(IOUT,6002) RS1(3*(JRES-1)+1)
ENDIF
CALL REDIND(IUNIT,RESINX,LRESND,TMPT,NTMPR,2+5*(KRES-1))
CALL REDIND(IUNIT,RESINX,LRESND,DILT,NDILR,3+5*(KRES-1))
IF(IPRINT.GE.100) THEN
WRITE(IOUT,6003) TN(JSO)
WRITE(IOUT,6008) (TMPT(ITT),ITT=1,NTMPR)
WRITE(IOUT,6004) SN(IGRF,JSO),DSIGPL(IGR)
WRITE(IOUT,6008) (DILT(ITT),ITT=1,NDILR)
ENDIF
DO 312 II=1,NTMPR
TMPT(II)=SQRT(TMPT(II))
312 CONTINUE
DO 313 II=1,NDILR
IF(DILT(II)-DSIGPL(IGR).GT.0.0) THEN
DILT(II)=SQRT(DILT(II)-DSIGPL(IGR))
ELSE
DILT(II)=0.0
ENDIF
313 CONTINUE
GO TO 311
ENDIF
310 CONTINUE
*----
* NO SELF SHIELDING DATA FOR THIS ISOTOPE EXIT TO 301
*----
XSREC(:NGROUP,10)=0.0
GO TO 301
ENDIF
*----
* READ SELF SHIELDING DATA FOR THIS ISOTOPE
*----
311 CONTINUE
*----
* READ FLUX FOR THIS RESONANCE INTEGRAL
*----
IF(IENDF.GE.2) THEN
*----
* READ TOTAL RR AND FLUX
*----
CALL REDIND(IUNIT,RESINX,LRESND,RRI,2*NTD,4+5*(KRES-1))
CALL LIBWRI(NTMPR,NDILR,TN(JSO),SN(IGRF,JSO),TMPT,
> DILT,RRI(1),RIT,XSOUT(IGRF,1),XSCOR(1))
CALL LIBWRI(NTMPR,NDILR,TN(JSO),SN(IGRF,JSO),TMPT,DILT,
> RRI(NTD+1),RIT,XSOUT(IGRF,4),XSCOR(4))
ELSE
*----
* READ TOTAL RR
*----
CALL REDIND(IUNIT,RESINX,LRESND,RRI,NTD,4+5*(KRES-1))
CALL LIBWRI(NTMPR,NDILR,TN(JSO),SN(IGRF,JSO),TMPT,
> DILT,RRI(1),RIT,XSOUT(IGRF,1),XSCOR(1))
IF(IPRINT.GE.100) THEN
WRITE(IOUT,6005) XSOUT(IGRF,1)
WRITE(IOUT,6008) (RRI(ITT),ITT=1,NTD)
ENDIF
ENDIF
IF(NTYP.GE.2) THEN
*----
* READ FISSION RR
*----
CALL REDIND(IUNIT,RESINX,LRESND,RRI,NTD,5+5*(KRES-1))
CALL LIBWRI(NTMPR,NDILR,TN(JSO),SN(IGRF,JSO),TMPT,DILT,
> RRI(1),RIT,XSOUT(IGRF,2),XSCOR(2))
IF(IPRINT.GE.100) THEN
WRITE(IOUT,6006) XSOUT(IGRF,2)
WRITE(IOUT,6008) (RRI(ITT),ITT=1,NTD)
ENDIF
IF(NTYP.GE.3) THEN
*----
* READ SCATTERING RR
*----
CALL REDIND(IUNIT,RESINX,LRESND,RRI,NTD,
> 6+5*(KRES-1))
IRRICS=0
ASIGPL=0.0
DO 340 ILL=1,NTD
ASIGPL=ASIGPL+RRI(IRRICS+1)
IRRICS=IRRICS+1
340 CONTINUE
IF(ASIGPL.GT.0.0) THEN
CALL LIBWRI(NTMPR,NDILR,TN(JSO),SN(IGRF,JSO),TMPT,
> DILT,RRI(1),RIT,XSOUT(IGRF,3),XSCOR(3))
IF(IPRINT.GE.100) THEN
WRITE(IOUT,6007) XSOUT(IGRF,3)
WRITE(IOUT,6008) (RRI(ITT),ITT=1,NTD)
ENDIF
ENDIF
ENDIF
ENDIF
300 CONTINUE
*----
* CORRECT CROSS SECTIONS FOR CURRENT GROUP
*----
IGRL=IGRF
IGRF=NGF+1
CALL LIBWRE(NTYP,IPRINT,ITLIB,NGROUP,1,IGRF,IGRL,NGR,
> SCAT,XSREC(1,IP0),XSREC(1,1),XSREC(1,7),
> XSREC(1,3),XSREC(1,4),XSREC(1,6),
> DELTA,SN(1,JSO),SB(1,JSO),XSOUT,XSCOR,
> DSIGPL)
*----
* PRINT CROSS SECTIONS IF REQUIRED
*----
IF(IPRINT.GE.5) THEN
WRITE(IOUT,6100)
DO 400 IG1=NGF+1,NGFR
WRITE(IOUT,6101) IG1,SN(IG1,JSO),SB(IG1,JSO),
> XSOUT(IG1,4),XSREC(IG1,1),
> XSREC(IG1,IP0),XSREC(IG1,3),
> XSREC(IG1,9)
400 CONTINUE
ENDIF
*----
* SET NWT0 THE RESONANCE FLUX WEIGHTING
*----
XSREC(:NGROUP,10)=1.0
DO 401 IG1=NGF+1,NGFR
XSREC(IG1,10)=XSOUT(IG1,4)
401 CONTINUE
301 CONTINUE
*----
* P1 SCATTERING
*----
IF(NL.EQ.2) THEN
IREC=16+NTMP*5
NTMP=SUBINX(LSUBIN+10)
IF(NTMP+1.GT.MAXTEM) THEN
CALL XABORT('LIBWIM: INVALID MAXTEM FOR P1.')
ELSE IF(NTMP.GT.0) THEN
CALL REDIND(IUNIT,SUBINX,LSUBIN,NXS,NTMP+1,7)
CALL REDIND(IUNIT,SUBINX,LSUBIN,TMPT,NTMP,5)
NSCT=NXS(NTMP+1)
IF(NSCT.GT.MXSCT) THEN
WRITE(IOUT,9004) NSCT,MXSCT
CALL XABORT('LIBWIM: INVALID SCATTERING MATRIX -E/1')
ENDIF
CALL REDIND(IUNIT,SUBINX,LSUBIN,XSSCMP,NSCT,IREC)
IREC=IREC+1
*----
* DECOMPRESS P1 SCATTERING CROSS SECTIONS AND COMPUTE
* P1 SCATTERING OUT OF GROUP
*----
CALL LIBWSC(NGROUP,1,NGFR,NSCT,XSSCMP,
> SCAT(1,1,2),XSREC(1,IP1))
ENDIF
IF(NTMP.EQ.1) THEN
IF(NXS(1).GT.MXSCT) THEN
WRITE(IOUT,9004) NXS(1),MXSCT
CALL XABORT('LIBWIM: INVALID SCATTERING MATRIX -T/1')
ENDIF
CALL REDIND(IUNIT,SUBINX,LSUBIN,XSSCMP,NXS(1),IREC)
IREC=IREC+1
*----
* DECOMPRESS P1 SCATTERING CROSS SECTIONS AND COMPUTE
* P1 SCATTERING OUT OF GROUP
*----
CALL LIBWSC(NGROUP,NGFR+1,NGROUP,NXS(1),XSSCMP,
> SCAT(1,1,2),XSREC(1,IP1))
ELSE IF(NTMP.GT.1) THEN
*----
* AVALUATE LAGRANGIAN INTERPOLATION FACTOR FOR
* AVAILABLE TMPTERATURES (ORDER NOTX) AND INTERPOLATE.
*----
CALL LIBLEX(NTMP,TN(JSO),TMPT,NOTX,TERP)
NRDT=NGTHER-1
IACT=1
DO 170 ITMP=1,NTMP
IF(TERP(ITMP).EQ.0.0D0) THEN
IREC=IREC+1
ELSE
IF(NXS(ITMP).GT.MXSCT) THEN
WRITE(IOUT,9004) NXS(ITMP),MXSCT
CALL XABORT('LIBWIM: INVALID SCATTERING MATRIX -T/1')
ENDIF
CALL REDIND(IUNIT,SUBINX,LSUBIN,XSSCMP,NXS(ITMP),IREC)
IREC=IREC+1
*----
* DECOMPRESS P1 SCATTERING CROSS SECTIONS AND COMPUTE
* P1 SCATTERING OUT OF GROUP
*----
CALL LIBWSC(NGROUP,NGFR+1,NGROUP,NXS(ITMP),XSSCMP,
> TMPSC(ILOCS+1),TMPXS(ILOCX+4*NGROUP+1))
ITXS=2
CALL LIBWTE(IACT,ITXS,NGROUP,NGTHER,1,NF,TERP(ITMP),
> SCAT(1,1,2),XSREC(1,IP1),XSREC(1,7),
> XSREC(1,3),XSREC(1,4),XSREC(1,2),
> TMPXS,TMPSC)
IACT=2
ENDIF
170 CONTINUE
ENDIF
ENDIF
*----
* SAVE MAIN CROSS SECTIONS ON LCM
*----
KPLIB=IPISO(JSO) ! set JSO-th isotope
CALL LCMPTC(KPLIB,'ALIAS',12,HNAMIS)
CALL LCMPUT(KPLIB,'AWR',1,2,AWJSO)
CALL XDRLGS(KPLIB,1,IPRLOC,0,NL-1,1,NGROUP,XSREC(1,NDPROC+1),
> SCAT,ITYPRO)
CALL XDRLXS(KPLIB,1,IPRLOC,NDPROC,NAMDXS,1,NGROUP,XSREC)
CALL LCMLEN(KPLIB,'NTOT0',ILONG,ITYLCM)
IF(ILONG.EQ.0) CALL LCMPUT(KPLIB,'NTOT0',NGROUP,2,XSREC(1,1))
WRITE(README(:8),'(A8)') HNAMIS(1:8)
READ(README,'(24A4)') (IHGAR(II),II=1,24)
CALL LCMPUT(KPLIB,'README',24,3,IHGAR)
IF(IPRINT.GE.100) CALL LCMLIB(KPLIB)
115 CONTINUE
110 CONTINUE
DEALLOCATE(RIT,RRI,TMPSC,TMPXS)
CALL CLSIND(IUNIT)
*----
* SCRATCH STORAGE DEALLOCATION
*----
DEALLOCATE(DSIGPL,GAR,XSOUT,XSSCMP,SCAT,XSREC,DELTA)
DEALLOCATE(ITYPRO)
*----
* RETURN
*----
RETURN
*----
* FORMAT
*----
9001 FORMAT(/' NUMBER OF GROUPS SPECIFIED :',I10/
> ' NUMBER OF GROUPS IN LIBRARY :',I10)
9002 FORMAT(/' LIBWIM: MATERIAL/ISOTOPE ',A12,' IS MISSING ON WIMS',
> ' FILE NAME ',A8)
9003 FORMAT(/' MAXIMUM NUMBER OF ISOTOPE SPECIFIED :',I10/
> ' NUMBER OF ISOTOPE IN LIBRARY :',I10)
9004 FORMAT(/' DIMENSION OF SCATTERING MATRIX :',I10/
> ' MAXIMUM DIMENSION OF SCATTERING MATRIX :',I10)
9005 FORMAT(/' NUMBER OF RESONANT ISOTOPES :',I10/
> ' MAXIMUM NUMBER OF RESONANT ISOTOPES :',I10)
9006 FORMAT(/' NUMBER OF RESONANT TEMPERATURE :',I10/
> ' MAXIMUM NUMBER OF RESONANT TEMPERATURE :',I10)
9007 FORMAT(/' NUMBER OF RESONANT DILUTION :',I10/
> ' MAXIMUM NUMBER OF RESONANT DILUTION :',I10)
6000 FORMAT(' READING WIMS-AECL LIBRARY NAME ',A8)
6001 FORMAT(' PROCESSING ISOTOPE/MATERIAL = ',A12)
6002 FORMAT(' SELF SHIELDING ISOTOPE = ',F9.3)
6003 FORMAT(' RESONANCE TEMPERATURE = ',1P,E15.7)
6004 FORMAT(' RESONANCE DILUTIONS = ',1P,2E15.7)
6005 FORMAT(' ABSORPTION RATE = ',1P,E15.7)
6006 FORMAT(' FISSION RATE = ',1P,E15.7)
6007 FORMAT(' SCATTERING RATE = ',1P,E15.7)
6008 FORMAT(1P,5E15.7)
6100 FORMAT(/5X,'GROUP',10X,'DILUT',13X,'SB',11X,'NPHI',10X,'NTOT0',
> 11X,'SIGS',9X,'NUSIGF',10X,'NGOLD')
6101 FORMAT(5X,I5,1P,8E15.5)
6200 FORMAT(' TEMPERATURE = ',F10.5,10X,
> ' CROSS SECTION TABULATED AT A SINGLE TEMPERATURE')
6201 FORMAT(' TEMPERATURE = ',F10.5,10X,
> ' CROSS SECTION TABULATED AT MULTIPLE TEMPERATURES')
6202 FORMAT(' TABULATION TEMPERATURES= ',/(5F15.5))
6203 FORMAT(' INTERPOLATION FACTORS = ',1P,/(5E15.5))
END
|
