blob: 42f1e698b69c48a2187b4a063d5c1ad74700848a (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
|
* Name: Geo15x15.c2m
* Type: DRAGON procedure
* Use: Create various geometry & tracking objects
* Author: A. Bruneau 03.2015, 04.2015
* [CS-SI | IRSN/PSN-EXP/SNC/LNR]
* V. Salino 05.2016 : ajout des cas 15x15 (Tihange)
* dont Pyrex
*-----------------------------------------------------------
PARAMETER Discr DiscrAu ::
::: LINKED_LIST
Discr DiscrAu ; ;
MODULE GEO: SYBILT: DELETE: ABORT: END: GREP: ;
PROCEDURE ThermaExpans GetTechData ;
LINKED_LIST Assmb AssmbAu Cellules Huitieme
UOX UOX_SS UOX_PY UOX_PY_SS
UOX_BLACK UOX_BLACK_SS ;
! /////////////////////////////////////////////////////////////////////
! /// Variables & Parameters ///
! /////////////////////////////////////////////////////////////////////
! ---------------------------------------------------------------------
! --- DIVERS ---
! ---------------------------------------------------------------------
STRING Gestion AssType ConfigPyrex ;
INTEGER ThermExp BarType ;
REAL tcom tmod tclad ;
INTEGER DUMMY_I0 := 0 ;
INTEGER DUMMY_I310 := 310 ;
REAL DUMMY_R0 := 0. ;
STRING Model := "TIH" ;
! ---------------------------------------------------------------------
! --- TECH DATA ---
! ---------------------------------------------------------------------
REAL NbPinAssXY ;
REAL pAss pPin hWaterGap pPinWaterGap ;
REAL rFuel rCladFuel ;
REAL rRodAICn rCladRod ;
REAL rRodBPIn rRodBPEx rCladBPIn rCladBPEx ;
REAL rTubeIn rTubeEx ;
! ---------------------------------------------------------------------
! --- DISCRETIZATION ---
! ---------------------------------------------------------------------
REAL Rfuel1 Rfuel2 Rfuel3 Rfuel4 ;
REAL rRodAICn1 rRodAICn2 rRodAICn3 ;
*-------------------------------------------------------
* Pyrex configuration provided : None Py8 Py12
*-------------------------------------------------------
:: >>Gestion<< >>AssType<< >>ConfigPyrex<< >>ThermExp<<
>>BarType<< >>tcom<< >>tmod<< ;
EVALUATE tclad := 0.12 tcom * 0.88 tmod * + ;
! /////////////////////////////////////////////////////////////////////
! /// GET DATA LISTS ///
! /////////////////////////////////////////////////////////////////////
LINKED_LIST Distances General ;
Distances := GetTechData :: <<Gestion>> <<AssType>>
<<DUMMY_I0>> 'None' 'DISTANCES' ;
General := GetTechData :: <<Gestion>> <<AssType>>
<<DUMMY_I0>> 'None' 'GENERAL' ;
! /////////////////////////////////////////////////////////////////////
! /// GET DATA VALUES ///
! /////////////////////////////////////////////////////////////////////
! ---------------------------------------------------------------------
! --- Distances ---
! ---------------------------------------------------------------------
! ***gen***
GREP: Distances :: GETVAL 'pAss' 1 >>pAss<< ;
GREP: Distances :: GETVAL 'pPin' 1 >>pPin<< ;
! ***radius pin content***
GREP: Distances :: GETVAL 'rFuel' 1 >>rFuel<< ;
GREP: Distances :: GETVAL 'rRodAICn' 1 >>rRodAICn<< ;
GREP: Distances :: GETVAL 'rRodBPIn' 1 >>rRodBPIn<< ;
GREP: Distances :: GETVAL 'rRodBPEx' 1 >>rRodBPEx<< ;
! ***radius clad***
GREP: Distances :: GETVAL 'rCladFuel' 1 >>rCladFuel<< ;
GREP: Distances :: GETVAL 'rCladRod' 1 >>rCladRod<< ;
GREP: Distances :: GETVAL 'rCladBPIn' 1 >>rCladBPIn<< ;
GREP: Distances :: GETVAL 'rCladBPEx' 1 >>rCladBPEx<< ;
! ***assembly structure***
GREP: Distances :: GETVAL 'rTubeIn' 1 >>rTubeIn<< ;
GREP: Distances :: GETVAL 'rTubeEx' 1 >>rTubeEx<< ;
! ---------------------------------------------------------------------
! --- General ---
! ---------------------------------------------------------------------
GREP: General :: GETVAL 'NbPinAssXY' 1 >>NbPinAssXY<< ;
! ---------------------------------------------------------------------
! --- Cold Half Water Gap ---
! ---------------------------------------------------------------------
EVALUATE hWaterGap := pAss pPin NbPinAssXY * - 2. / ;
! /////////////////////////////////////////////////////////////////////
! /// THERMALEXPANSION ///
! /////////////////////////////////////////////////////////////////////
ECHO "@@@@@@@@@@@ DISTANCES BEFORE (THERMAL EXPANSION) @@@@@@@@@@@" ;
ECHO " pAss = " pAss " at 20 C." ;
ECHO " pPin = " pPin " at 20 C." ;
ECHO " rFuel = " rFuel " at 20 C." ;
ECHO " rRodAICn = " rRodAICn " at 20 C." ;
ECHO " rRodBPIn = " rRodBPIn " at 20 C." ;
ECHO " rRodBPEx = " rRodBPEx " at 20 C." ;
ECHO " rCladFuel = " rCladFuel " at 20 C." ;
ECHO " rCladRod = " rCladRod " at 20 C." ;
ECHO " rCladBPIn = " rCladBPIn " at 20 C." ;
ECHO " rCladBPEx = " rCladBPEx " at 20 C." ;
ECHO " rTubeIn = " rTubeIn " at 20 C." ;
ECHO " rTubeEx = " rTubeEx " at 20 C." ;
ECHO " hWaterGap = " hWaterGap " at 20 C." ;
IF ThermExp 1 = THEN
! ---------------------------------------------------------------------
! --- Assembly and pin pitches ---
! ---------------------------------------------------------------------
ThermaExpans :: <<pAss>> "SS304" <<tmod>> "Distance" <<Model>>
<<DUMMY_R0>> <<DUMMY_R0>>
>>pAss<< ;
ThermaExpans :: <<pPin>> "In718" <<tmod>> "Distance" <<Model>>
<<DUMMY_R0>> <<DUMMY_R0>>
>>pPin<< ;
! ---------------------------------------------------------------------
! --- Fuel Pin ---
! ---------------------------------------------------------------------
ThermaExpans :: <<rFuel>> "UO2" <<tcom>> "Distance" <<Model>>
<<DUMMY_R0>> <<DUMMY_R0>>
>>rFuel<< ;
ThermaExpans :: <<rCladFuel>> "Zr4" <<tclad>> "Distance" <<Model>>
<<DUMMY_R0>> <<DUMMY_R0>>
>>rCladFuel<< ;
! ---------------------------------------------------------------------
! --- Control Rod Pin (SS / AICg /AICn / B4C) ---
! ---------------------------------------------------------------------
ThermaExpans :: <<rRodAICn>> "AIC" <<tmod>> "Distance" <<Model>>
<<DUMMY_R0>> <<DUMMY_R0>>
>>rRodAICn<< ;
ThermaExpans :: <<rCladRod>> "SS304" <<tmod>> "Distance" <<Model>>
<<DUMMY_R0>> <<DUMMY_R0>>
>>rCladRod<< ;
! ---------------------------------------------------------------------
! --- Poison Consommable Pyrex / Hafnium ---
! ---------------------------------------------------------------------
ThermaExpans :: <<rRodBPIn>> "Pyrex" <<tmod>> "Distance" <<Model>>
<<DUMMY_R0>> <<DUMMY_R0>>
>>rRodBPIn<< ;
ThermaExpans :: <<rRodBPEx>> "Pyrex" <<tmod>> "Distance" <<Model>>
<<DUMMY_R0>> <<DUMMY_R0>>
>>rRodBPEx<< ;
ThermaExpans :: <<rCladBPIn>> "SS304" <<tmod>> "Distance" <<Model>>
<<DUMMY_R0>> <<DUMMY_R0>>
>>rCladBPIn<< ;
ThermaExpans :: <<rCladBPEx>> "SS304" <<tmod>> "Distance" <<Model>>
<<DUMMY_R0>> <<DUMMY_R0>>
>>rCladBPEx<< ;
! ---------------------------------------------------------------------
! --- Guide Tube / Instrumentation ---
! ---------------------------------------------------------------------
ThermaExpans :: <<rTubeIn>> "Zr4" <<tmod>> "Distance" <<Model>>
<<DUMMY_R0>> <<DUMMY_R0>>
>>rTubeIn<< ;
ThermaExpans :: <<rTubeEx>> "Zr4" <<tmod>> "Distance" <<Model>>
<<DUMMY_R0>> <<DUMMY_R0>>
>>rTubeEx<< ;
ENDIF ;
! ---------------------------------------------------------------------
! --- Half Water Gap ---
! ---------------------------------------------------------------------
EVALUATE hWaterGap := pAss NbPinAssXY pPin * - 2. / ;
EVALUATE pPinWaterGap := pPin hWaterGap + ;
ECHO "@@@@@@@@@@@ DISTANCES AFTER (THERMAL EXPANSION) @@@@@@@@@@@" ;
ECHO " pAss = " pAss " at " tmod "C." ;
ECHO " pPin = " pPin " at " tmod "C." ;
ECHO " rFuel = " rFuel " at " tcom "C." ;
ECHO " rRodAICn = " rRodAICn " at " tmod "C." ;
ECHO " rRodBPIn = " rRodBPIn " at " tmod "C." ;
ECHO " rRodBPEx = " rRodBPEx " at " tmod "C." ;
ECHO " rCladFuel = " rCladFuel " at " tclad "C." ;
ECHO " rCladRod = " rCladRod " at " tmod "C." ;
ECHO " rCladBPIn = " rCladBPIn " at " tmod "C." ;
ECHO " rCladBPEx = " rCladBPEx " at " tmod "C." ;
ECHO " rTubeIn = " rTubeIn " at " tmod "C." ;
ECHO " rTubeEx = " rTubeEx " at " tmod "C." ;
ECHO " hWaterGap = " hWaterGap " at " tmod "C." ;
! /////////////////////////////////////////////////////////////////////
! /// DISCRETISATION ///
! /////////////////////////////////////////////////////////////////////
*------------------------------------------------------
* Evaluate Radii:
* Fuel: r1 = ( .50 x rFuel^2 )^1/2
* r2 = ( .80 x rFuel^2 )^1/2
* r3 = ( .95 x rFuel^2 )^1/2
* r4 = rFuel
*
* Gado: r1 = ( .20 x rFuel^2 )^1/2
* r2 = ( .40 x rFuel^2 )^1/2
* r3 = ( .60 x rFuel^2 )^1/2
* r4 = ( .80 x rFuel^2 )^1/2
* r5 = ( .95 x rFuel^2 )^1/2
* r6 = rFuel
*------------------------------------------------------
EVALUATE Rfuel1 := rFuel .50 SQRT * ;
EVALUATE Rfuel2 := rFuel .80 SQRT * ;
EVALUATE Rfuel3 := rFuel .95 SQRT * ;
EVALUATE Rfuel4 := rFuel ;
*------------------------------------------------------
* Materiaux de base: 1 -> 9
* Moderateurs: 10 -> 19
* Structures: Tubes 20
* Barres 21 -> 29
* Gaines 30 -> 39
* Combustibles: UOX 100 -> Nmix
*------------------------------------------------------
* Materiaux de base
* 1 - SS304
* 2 - Inconel
* 3 - Zircalloy-4
* 4 - Grilles precalculees
* 5 - Eau boree
* 6 - Isotopes de barre virtuelle
* 7 - Eau boree tube instrumentation
* Moderateurs
* 10 - MODE [moderateur cellule centrale]
* 11 - MODEL [moderateur cellule en peripherie (avec lame d'eau)]
* 12 - MODEC [moderateur cellule en coin (double lame d'eau)]
* 13 - MODETI [moderateur cellule tube (interieur du tube)+Isotopes de barres AIC a 0]
* 14 - MODETE [moderateur cellule tube (exterieur du tube)]
* 15 - MODETII [moderateur cellule tube (interieur du tube d'instrumentation)]
* Structures: Tubes
* 20 - TUBE
* Structures: Barres
* 21 - AIC [Barres AIC]
* Structures: Gaines
* 30 - GAINC [Gaine combustible UOX/MOX/UGd]
* 34 - GAINE BP INT ACIER SS304
* 35 - GAINE BP EXT ACIER SS304
* 37 - GAINA [Gaine Barres AICn]
* Structures: Barres (suite)
* 41 - AIC [Barres AIC 1ere couronne]
* 42 - AIC [Barres AIC 2e couronne]
* 43 - AIC [Barres AIC 3e couronne]
* Poison consommable (Pyrex)
* 59 - Air
* 65 - PYREX
* Combustibles UOX
* 100 - COMB [UOX 1ere couronne (centre a Rcomb*0.5^1/2) <=> 0 a r1]
* 101 - COMB [UOX 2e couronne]
* 102 - COMB [UOX 3e couronne]
* 103 - COMB [UOX 4e couronne (r3 a Rcomb)]
*------------------------------------------------------
Cellules := GEO: ::
::: T := GEO: CARCEL 2
MESHX 0. <<pPin>>
MESHY 0. <<pPin>>
RADIUS 0. <<rTubeIn>> <<rTubeEx>>
MIX 13 20 14 ;
::: C1 := GEO: CARCEL 5
MESHX 0. <<pPin>>
MESHY 0. <<pPin>>
RADIUS 0. <<Rfuel1>> <<Rfuel2>> <<Rfuel3>> <<Rfuel4>> <<rCladFuel>>
MIX 100 101 102 103 30 10 ;
::: C2 := GEO: C1 MESHX 0. <<pPinWaterGap>> MIX 100 101 102 103 30 11 ;
::: C3 := GEO: C2 MESHY 0. <<pPinWaterGap>> MIX 100 101 102 103 30 12 ;
::: Py := GEO: CARCEL 6
MESHX 0. <<pPin>>
MESHY 0. <<pPin>>
RADIUS 0.0 <<rCladBPIn>> <<rRodBPIn>> <<rRodBPEx>>
<<rCladBPEx>> <<rTubeIn>> <<rTubeEx>>
MIX 59 34 65 35 13 20 14 ;
::: R := GEO: CARCEL 4
MESHX 0. <<pPin>>
MESHY 0. <<pPin>>
RADIUS 0. <<rRodAICn>> <<rCladRod>> <<rTubeIn>> <<rTubeEx>>
MIX 41 37 13 20 14 ;
;
Huitieme := GEO: Cellules :: CAR2D 8 8
X- DIAG X+ REFL
Y- SYME Y+ DIAG ;
*------------------------------------------------------
* T : TUBE_GUIDE
* C1 : CELLULE_COMBUSTIBLE_CENTRALE
* C2 : CELLULE_COMBUSTIBLE_LATERALE
* C3 : CELLULE_COMBUSTIBLE_COIN
* Py : Pyrex rod
* R : CELLULE_ABSORBANT_AIC
*------------------------------------------------------
UOX := GEO: Huitieme ::
CELL T C1 C1 C1 T C1 C1 C2
C1 C1 C1 C1 C1 C1 C2
C1 C1 C1 T C1 C2
T C1 C1 C1 C2
C1 C1 C1 C2
T C1 C2
C1 C2
C3 ;
*------------------------------------------------------
* UOX Assembly
* 15 X 15 UOX 900MWe Tihange PWR assembly without Rods
*------------------------------------------------------
UOX_SS := GEO: UOX ::
MERGE 1 2 2 2 1 2 2 4
2 2 2 2 2 2 4
2 2 2 1 2 4
1 2 2 2 4
2 2 2 4
1 2 4
2 4
3 ;
IF ConfigPyrex "Py8" = THEN
*------------------------------------------------------
* UOX Assembly
* 15 X 15 UOX 900MWe Tihange PWR assembly with 8 Pyrex rods
*------------------------------------------------------
UOX_PY := GEO: Huitieme ::
CELL T C1 C1 C1 Py C1 C1 C2
C1 C1 C1 C1 C1 C1 C2
C1 C1 C1 T C1 C2
Py C1 C1 C1 C2
C1 C1 C1 C2
T C1 C2
C1 C2
C3 ;
UOX_PY_SS := GEO: UOX_PY ::
* Merging region #5 = Pyrex
MERGE 1 2 2 2 5 2 2 4
2 2 2 2 2 2 4
2 2 2 1 2 4
5 2 2 2 4
2 2 2 4
1 2 4
2 4
3 ;
ELSEIF ConfigPyrex "Py12" = THEN
*------------------------------------------------------
* UOX Assembly
* 15 X 15 UOX 900MWe Tihange PWR assembly with 12 Pyrex rods
*------------------------------------------------------
UOX_PY := GEO: Huitieme ::
CELL T C1 C1 C1 Py C1 C1 C2
C1 C1 C1 C1 C1 C1 C2
C1 C1 C1 T C1 C2
Py C1 C1 C1 C2
C1 C1 C1 C2
Py C1 C2
C1 C2
C3 ;
UOX_PY_SS := GEO: UOX_PY ::
* Merging region #5 = Pyrex
MERGE 1 2 2 2 5 2 2 4
2 2 2 2 2 2 4
2 2 2 1 2 4
5 2 2 2 4
2 2 2 4
5 2 4
2 4
3 ;
ENDIF ;
*------------------------------------------------------
* UOX Assembly with 'Black' Rods
* 15 X 15 UOX 900MWe Tihange PWR assembly with AIC Control Rods
*------------------------------------------------------
UOX_BLACK := GEO: UOX ::
CELL T C1 C1 C1 R C1 C1 C2
C1 C1 C1 C1 C1 C1 C2
C1 C1 C1 R C1 C2
R C1 C1 C1 C2
C1 C1 C1 C2
R C1 C2
C1 C2
C3 ;
UOX_BLACK_SS := GEO: UOX_BLACK ::
* Merging region #5 = AIC
MERGE 1 2 2 2 5 2 2 4
2 2 2 2 2 2 4
2 2 2 5 2 4
5 2 2 2 4
2 2 2 4
5 2 4
2 4
3 ;
! /////////////////////////////////////////////////////////////////////
! /// BARR TYPE SELECTOR ///
! /////////////////////////////////////////////////////////////////////
IF BarType 1 = THEN ! 1 = Pas de BARR [nominal]
Assmb := UOX ;
AssmbAu := UOX_SS ;
ELSEIF BarType 2 = THEN ! 2 = AICN
Assmb := UOX_BLACK ;
AssmbAu := UOX_BLACK_SS ;
ELSEIF BarType 4 = THEN ! 4 = PY (Pyrex)
Assmb := UOX_PY ;
AssmbAu := UOX_PY_SS ;
ELSE
ECHO "Unknown BarType" ;
ABORT: ;
ENDIF ;
! /////////////////////////////////////////////////////////////////////
! /// DISCRETISATION SETTING ///
! /////////////////////////////////////////////////////////////////////
INTEGER imax := 1000000 ;
Discr := SYBILT: Assmb :: MAXZ <<imax>> MAXR <<imax>>
QUA2 3 3 GAUSS DP01 ;
DiscrAu := SYBILT: AssmbAu :: MAXZ <<imax>> MAXR <<imax>>
QUA2 3 3 GAUSS DP01 ;
END: ;
QUIT "LIST" .
|
