blob: 20181de81c05b9dbad9052ccd9f9e6774f3459f1 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
|
*DECK BibCellG2.c2m
*----------
* Nom : BibCellG2.c2m
* Type : procedure DRAGON
* Usage : Definir bibliotheque pour cellule G-2
* Auteur : G. Marleau
* Date : 2002/12/03
*
* Description de la procedure :
*
* Biblio := BibCellG2 [Biblio ConcEvol] ::
* <<RefLib>> <<BibOpt>>
* <<TempComb>> <<EnriComb>> <<DensComb>>
* <<TempCalo>> <<PurtCalo>> <<DensCalo>>
* <<TempMod>> <<PurtMod>> <<DensMod>> <<BoreMod>>
* <<Impression>>
* ;
* Structures de donnees:
* Biblio : Bibliotheque de section efficace (L_LIBRARY).
* ConcEvol : Structure de donnee pour evolution (L_BURNUP).
* Parametres de controle:
* RefLib : Type de bibliotheque
* "Winfrith" -> Bibliotheque Winfrith WIMS-AECL
* "ENDFB5" -> Bibliotheque ENDF/B-V WIMS-AECL
* (defaut)
* "ENDFB6" -> Bibliotheque ENDF/B-VI WIMS-AECL
* "IGE227W" -> Bibliotheque Winfrith WIMS-AECL
* isotopes de IGE227
* "IGE227E5" -> Bibliotheque ENDF/B-V WIMS-AECL
* isotopes de IGE227
* BibOpt : Options de calcul
* BibOpt = 0 -> Initialiser la blbliotheque
* aux conditions initiales sans
* mise a jour en fonction du
* temps d'evolution.
* BibOpt = 1 -> Initialiser la blbliotheque
* aux conditions initiales et
* mettre a jour
* utilisant l'information dans
* ConcEvol.
* TempComb : Temperature combustible (C)
* EnriComb : Enrichissement combustible (%)
* DensComb : Densite combustible (g/cc)
* TempCalo : Temperature caloporteur (C)
* PurtCalo : % D2O caloporteur
* DensCalo : Densite caloporteur (g/cc)
* A calculer si 0.0
* TempMod : Temperature moderateur (C)
* PurtMod : % D2O moderateur
* DensMod : Densite moderateur (g/cc)
* A calculer si 0.0
* BoreMod : Bore dans le moderateur (ppm)
* Impression : Niveau d'impression
* Procedure requise:
* BibCreaG2 : Creation le la bibliotheque de section efficace
* pour le calcul de cellule
* Modules DRAGON requis:
* LIB: : Gestion des bibliotheque microscopiques
*----------
* Definition des parametres de la procedure
*
PARAMETER Biblio ConcEvol ::
EDIT 1
::: LINKED_LIST Biblio ConcEvol ; ;
STRING RefLib ;
INTEGER BibOpt ;
REAL TempComb EnriComb DensComb
TempCalo PurtCalo DensCalo
TempMod PurtMod DensMod BoreMod ;
INTEGER Impression ;
*----
* Reccuperer information transferee a la procedure
*----
:: >>RefLib<< >>BibOpt<<
>>TempComb<< >>EnriComb<< >>DensComb<<
>>TempCalo<< >>PurtCalo<< >>DensCalo<<
>>TempMod<< >>PurtMod<< >>DensMod<< >>BoreMod<<
>>Impression<< ;
*----
* Procedures externes et Modules et structures de donnees
*----
PROCEDURE BibCreaG2 ;
MODULE LIB: DELETE: ;
LINKED_LIST TmpBibl ;
*----
* Imprimer donnees d'entree si requis
*----
IF Impression 10 > THEN
ECHO "Bibliotheque =" RefLib ;
ECHO "Option de calcul =" BibOpt ;
ECHO "Temperature combustible =" TempComb "C" ;
ECHO "Enrichissement combustible =" EnriComb "%" ;
ECHO "Densite combustible =" DensComb "g/cc" ;
ECHO "Temperature caloporteur =" TempCalo "C" ;
ECHO "Purete caloporteur =" PurtCalo "%" ;
IF DensCalo 0.0 > THEN
ECHO "Densite caloporteur =" DensCalo "g/cc" ;
ENDIF ;
ECHO "Temperature moderateur =" TempMod "C" ;
ECHO "Purete moderateur =" PurtMod "%" ;
IF DensMod 0.0 > THEN
ECHO "Densite moderateur =" DensMod "g/cc" ;
ENDIF ;
ECHO "Bore moderateur =" BoreMod "ppm" ;
ENDIF ;
*----
* Variables locales
*----
IF BibOpt 0 = THEN
Biblio := BibCreaG2 ::
<<RefLib>>
<<TempComb>> <<EnriComb>> <<DensComb>>
<<TempCalo>> <<PurtCalo>> <<DensCalo>>
<<TempMod>> <<PurtMod>> <<DensMod>> <<BoreMod>>
<<Impression>> ;
ELSE
TmpBibl := BibCreaG2 ::
<<RefLib>>
<<TempComb>> <<EnriComb>> <<DensComb>>
<<TempCalo>> <<PurtCalo>> <<DensCalo>>
<<TempMod>> <<PurtMod>> <<DensMod>> <<BoreMod>>
<<Impression>> ;
TmpBibl := LIB: TmpBibl ConcEvol :: BURN 1 ;
Biblio := TmpBibl ;
ENDIF ;
*----
* terminer execution
*----
QUIT "LIST" .
|
