*----
*  TEST CASE iaea2d
*  IAEA 2D BENCHMARK IN DIFFUSION THEORY
*  MACROLIB-DEFINED CROSS SECTIONS
*----
*  Define STRUCTURES and MODULES used
*----
LINKED_LIST IAEA MACRO TRACK SYSTEM FLUX EDIT ;
MODULE GEO: MAC: BIVACT: BIVACA: TRIVAT: TRIVAA: FLUD: OUT: DELETE:
       END: ;
PROCEDURE assertS ;
*
IAEA := GEO: :: CAR2D 9 9
           EDIT 2
           X- DIAG X+ VOID
           Y- SYME Y+ DIAG
           MIX  3 2 2 2 3 2 2 1 4
                  2 2 2 2 2 2 1 4
                    2 2 2 2 1 1 4
                      2 2 2 1 4 4
                        3 1 1 4 0
                          1 4 4 0
                            4 0 0
                              0 0
                                0
           MESHX 0.0 20.0 40.0 60.0 80.0 100.0 120.0 140.0 160.0 180.0
           ;
MACRO := MAC: ::
 EDIT 2 NGRO 2 NMIX 4 NIFI 1
 READ INPUT
 MIX     1
      DIFF  1.500E+00  4.0000E-01
     TOTAL  3.012E-02  8.0032E-02
    NUSIGF  0.000E+00  1.3500E-01
  H-FACTOR  0.000E+00  1.3500E-01
      SCAT  1 1 0.0 2 2 0.0   0.2E-01
 MIX     2
      DIFF  1.500E+00  4.0000E-01
     TOTAL  3.012E-02  8.5032E-02
    NUSIGF  0.000E+00  1.3500E-01
  H-FACTOR  0.000E+00  1.3500E-01
      SCAT  1 1 0.0 2 2 0.0   0.2E-01
 MIX     3
      DIFF  1.500E+00  4.00000E-01
     TOTAL  3.012E-02  1.30032E-01
    NUSIGF  0.000E+00  1.35000E-01
  H-FACTOR  0.000E+00  1.35000E-01
      SCAT  1 1 0.0 2 2 0.0   0.2E-01
 MIX     4
      DIFF  2.000E+00  3.0000E-01
     TOTAL  4.016E-02  1.0024E-02
      SCAT  1 1 0.0 2 2 0.0   0.4E-01
 ;
*----
* BIVAC
*----
TRACK := BIVACT: IAEA ::
      TITLE 'IAEA-2D BENCHMARK'
      EDIT 2 MAXR 81 DUAL 2 1 ;
SYSTEM := BIVACA: MACRO TRACK ;
FLUX := FLUD: SYSTEM TRACK ::
      EDIT 2 ;
assertS FLUX :: 'K-EFFECTIVE' 1 1.029094 ;
EDIT := OUT: FLUX TRACK MACRO IAEA ::
       EDIT 2 INTG
       1  2  3  4  5  6  7  8  0
          9 10 11 12 13 14 15  0
            16 17 18 19 20 21  0
               22 23 24 25  0  0
                  26 27 28  0  0
                     29  0  0  0
                         0  0  0
                            0  0
                               0
       ;
TRACK SYSTEM FLUX EDIT := DELETE: TRACK SYSTEM FLUX EDIT ;
*
TRACK := BIVACT: IAEA ::
      TITLE 'IAEA-2D BENCHMARK'
      EDIT 2 MAXR 81 PRIM 2 2 ;
SYSTEM := BIVACA: MACRO TRACK ;
FLUX := FLUD: SYSTEM TRACK ::
      EDIT 2 ;
assertS FLUX :: 'K-EFFECTIVE' 1 1.032310 ;
TRACK SYSTEM FLUX := DELETE: TRACK SYSTEM FLUX ;
*----
* TRIVAC
*----
TRACK := TRIVAT: IAEA ::
      TITLE 'IAEA-2D BENCHMARK'
      EDIT 2 MAXR 81 DUAL 2 1 ;
SYSTEM := TRIVAA: MACRO TRACK ;
FLUX := FLUD: SYSTEM TRACK ::
      EDIT 2 ADJ ;
assertS FLUX :: 'K-EFFECTIVE' 1 1.029094 ;
TRACK SYSTEM FLUX := DELETE: TRACK SYSTEM FLUX ;
*
TRACK := TRIVAT: IAEA ::
      TITLE 'IAEA-2D BENCHMARK'
      EDIT 2 MAXR 81 DUAL 2 2 ;
SYSTEM := TRIVAA: MACRO TRACK ;
FLUX := FLUD: SYSTEM TRACK ::
      EDIT 2 ;
assertS FLUX :: 'K-EFFECTIVE' 1 1.028690 ;
TRACK SYSTEM FLUX := DELETE: TRACK SYSTEM FLUX ;
*
TRACK := TRIVAT: IAEA ::
      TITLE 'IAEA-2D BENCHMARK'
      EDIT 2 MAXR 81 PRIM 2 ;
SYSTEM := TRIVAA: MACRO TRACK ;
FLUX := FLUD: SYSTEM TRACK ::
      EDIT 2 ;
assertS FLUX :: 'K-EFFECTIVE' 1 1.032310 ;
TRACK SYSTEM FLUX := DELETE: TRACK SYSTEM FLUX ;
*
TRACK := TRIVAT: IAEA ::
      TITLE 'IAEA-2D BENCHMARK'
      EDIT 2 MAXR 81 MCFD 2 ;
SYSTEM := TRIVAA: MACRO TRACK ;
FLUX := FLUD: SYSTEM TRACK ::
      EDIT 2 ;
assertS FLUX :: 'K-EFFECTIVE' 1 1.028690 ;
TRACK SYSTEM FLUX := DELETE: TRACK SYSTEM FLUX ;
ECHO "test iaea2d completed" ;
END: ;