blob: e7f8ed4dbd26608e1e871282c95e7cbcc0d896e7 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
|
*----
* TEST CASE TCDR33
* HOMOGENEOUS DEPLETION CASE WITH USER-DEFINED CHAIN
* 172-GROUP JEF2.2 DRAGLIB
*
* REF: None
*
*----
* Define variables
* Burnup paremeters
* a) Power
* = 600.0 kw/kg for 0.0 to 1000.0 days
* = 0.0 kw/kg for 1000.0 to 2000.0 days
* b) Burnup time interval Delt
* = 10 days for 0 to 50 days
* = 50 days for 50 to 500 days
* = 100 days for 500 to 1000 days
* = 1000 days for 1000 to 2000 days
* c) Editing time Timec
* = 0.0, 50.0, 500.0, 1000.0 and 2000.0 days
* d) Burnup control time variables Timei, Timef, TotalTime
* Timei = initial time
* Timef = final time
* TotalTime = Final time reached
* d) Print variable Iprint
* = 1 reduced print
* = 3 full print
*----
REAL
Power Delt Timec Timei Timef TotalTime :=
600.0 10.0 50.0 0.0 0.0 2000.0 ;
INTEGER
Iprint := 1 ;
*----
* Define STRUCTURES and MODULES used
*----
LINKED_LIST
LIBRARY HOM TRACK PIJ FLUX BURNUP EDITION ;
MODULE
GEO: SYBILT: LIB: SHI: ASM: FLU: EVO: EDI: DELETE: END: ;
PROCEDURE assertS ;
*----
* Depletion data from Jef 2.2 Draglib
* Microscopic cross sections from Jef 2.2 Draglib
*----
LIBRARY := LIB: ::
NMIX 1 CTRA WIMS
DEPL 100 CHAIN
Am243 NFTOT 222.2 NG
FROM NG 1.0000E+00 Pu242 NG 1.0000E+00 Am242
Am242 DECAY 1.55780E-02 NFTOT NG
FROM NG 2.5000E-01 Am241
Am241 NFTOT 217.1 NG
FROM DECAY 1.0000E+00 Pu241
Pu242 NFTOT 217.0 NG N2N
FROM NG 1.0000E+00 Pu241
Pu241 DECAY 1.52540E-01 NFTOT 214.0 NG N2N
FROM NG 1.0000E+00 Pu240
Pu240 NFTOT 214.1 NG N2N
FROM NG 1.0000E+00 Np239 NG 1.0000E+00 Pu239
Pu239 NFTOT 211.3 NG N2N
FROM DECAY 1.0000E+00 Np239
Np239 DECAY 3.39940E+02 NFTOT NG N2N
FROM NG 1.0000E+00 U238
U238 NFTOT 212.2 NG N2N
Np237 NFTOT 210.3 NG
FROM NG 1.0000E+00 U236
U236 NFTOT 200.3 NG
FROM NG 1.0000E+00 U235
U235 NFTOT 202.6 NG N2N
FROM NG 1.0000E+00 U234
U234 NFTOT 203.4 NG
ENDCHAIN
MIXS LIB: DRAGON FIL: DLIB_J2
MIX 1 300.0 H1 = H1 2.00000E+1
U235 = U235 1.0 1
U236 = U236 0.0 1
;
*----
* Geometry HOM : Homogeneous geometry
*----
HOM := GEO: :: HOMOGE
MIX 1 ;
*----
* Self-Shielding calculation SYBIL
* Transport calculation SYBIL
* Flux calculation for keff
*----
TRACK := SYBILT: HOM ::
TITLE 'TCDR33: HOMOGENEOUS BENCHMARK WITH BURNUP' ;
LIBRARY := SHI: LIBRARY TRACK :: EDIT 0 NOLJ ;
PIJ := ASM: LIBRARY TRACK ;
FLUX := FLU: PIJ LIBRARY TRACK ::
TYPE K ;
assertS FLUX :: 'K-EFFECTIVE' 1 1.873188 ;
EDITION := EDI: FLUX LIBRARY TRACK ::
COND 4.0 MERGE COMP SAVE ;
*----
* Burnup loop: for first step BURNUP is created
* while for other steps it is modified
*----
WHILE Timei TotalTime < DO
EVALUATE Timef := Timei Delt + ;
IF Timef Timec = THEN
EVALUATE Iprint := 3 ;
ELSE
EVALUATE Iprint := 1 ;
ENDIF ;
IF Timei 0.0 = THEN
BURNUP LIBRARY := EVO: LIBRARY FLUX TRACK ::
EDIT <<Iprint>> DEPL <<Timei>> <<Timef>> DAY
POWR <<Power>> ;
ELSE
BURNUP LIBRARY := EVO: BURNUP LIBRARY FLUX TRACK ::
EDIT <<Iprint>> NOEX DEPL <<Timei>> <<Timef>> DAY
POWR <<Power>> ;
ENDIF ;
LIBRARY := SHI: LIBRARY TRACK :: EDIT 0 NOLJ ;
PIJ := DELETE: PIJ ;
PIJ := ASM: LIBRARY TRACK ;
FLUX := FLU: FLUX PIJ LIBRARY TRACK ::
TYPE K ;
IF Iprint 3 = THEN
EDITION := EDI: EDITION FLUX LIBRARY TRACK ::
SAVE ;
ENDIF ;
*----
* change delta t for burnup, final time and power if required
*----
IF Timef Timec = THEN
IF Timec 1000.0 = THEN
EVALUATE Power Delt Timec := 0.0 1000.0 2000.0 ;
ENDIF ;
IF Timec 500.0 = THEN
EVALUATE Delt Timec := 100.0 1000.0 ;
ENDIF ;
IF Timec 50.0 = THEN
EVALUATE Delt Timec := 50.0 500.0 ;
ENDIF ;
ENDIF ;
EVALUATE Timei := Timef ;
ENDWHILE ;
assertS FLUX :: 'K-EFFECTIVE' 1 1.760241 ;
ECHO "test TCDR33 completed" ;
END: ;
QUIT "LIST" .
|
