blob: bf4081f66c517c79749241154a1b7ca6a48a3ca0 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
|
*----
* TEST CASE TCDR01
* MOSTELLER BENCHMARK: 1-D ANNULAR CELL AND 2-D CARTESIAN CELL
* 172-GROUP JEF2.2 DRAGLIB
*
* REF: R. Mosteller et al. Nucl. Sci. Eng. 107, 265 (1991)
*
*----
* Define STRUCTURES and MODULES used
*----
LINKED_LIST
MOSTELA MOSTELC DISCR LIBRARY CP CALC OUT ;
SEQ_BINARY
TRKSPC ;
MODULE
LIB: GEO: SYBILT: EXCELT: SHI: ASM: FLU: EDI: DELETE: END: ;
PROCEDURE assertS ;
*----
* Microscopic cross sections from Jef 2.2 Draglib
*----
LIBRARY := LIB: ::
NMIX 3 CTRA WIMS
MIXS LIB: DRAGON FIL: DLIB_J2
MIX 1 600.0 O16 = O16 4.61309E-2
U235 = U235 1.66078E-4 1
U238 = U238 2.28994E-2 1
MIX 2 600.0
Zr91 = Zr0 3.83243E-2
MIX 3 600.0
H1H2O = H1_H2O 4.42326E-2 O16H2O = O16 2.21163E-2
B10 = B10 2.02222E-6 B11 = B11 8.19107E-6
;
*----
* Geometry MOSTELA : annular 3 region geometry
* MOSTELC : Cartesian 3 region geometry
*----
MOSTELA := GEO: :: TUBE 3
R+ REFL RADIUS 0.0 0.39306 0.45802 0.71206 SPLITR 2 1 1
MIX 1 2 3 ;
MOSTELC := GEO: :: CARCEL 2
X- REFL X+ REFL MESHX 0.0 1.26209
Y- REFL Y+ REFL MESHY 0.0 1.26209
RADIUS 0.0 0.39306 0.45802 SPLITR 2 1
MIX 1 2 3 ;
*----
* Case 1 -- annular
* Self-Shielding calculation SYBIL
* Transport calculation SYBIL
* Flux calculation for K no leakage
*----
DISCR := SYBILT: MOSTELA ::
TITLE 'TCDR01: MOSTELLER BENCHMARK (SYBIL / SYBIL)'
MAXR 4 QUA1 5 ;
LIBRARY := SHI: LIBRARY DISCR :: EDIT 0 NOLJ ;
CP := ASM: LIBRARY DISCR ;
CALC := FLU: CP LIBRARY DISCR ::
TYPE K ;
assertS CALC :: 'K-EFFECTIVE' 1 0.8237322 ;
OUT := EDI: LIBRARY DISCR CALC ::
EDIT 4 MERG MIX 1 2 3 COND 4.0 SAVE ;
DISCR CP := DELETE: DISCR CP ;
*----
* Case 2 -- Cartesian
* Self-Shielding calculation SYBIL
* Transport calculation SYBIL
* Flux calculation for K no leakage
*----
DISCR := SYBILT: MOSTELC ::
TITLE 'TCDR01: MOSTELLER BENCHMARK (SYBIL / SYBIL)'
MAXR 4 QUA1 5 QUA2 6 5 ;
LIBRARY := SHI: LIBRARY DISCR :: EDIT 0 NOLJ ;
CP := ASM: LIBRARY DISCR ;
CALC := FLU: CALC CP LIBRARY DISCR ::
TYPE K ;
assertS CALC :: 'K-EFFECTIVE' 1 0.8239249 ;
OUT := EDI: OUT LIBRARY DISCR CALC ::
EDIT 1 MERG MIX 1 2 3 COND 4.0 STAT ALL REFE 1 ;
CALC DISCR CP := DELETE: CALC DISCR CP ;
*----
* Case 3 -- annular
* Self-Shielding calculation EXCEL-ISO
* Transport calculation EXCEL-ISO
* Flux calculation for K no leakage
*----
DISCR TRKSPC := EXCELT: MOSTELC ::
TITLE 'TCDR01: MOSTELLER BENCHMARK (EXCELL)'
MAXR 4 TRAK TISO 12 20.0 ;
LIBRARY := SHI: LIBRARY DISCR TRKSPC :: EDIT 0 NOLJ ;
CP := ASM: LIBRARY DISCR TRKSPC ;
CALC := FLU: CP LIBRARY DISCR ::
TYPE K ;
assertS CALC :: 'K-EFFECTIVE' 1 0.8247744 ;
OUT := EDI: OUT LIBRARY DISCR CALC ::
EDIT 1 MERG MIX 1 2 3 COND 4.0 STAT ALL REFE 1 ;
DISCR TRKSPC CP := DELETE: DISCR TRKSPC CP ;
*----
* Case 4 -- Cartesian
* Self-Shielding calculation EXCEL-SPC
* Transport calculation EXCEL-SPC
* Flux calculation for K no leakage
*----
DISCR TRKSPC := EXCELT: MOSTELC ::
TITLE 'TCDR01: MOSTELLER BENCHMARK (EXCELL)'
MAXR 4 TRAK TSPC 12 20.0 ;
LIBRARY := SHI: LIBRARY DISCR TRKSPC :: EDIT 0 NOLJ ;
CP := ASM: LIBRARY DISCR TRKSPC ;
CALC := FLU: CALC CP LIBRARY DISCR ::
TYPE K ;
assertS CALC :: 'K-EFFECTIVE' 1 0.8256814 ;
OUT := EDI: OUT LIBRARY DISCR CALC ::
EDIT 1 MERG MIX 1 2 3 COND 4.0 STAT ALL REFE 1 ;
DISCR TRKSPC CP := DELETE: DISCR TRKSPC CP ;
ECHO "test TCDR01 completed" ;
END: ;
QUIT "LIST" .
|
