*----
*  TEST CASE TCWE32
*  VVER Assembly of central water hole with 6 identical fuel cells
*  NXT self-shielding and flux
*  Coarse mesh
*----
MODULE
  LIB: GEO: NXT: SHI: ASM: FLU: DELETE: END: ;
LINKED_LIST
  LIBRARY GEOMS GEOMF TRACK PIJMAT FLUX ;
SEQ_BINARY 
  TRACK_LGT ;
PROCEDURE assertS ;
*----
*  Microscopic cross sections from file WNEALIB format WIMSE
*----
LIBRARY := LIB: ::
  EDIT 1
  NMIX 4
  CTRA WIMS
  MIXS LIB: WIMSE FIL: WIMS-E
  MIX 1 579.9
    H1H2O    = '1001'   4.76690E-2   O16H2O   = '8016'   2.38345E-2
    BNat     = '1011'   2.38103E-5
  MIX 2 609.0                        O16      = '8016'   3.06711E-4
    Cr52     = '24052'  7.54987E-5   Fe56     = '26056'  1.47624E-4
    Zr90     = '40090'  2.15381E-02  Zr91     = '40091'  4.69693E-03 2
    Zr92     = '40092'  7.17935E-03  Zr94     = '40094'  7.27563E-03
    Zr96     = '40096'  1.17214E-03
  MIX 3 966.0                        O16      = '8016'     4.49355E-2
    U235     = '92235'   7.39237E-4 1 
    U238     = '92238'   2.17285E-2 1 
  MIX 4 579.9
    H1H2O    = '1001'   4.76690E-2   O16H2O   = '8016'   2.38345E-2
    B10      = '5010'   4.73825E-06  B11      = '5011'   1.90721E-05
  ;
*----
*  Geometries NXT
*----
GEOMS := GEO: :: HEX 7
  EDIT 2
  HBC COMPLETE REFL
  CELL CT  CFI CFI CFI CFI CFI CFI
  ::: CT := GEO: HEXTCEL 2 1
    SIDE 0.736121593
    MIX 4 2 1
    RADIUS 0.0 0.386 0.445
    ;
  ::: CFI := GEO: HEXTCEL 2 1
    SIDE 0.736121593
    MIX 3 2 1
    RADIUS 0.0 0.386 0.445
    ;
  ;
GEOMF := GEO: :: HEX 7
  EDIT 2
  HBC COMPLETE REFL
  CELL CT  CFI CFI CFI CFI CFI CFI
  ::: CT := GEO: HEXTCEL 2 1
    SIDE 0.736121593
    SPLITR 3 1
    MIX 1 2 1
    RADIUS 0.0 0.386 0.445
    ;
  ::: CFI := GEO: HEXTCEL 2 1
    SIDE 0.736121593
    SPLITR 3 1
    MIX 3 2 1
    RADIUS 0.0 0.386 0.445
    ;
  ;
*----
*  Self-Shielding calculation
*  Transport calculation
*  Flux calculation
*----
TRACK TRACK_LGT := NXT: GEOMS ::
  EDIT 3  TITL 'VVER-NXT: Shielding'
  ALLG BATCH 100
  TISO 50 20.0 ;
LIBRARY := SHI: LIBRARY TRACK TRACK_LGT ;
TRACK TRACK_LGT GEOMS := DELETE: TRACK TRACK_LGT GEOMS ;
TRACK TRACK_LGT := NXT: GEOMF ::
  EDIT 3  TITL 'VVER-NXT: Flux'
  ALLG BATCH 100
  TISO 50 100.0 ;
PIJMAT := ASM: LIBRARY TRACK TRACK_LGT ::
  EDIT 1 ;
FLUX := FLU: PIJMAT LIBRARY TRACK ::
  EDIT 1  TYPE K ;
assertS FLUX :: 'K-EFFECTIVE' 1 1.360705 ;
TRACK TRACK_LGT GEOMF := DELETE: TRACK TRACK_LGT GEOMF ;
PIJMAT FLUX := DELETE: PIJMAT FLUX ;
LIBRARY := DELETE: LIBRARY ;
ECHO "test TCWE32 completed" ;
END: ;
QUIT "LIST" .