blob: 0d6678c31eba9e73692f67f282e617a869925850 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
|
*----
*
* TEST CASE uo2_295_kec1_openMP
* UO2 ROWLAND'S BENCHMARK
* DISTRIBUTED SELF-SHIELDING
* 295-GROUP JEF3.1.1 DRAGLIB
*
* Author: A. Hebert
*
*----
* Define STRUCTURES and MODULES used
*----
LINKED_LIST GEOM TRACK_SS TRACK LIBRARY LIBRARY2 CP CALC ;
SEQ_ASCII UOX_TBH ;
SEQ_BINARY TF_EXC_SS TF_EXC ;
MODULE LIB: GEO: G2S: SALT: MAC: USS: ASM: FLU: ;
INTEGER COMB0101 COMB0102 COMB0103 COMB0104 COMB0105 COMB0106 GAIN1
MODE1 :=
1 2 3 4 5 6 7 8 ; (* DISTRIBUTED SELF-SHIELDING *)
REAL RCOMB1 RCOMB2 RCOMB3 RCOMB4 RCOMB5 RCOMB6 ;
PROCEDURE assertS ;
REAL P_Zr90 P_Zr91 P_Zr92 P_Zr94 P_Zr96 :=
51.45E-02 11.22E-02 17.15E-02 17.38E-02 2.80E-02 ;
REAL N_Zr0 := 4.3241E-2 ;
REAL N_Zr90 N_Zr91 N_Zr92 N_Zr94 N_Zr96 :=
N_Zr0 P_Zr90 * N_Zr0 P_Zr91 * N_Zr0 P_Zr92 * N_Zr0 P_Zr94 *
N_Zr0 P_Zr96 * ;
INTEGER an2d := 12 ;
REAL densur := 20.0 ;
*
EVALUATE RCOMB6 := 0.4 ;
EVALUATE RCOMB1 := 0.4 SQRT RCOMB6 * ;
EVALUATE RCOMB2 := 0.7 SQRT RCOMB6 * ;
EVALUATE RCOMB3 := 0.8 SQRT RCOMB6 * ;
EVALUATE RCOMB4 := 0.9 SQRT RCOMB6 * ;
EVALUATE RCOMB5 := 0.95 SQRT RCOMB6 * ;
GEOM := GEO: :: CARCEL 8
X- REFL X+ REFL Y- REFL Y+ REFL
RADIUS 0.0 <<RCOMB1>> <<RCOMB2>> <<RCOMB3>> <<RCOMB4>>
<<RCOMB5>> <<RCOMB6>> 0.45 0.5748331
MIX <<COMB0101>> <<COMB0102>> <<COMB0103>> <<COMB0104>>
<<COMB0105>> <<COMB0106>> <<GAIN1>> <<MODE1>> <<MODE1>>
MESHX 0.0 1.2 MESHY 0.0 1.2
;
UOX_TBH := G2S: GEOM ;
TRACK_SS TF_EXC_SS := SALT: UOX_TBH ::
EDIT 3
ALLG BATCH 3
TSPC EQW2 <<an2d>> <<densur>> REND
MERGMIX
;
TRACK TF_EXC := SALT: UOX_TBH ::
EDIT 3
ALLG BATCH 3
TSPC <<an2d>> <<densur>> REND
;
*
* Subgroup projection method
LIBRARY := LIB: ::
EDIT 1
NMIX 8 (*MAXIMUM OF MATERIAL MIXTURES*)
CTRA APOL (*APOLLO TYPE TRANSPORT CORRECTION*)
ANIS 2
ADED 4 NELAS N4N N2N N3N
CALENDF 3 PT (*CALENDF TYPE PROBABILITY TABLES*)
*
MIXS LIB: DRAGON FIL: DLIB_295
MIX <<COMB0101>> 300.0 (*COMB0101*)
O16 = O16 4.6624E-2
U235 = U235 7.0803E-4 1
U238 = U238 2.2604E-2 1
MIX <<COMB0102>> COMB <<COMB0101>> 1.0 (*COMB0102*)
MIX <<COMB0103>> COMB <<COMB0101>> 1.0 (*COMB0103*)
MIX <<COMB0104>> COMB <<COMB0101>> 1.0 (*COMB0104*)
MIX <<COMB0105>> COMB <<COMB0101>> 1.0 (*COMB0105*)
MIX <<COMB0106>> COMB <<COMB0101>> 1.0 (*COMB0106*)
MIX <<GAIN1>> 300.0 (*GAIN1*)
Zr90 = Zr90 <<N_Zr90>> 2
Zr91 = Zr91 <<N_Zr91>> 2
Zr92 = Zr92 <<N_Zr92>> 2
Zr94 = Zr94 <<N_Zr94>>
Zr96 = Zr96 <<N_Zr96>>
MIX <<MODE1>> 300.0 (*MODE1*)
H1 = H1_H2O 6.6988E-2
O16 = O16 3.3494E-2
;
LIBRARY2 := USS: LIBRARY TRACK_SS TF_EXC_SS :: EDIT 1 TRAN PASS 3 GRMIN 52 ;
CP := ASM: LIBRARY2 TRACK TF_EXC :: EDIT 1 PIJ ;
CALC := FLU: CP LIBRARY2 TRACK :: EDIT 1 TYPE K ;
assertS CALC :: K-EFFECTIVE 1 1.388390 ;
ECHO "test uo2_295_kec1_openMP completed" ;
QUIT "LIST" .
|
