blob: 20d3d475c9b6106300aa4fab9c41acba0587f095 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
|
*======================================================================
* Name : testNAPhet.x2m
* Type : DONJON File
*
* Use : Input file to perform PPR
* Notes:
* 1) Homogenization can be homogeneous or heterogeneous
* 2) The pin-by-pin geometry is also created to be able to visualize it
*----------------------------------------------------------------------
* Donjon: v5.0.1_ev346 modified (or more recent)
*----------------------------------------------------------------------
*
* Author : R. Chambon (06/2014)
*
* modified : R. Chambon (09/2015)
* Note: The '_ACPOenrichU0' enrich multicompo can be obtained by running
* ----- twice the 'rep900EnrichCOMPOhet.x2m' input file once for
* homogeneous option and once for heterogeneous option.
*
SEQ_ASCII ACOMPOU :: FILE '_ACPOenrichU0' ;
SEQ_ASCII ACOMPOR :: FILE '_ACompo' ;
*
SEQ_ASCII AGEO1 :: FILE 'AGEO1' ;
SEQ_ASCII AGEOH AmapH AMatH :: FILE 'AGEOH' 'AmapH' 'AMatH' ;
SEQ_ASCII AMFH AMACROH AMACR :: FILE 'AMFH' 'AMACROH' 'AMACR' ;
SEQ_ASCII AFLU ATRK :: FILE 'AFLU_NAP' 'ATRK_NAP' ;
LINKED_LIST CpoU CpoR DONNEES Geo1
GeoH MatexH FmapH MacroFH Macro2H
GeoP
CpoRefl Micro Macro
Track System Flux
FmapH2 FmapH3 PowerIter
;
PROCEDURE assertS ;
*
MODULE GEO: USPLIT: RESINI: MACINI: NCR: NAP:
TRIVAA: TRIVAT: FLUD: FLPOW:
END: DELETE: GREP: UTL: ABORT: ;
*
STRING Fuel := "UOX" ; ! UOX
INTEGER npin maxr ;
REAL BURN1 BURN2 BURN3 := 0. 0. 0. ;
REAL CBOR := 600. ;
REAL Cote Lame mx1 mx2 mx3 mx4 mx5 mx6 Size wat ;
REAL Ptot := 9.0 ; ! MW
EVALUATE npin := 17 ;
*
EVALUATE Cote := 1.26 ;
EVALUATE Lame := 0.04 ;
EVALUATE wat := 10. ;
EVALUATE Size := npin I_TO_R Cote * Lame 2. * + ;
EVALUATE mx1 := Size -1.5 * wat - ;
EVALUATE mx2 := Size -1.5 * ;
EVALUATE mx3 := Size -0.5 * ;
EVALUATE mx4 := Size 0.5 * ;
EVALUATE mx5 := Size 1.5 * ;
EVALUATE mx6 := Size 1.5 * wat + ;
*
STRING TypeCompo := "Homog" ; ! Homog : homogeneous properties
! Heter : heterogeneous (3 mix) properties
! PinByPin : PinByPin properties
STRING DirAss := "Ass " ; ! the name used in the multicompo
! Homog Ass
! PinByPin Pin
! Heter Het1
INTEGER ifx := 0 ; ! ifx value used in the enrich multicompo
! Homog 0
! Heter 1
STRING DirR := "EDI2B " ;
STRING AutoAss := "Manual" ; ! Definition of assembly in FmapH
! "Auto" done by NAP
! "Manual" by the user directly in the input
! for homogeneous properties only
*
CpoU := ACOMPOU ;
CpoR := ACOMPOR ;
!--------------------------
!--------------------------
* Test NAP: Geometry part
!--------------------------
! Build geometry for homogeneous assembly
Geo1 := GEO: :: CAR3D 5 5 4
EDIT 0
X- VOID X+ VOID
Y- VOID Y+ VOID
Z- VOID Z+ VOID
MIX
PLANE 1
0 4 4 4 0
4 4 4 4 4
4 4 4 4 4
4 4 4 4 4
0 4 4 4 0
PLANE 2
0 4 4 4 0
4 3 2 3 4
4 2 1 2 4
4 3 2 3 4
0 4 4 4 0
PLANE 3 SAME 2
PLANE 4 SAME 1
MESHX <<mx1>> <<mx2>> <<mx3>> <<mx4>> <<mx5>> <<mx6>>
MESHY <<mx1>> <<mx2>> <<mx3>> <<mx4>> <<mx5>> <<mx6>>
MESHZ 0. 10. 110. 210. 220.
SPLITX 2 1 1 1 2
SPLITY 2 1 1 1 2
SPLITZ 2 1 1 2
;
IF TypeCompo "Homog" = THEN
ECHO " Build geometry for homogeneous assembly " ;
GeoH := NAP: Geo1 CpoU ::
EDIT 100
DIRGEO <<DirAss>>
MIXASS 3 1 2 3
SPLITX-ASS 2
SPLITY-ASS 2
;
! Max reg=(2+2*3+2)^2*6=600
EVALUATE maxr := 600 ;
ELSEIF TypeCompo "Heter" = THEN
ECHO " Build geometry for heterogeneous assembly " ;
GeoH := NAP: Geo1 CpoU ::
EDIT 100
DIRGEO <<DirAss>>
MIXASS 3 1 2 3
SPLITX-ASS 1 2 1
SPLITY-ASS 1 2 1
;
! Max reg=(2+4*3+2)^2*6=1536
EVALUATE maxr := 1536 ;
ELSEIF TypeCompo "PinByPin" = THEN
ECHO " Build geometry for pin-by-pin assembly " ;
GeoH := NAP: Geo1 CpoU ::
EDIT 100
DIRGEO <<DirAss>>
MIXASS 3 1 2 3
;
! Max reg=(2+17*3+2)^2*6=18150
EVALUATE maxr := 18150 ;
ENDIF ;
AGEO1 := Geo1 ;
AGEOH := GeoH ;
!AGEOP := GeoP ;
* Max reg=(2+4*3+2)^2*6=1536
IF AutoAss "Auto" = THEN
GeoH MatexH := USPLIT: GeoH ::
NGRP 2 MAXR 1536
NREFL 1 RMIX 4
NFUEL ASBLY
;
ELSEIF AutoAss "Manual" = THEN
GeoH MatexH := USPLIT: GeoH ::
NGRP 2 MAXR 1536
NREFL 1 RMIX 4
NFUEL 6 FMIX 1 5 ! Homog
2 6
3 7
;
ENDIF ;
Track := TRIVAT: GeoH ::
MAXR <<maxr>> DUAL 3 3 ;
ATRK := Track ;
!--------------------------
* Test NAP: Geometry part embedded in RESINI:
!--------------------------
IF TypeCompo "Homog" = AutoAss "Auto" = * THEN
ECHO " Build map for homogeneous assembly (auto)" ;
FmapH MatexH := RESINI: MatexH CpoU ::
EDIT 0
:::
SPLIT-NAP:
GEO:
CAR3D 5 5 4
EDIT 10
X- VOID X+ VOID
Y- VOID Y+ VOID
Z- VOID Z+ VOID
MIX
PLANE 1
0 0 0 0 0
0 0 0 0 0
0 0 0 0 0
0 0 0 0 0
0 0 0 0 0
PLANE 2
0 0 0 0 0
0 3 2 3 0
0 2 1 2 0
0 3 2 3 0
0 0 0 0 0
PLANE 3 SAME 2
PLANE 4 SAME 1
MESHX <<mx1>> <<mx2>> <<mx3>> <<mx4>> <<mx5>> <<mx6>>
MESHY <<mx1>> <<mx2>> <<mx3>> <<mx4>> <<mx5>> <<mx6>>
MESHZ 0. 10. 110. 210. 220.
;
::: NAP:
DIRGEO <<DirAss>>
MIXASS 3 1 2 3
MAX-MIX-GEO 4
;
ASSEMBLY 9 3 3
A-ZONE
ASBLY
AXNAME '1' '2' '3'
AYNAME 'A' 'B' 'C'
NXNAME '-' '1' '2' '3' '-'
NYNAME '-' 'A' 'B' 'C' '-'
NCOMB ASBLY
ADD-PARAM PNAME 'ppmBore' PARKEY 'ppmBore' GLOBAL
;
ELSEIF TypeCompo "Homog" = AutoAss "Manual" = * THEN
ECHO " Build map for homogeneous assembly (manual)" ;
FmapH MatexH := RESINI: MatexH ::
EDIT 0
:::
GEO:
CAR3D 5 5 4
EDIT 10
X- VOID X+ VOID
Y- VOID Y+ VOID
Z- VOID Z+ VOID
MIX
PLANE 1
0 0 0 0 0
0 0 0 0 0
0 0 0 0 0
0 0 0 0 0
0 0 0 0 0
PLANE 2
0 0 0 0 0
0 3 2 3 0
0 2 1 2 0
0 3 2 3 0
0 0 0 0 0
PLANE 3 SAME 2
PLANE 4 SAME 1
MESHX <<mx1>> <<mx2>> <<mx3>> <<mx4>> <<mx5>> <<mx6>>
MESHY <<mx1>> <<mx2>> <<mx3>> <<mx4>> <<mx5>> <<mx6>>
MESHZ 0. 10. 110. 210. 220.
;
ASSEMBLY 9 3 3
A-ZONE
1 2 3
4 5 6
7 8 9
A-NX 3 3 3
A-IBX 1 1 1
! !---
AXNAME '1' '2' '3'
AYNAME 'A' 'B' 'C'
NXNAME '-' '1' '2' '3' '-'
NYNAME '-' 'A' 'B' 'C' '-'
NCOMB ASBLY
ADD-PARAM PNAME 'ppmBore' PARKEY 'ppmBore' GLOBAL
;
ELSEIF TypeCompo "Heter" = THEN
ECHO " Build map for heterogeneous assembly " ;
FmapH MatexH := RESINI: MatexH CpoU ::
EDIT 1000
:::
SPLIT-NAP:
GEO:
CAR3D 5 5 4
EDIT 10
X- VOID X+ VOID
Y- VOID Y+ VOID
Z- VOID Z+ VOID
MIX
PLANE 1
0 0 0 0 0
0 0 0 0 0
0 0 0 0 0
0 0 0 0 0
0 0 0 0 0
PLANE 2
0 0 0 0 0
0 3 2 3 0
0 2 1 2 0
0 3 2 3 0
0 0 0 0 0
PLANE 3 SAME 2
PLANE 4 SAME 1
MESHX <<mx1>> <<mx2>> <<mx3>> <<mx4>> <<mx5>> <<mx6>>
MESHY <<mx1>> <<mx2>> <<mx3>> <<mx4>> <<mx5>> <<mx6>>
MESHZ 0. 10. 110. 210. 220.
;
::: NAP:
DIRGEO <<DirAss>>
MIXASS 3 1 2 3
MAX-MIX-GEO 4
;
ASSEMBLY 9 3 3
A-ZONE
ASBLY
AXNAME '1' '2' '3'
AYNAME 'A' 'B' 'C'
NXNAME '-' '1' '1' '1' '2' '2' '2' '3' '3' '3' '-'
NYNAME '-' 'A' 'A' 'A' 'B' 'B' 'B' 'C' 'C' 'C' '-'
NCOMB ASBLY
ADD-PARAM PNAME 'ppmBore' PARKEY 'ppmBore' GLOBAL
;
ELSEIF TypeCompo "PinByPin" = THEN
ECHO " Build map for heterogeneous assembly " ;
FmapH MatexH := RESINI: MatexH CpoU ::
EDIT 0
:::
SPLIT-NAP:
GEO:
CAR3D 5 5 4
EDIT 10
X- VOID X+ VOID
Y- VOID Y+ VOID
Z- VOID Z+ VOID
MIX
PLANE 1
0 0 0 0 0
0 0 0 0 0
0 0 0 0 0
0 0 0 0 0
0 0 0 0 0
PLANE 2
0 0 0 0 0
0 3 2 3 0
0 2 1 2 0
0 3 2 3 0
0 0 0 0 0
PLANE 3 SAME 2
PLANE 4 SAME 1
MESHX <<mx1>> <<mx2>> <<mx3>> <<mx4>> <<mx5>> <<mx6>>
MESHY <<mx1>> <<mx2>> <<mx3>> <<mx4>> <<mx5>> <<mx6>>
MESHZ 0. 10. 110. 210. 220.
;
::: NAP:
DIRGEO <<DirAss>>
MIXASS 3 1 2 3
MAX-MIX-GEO 4
;
ASSEMBLY 9 3 3
A-ZONE
ASBLY
AXNAME '1' '2' '3'
AYNAME 'A' 'B' 'C'
NXNAME '-' '1' '1' '1' '1' '1' '1' '1' '1' '1'
'1' '1' '1' '1' '1' '1' '1' '1'
'2' '2' '2' '2' '2' '2' '2' '2' '2'
'2' '2' '2' '2' '2' '2' '2' '2'
'3' '3' '3' '3' '3' '3' '3' '3' '3'
'3' '3' '3' '3' '3' '3' '3' '3'
'-'
NYNAME '-' 'A' 'A' 'A' 'A' 'A' 'A' 'A' 'A' 'A'
'A' 'A' 'A' 'A' 'A' 'A' 'A' 'A'
'B' 'B' 'B' 'B' 'B' 'B' 'B' 'B' 'B'
'B' 'B' 'B' 'B' 'B' 'B' 'B' 'B'
'C' 'C' 'C' 'C' 'C' 'C' 'C' 'C' 'C'
'C' 'C' 'C' 'C' 'C' 'C' 'C' 'C'
'-'
NCOMB ASBLY
ADD-PARAM PNAME 'ppmBore' PARKEY 'ppmBore' GLOBAL
;
ENDIF ;
FmapH := RESINI: FmapH :: EDIT 2
BTYPE INST-BURN
INST-BVAL ASBL
<<BURN3>> <<BURN2>> <<BURN3>>
<<BURN2>> <<BURN1>> <<BURN2>>
<<BURN3>> <<BURN2>> <<BURN3>>
SET-PARAM 'ppmBore' 0.0
;
AMatH := MatexH ;
!--------------------------
* Test NCR: assembly related keywords
!--------------------------
! Compute cross-section for heterogeneous assembly
IF AutoAss "Auto" = THEN
MacroFH := NCR: CpoU FmapH ::
EDIT 0
MACRO
LINEAR
TABLE CpoU <<DirAss>> 'burnup'
MIX 1 ASBLY INST-BURN
SET 'burnup' 0.0
SET 'ppmBore' <<CBOR>>
SET 'TF' 800.0
SET 'DCA' 0.659
SET 'TCA' 600.0
SET 'BARR' 0.0
ENDMIX
MIX 2 ASBLY INST-BURN
SET 'burnup' 0.0
SET 'ppmBore' <<CBOR>>
SET 'TF' 800.0
SET 'DCA' 0.659
SET 'TCA' 600.0
SET 'BARR' 0.0
ENDMIX
MIX 3 ASBLY INST-BURN
SET 'burnup' 0.0
SET 'ppmBore' <<CBOR>>
SET 'TF' 800.0
SET 'DCA' 0.659
SET 'TCA' 600.0
SET 'BARR' 0.0
ENDMIX
;
ELSEIF AutoAss "Manual" = THEN ! for homogene only
MacroFH := NCR: CpoU FmapH ::
EDIT 100
MACRO
LINEAR
TABLE CpoU <<DirAss>> 'burnup'
!* look back at mixture renumbering earlier, USPLIT: module
!* homogene
MIX 1 FROM 1 INST-BURN
SET 'burnup' 0.0
SET 'ppmBore' <<CBOR>>
SET 'TF' 800.0
SET 'DCA' 0.659
SET 'TCA' 600.0
SET 'BARR' 0.0
ENDMIX
MIX 2 FROM 1 INST-BURN
SET 'burnup' 0.0
SET 'ppmBore' <<CBOR>>
SET 'TF' 800.0
SET 'DCA' 0.659
SET 'TCA' 600.0
SET 'BARR' 0.0
ENDMIX
MIX 3 FROM 1 INST-BURN
SET 'burnup' 0.0
SET 'ppmBore' <<CBOR>>
SET 'TF' 800.0
SET 'DCA' 0.659
SET 'TCA' 600.0
SET 'BARR' 0.0
ENDMIX
MIX 5 FROM 1 INST-BURN
SET 'burnup' 0.0
SET 'ppmBore' <<CBOR>>
SET 'TF' 800.0
SET 'DCA' 0.659
SET 'TCA' 600.0
SET 'BARR' 0.0
ENDMIX
MIX 6 FROM 1 INST-BURN
SET 'burnup' 0.0
SET 'ppmBore' <<CBOR>>
SET 'TF' 800.0
SET 'DCA' 0.659
SET 'TCA' 600.0
SET 'BARR' 0.0
ENDMIX
MIX 7 FROM 1 INST-BURN
SET 'burnup' 0.0
SET 'ppmBore' <<CBOR>>
SET 'TF' 800.0
SET 'DCA' 0.659
SET 'TCA' 600.0
SET 'BARR' 0.0
ENDMIX
;
ENDIF ;
AMFH := MacroFH ;
Micro := NCR: CpoR ::
* dummy reflector -- please use more realistic data
EDIT 0
LINEAR NMIX 4
COMPO CpoR <<DirR>>
MIX 4 SET 'burnup' 0.0
SET 'ppmBore' 0.0
ENDMIX
;
Macro := Micro :: STEP UP MACROLIB ;
AMACR := Macro ;
Micro := DELETE: Micro ;
Macro2H MatexH := MACINI: MatexH Macro MacroFH ::
EDIT 0
;
AMACROH := Macro2H ;
* Compute flux distribution
System := TRIVAA: Macro2H Track ;
Flux := FLUD: System Track ::
EDIT 0
ADI 4
EXTE 500 0.00001
;
AFLU := Flux ;
REAL keff2 ;
GREP: Flux ::
GETVAL 'K-EFFECTIVE ' 1 >>keff2<< ;
ECHO "CBOR=" CBOR "K-effective 2 = " keff2 ;
PowerIter FmapH := FLPOW: FmapH Flux Track MatexH ::
EDIT 5 PTOT <<Ptot>> PRINT DISTR POWER ;
* Perform PPR
IF TypeCompo "Homog" = TypeCompo "Heter" = + THEN
FmapH := NAP: FmapH Track Flux MatexH MacroFH ::
EDIT 4
PPR
NZASS 2
METH GPPR <<ifx>>
;
ENDIF ;
AmapH := FmapH ;
FmapH2 := FmapH ::
STEP UP ASSEMBLY
STEP AT 1
;
FmapH2 := UTL: FmapH2 ::
DIR
;
assertS FmapH2 :: 'ASS-POWER' 1 6.361761E02 ;
ECHO "test testNAPhet.x2m completed" ;
END: ;
QUIT .
|
