blob: ed0ea195e16a9ab6fac6ee86084c16ef115d0774 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
|
*----
* TEST CASE TCWU11
* CANDU-6 ANNULAR CELL
* iaea WLUP Library
* TWO GROUP BURNUP
* POWER (KW) = 615.00000
* BURN POWER (KW/KG) = 31.97130
* URANIUM MASS = 19.23600
* UO2 REAL DENSITY = 10.59300
* UO2 EFF DENSITY = 10.43750
* UO2 TEMPERATURE = 941.28998
* ENRICHMENT = 0.71140
* COOLANT D2 AT % = 99.222
* MODERATOR D2 AT % = 99.911
* NUMBER OF DAYS = 50
*
*----
* Define variables
* Burnup paremeters
* a) Power
* = 31.9713 kw/kg for 0.0 to 300.0 days
* b) 69 Groups Burnup time interval Delt
* = 300 day for 0 to 300 day
* c) 2 Groups Burnup time interval Delt
* = 1 day for 0 to 1 day
* = 4 days for 1 to 5 days
* = 5 days for 5 to 10 days
* = 10 days for 10 to 50 days
* = 20 days for 50 to 150 days
* = 50 days for 150 to 300 days
* c) Days with burnup interval changes
* = 1.0, 5.0, 10.0, 50.0, 150.0 and 300.0 days
* d) Burnup control time variables Timei, Timef
* Timei = initial time
* Timef = final time
*----
REAL
Power Delt Timec Timei Timef :=
31.9713 1.0 300.0 0.0 0.0 ;
*----
* Define STRUCTURES and MODULES used
*----
LINKED_LIST LIBRARY ;
LINKED_LIST
CANDU6S CANDU6F VOLMATS VOLMATF PIJ FLUX BURNUP EDITION ;
SEQ_BINARY
INTLINS INTLINF ;
SEQ_ASCII
res ;
MODULE
GEO: EXCELT: LIB: SHI: ASM: FLU: EVO: EDI: SPH: DELETE: END: ;
PROCEDURE assertS ;
*----
* Depletion data from file iaea format WIMSD4
* Microscopic cross sections from file iaea format WIMSD4
*----
PROCEDURE TCWU05Lib ;
INTEGER iedit := 1 ;
LIBRARY := TCWU05Lib :: <<iedit>> ;
*----
* Geometry CANDU6S : 13 regions annular cluster for self-shielding
* CANDU6F : 31 regions annular cluster for transport
*----
CANDU6S := GEO: :: TUBE 5
R+ REFL RADIUS 0.00000 5.16890 5.60320 6.44780 6.58750 16.12171
MIX 1 2 3 4 5
CLUSTER ROD1 ROD2 ROD3 ROD4
::: ROD1 := GEO: TUBE 2 MIX 6 10 NPIN 1 RPIN 0.0000 APIN 0.0000
RADIUS 0.00000 0.6122 0.6540 ;
::: ROD2 := GEO: ROD1 MIX 7 10 NPIN 6 RPIN 1.4885 APIN 0.0000 ;
::: ROD3 := GEO: ROD1 MIX 8 10 NPIN 12 RPIN 2.8755 APIN 0.261799 ;
::: ROD4 := GEO: ROD1 MIX 9 10 NPIN 18 RPIN 4.3305 APIN 0.0 ;
;
CANDU6F := GEO: CANDU6S :: SPLITR 6 1 1 1 10
::: ROD1 := GEO: ROD1 SPLITR 2 1 ;
::: ROD2 := GEO: ROD2 SPLITR 2 1 ;
::: ROD3 := GEO: ROD3 SPLITR 2 1 ;
::: ROD4 := GEO: ROD4 SPLITR 2 1 ;
;
*----
* Self-Shielding calculation EXCEL
* Transport calculation EXCEL
* Flux calculation for keff
*----
VOLMATS INTLINS := EXCELT: CANDU6S ::
TITLE 'TCWU11: FEW GROUP BURNUP / SELF-SHIELDING TRACKING'
EDIT 0 MAXR 13
ALLG BATCH 100
TRAK TISO 5 10.0 SYMM 12 ;
LIBRARY := SHI: LIBRARY VOLMATS INTLINS :: EDIT 0 NOLJ ;
VOLMATF INTLINF := EXCELT: CANDU6F ::
TITLE 'TCWU11: FEW GROUP BURNUP / TRANSPORT TRACKING'
EDIT 0 MAXR 31
ALLG BATCH 100
TRAK TISO 5 10.0 SYMM 12 ;
PIJ := ASM: LIBRARY VOLMATF INTLINF ;
FLUX := FLU: PIJ LIBRARY VOLMATF ::
TYPE K ;
assertS FLUX :: 'K-EFFECTIVE' 1 1.121035 ;
EDITION := EDI: LIBRARY VOLMATF FLUX CANDU6F ::
MERG REGI 6 6 10 7 7 10 1 1 8 8 10 1
1 9 9 10 1 1 2 3 4 5 5 5
5 5 5 5 5 5 5
COND 4.0 MICR ALL SAVE
MGEO CANDU6F
;
EDITION := SPH: EDITION VOLMATF INTLINF ;
*----
* 69 group Burnup
*----
BURNUP LIBRARY := EVO: LIBRARY FLUX VOLMATF ::
EDIT 3 EXPM 200.0 DEPL <<Timei>> <<Timec>> DAY POWR <<Power>> ;
LIBRARY := SHI: LIBRARY VOLMATS INTLINS :: EDIT 0 NOLJ ;
PIJ := DELETE: PIJ ;
PIJ := ASM: LIBRARY VOLMATF INTLINF ;
FLUX := FLU: FLUX PIJ LIBRARY VOLMATF ::
TYPE K ;
assertS FLUX :: 'K-EFFECTIVE' 1 0.9414081 ;
EDITION := EDI: EDITION LIBRARY VOLMATF FLUX CANDU6F ::
MGEO CANDU6F
;
EDITION := SPH: EDITION VOLMATF INTLINF ;
BURNUP FLUX PIJ LIBRARY INTLINS VOLMATS CANDU6S := DELETE:
BURNUP FLUX PIJ LIBRARY INTLINS VOLMATS CANDU6S ;
*----
* 2 group Burnup
*----
LIBRARY := EDITION :: STEP UP 'REF-CASE0001' ;
EDITION := DELETE: EDITION ;
PIJ := ASM: LIBRARY VOLMATF INTLINF ;
FLUX := FLU: PIJ LIBRARY VOLMATF ::
TYPE K ;
assertS FLUX :: 'K-EFFECTIVE' 1 1.121052 ;
EDITION := EDI: LIBRARY VOLMATF FLUX ::
EDIT 1 MERGE COMP MICR ALL SAVE ;
EVALUATE Timec := 1.0 ;
WHILE Timei Timec < DO
EVALUATE Timef := Timei Delt + ;
IF Timei 0.0 = THEN
BURNUP LIBRARY := EVO: LIBRARY FLUX VOLMATF ::
EDIT 3 DEPL <<Timei>> <<Timef>> DAY POWR <<Power>> ;
ELSE
BURNUP LIBRARY := EVO: BURNUP LIBRARY FLUX VOLMATF ::
EDIT 3 NOEX DEPL <<Timei>> <<Timef>> DAY POWR <<Power>> ;
ENDIF ;
PIJ := DELETE: PIJ ;
PIJ := ASM: LIBRARY VOLMATF INTLINF ;
FLUX := FLU: FLUX PIJ LIBRARY VOLMATF ::
TYPE K ;
EDITION := EDI: EDITION LIBRARY VOLMATF FLUX ::
SAVE ;
*----
* change delta t for burnup and final time if required
*----
IF Timef Timec = THEN
IF Timec 5.0 = THEN
EVALUATE Delt Timec := 5.0 10.0 ;
ENDIF ;
IF Timec 1.0 = THEN
EVALUATE Delt Timec := 4.0 5.0 ;
ENDIF ;
ENDIF ;
EVALUATE Timei := Timef ;
ENDWHILE ;
assertS FLUX :: 'K-EFFECTIVE' 1 1.075327 ;
res := EDITION ;
EDITION BURNUP FLUX PIJ LIBRARY INTLINF VOLMATF CANDU6F := DELETE:
EDITION BURNUP FLUX PIJ LIBRARY INTLINF VOLMATF CANDU6F ;
ECHO "test TCWU11 completed" ;
END: ;
QUIT "LIST" .
|
