*----
*
*  TEST CASE gduo2_295_kec1
*  DISTRIBUTED SELF-SHIELDING
*  295-GROUP JEF3.1.1 DRAGLIB
*
*  Author: A. Hebert
*
*----
*  Define STRUCTURES and MODULES used
*----
LINKED_LIST GEOM TRACK_SS TRACK LIBRARY LIBRARY2 CP CALC ;
SEQ_ASCII UOX_TBH ;
SEQ_BINARY TF_EXC ;
MODULE LIB: GEO: SYBILT: G2S: SALT: MAC: USS: TONE: ASM: FLU: DELETE: ;
INTEGER COMB0101 COMB0102 COMB0103 COMB0104 COMB0105 COMB0106 GAIN1
        MODE1 := 
        1 2 3 4 5 6 7 8 ; (* DISTRIBUTED SELF-SHIELDING *)
REAL RCOMB1 RCOMB2 RCOMB3 RCOMB4 RCOMB5 RCOMB6 ;
PROCEDURE assertS ;
REAL P_Zr90     P_Zr91     P_Zr92    P_Zr94    P_Zr96    :=
     51.45E-02  11.22E-02  17.15E-02 17.38E-02 2.80E-02  ;
REAL N_Zr0 := 3.88E-2 ;
REAL N_Zr90       N_Zr91       N_Zr92       N_Zr94       N_Zr96    :=
     N_Zr0 P_Zr90 *  N_Zr0 P_Zr91 *  N_Zr0 P_Zr92 *  N_Zr0 P_Zr94 *
     N_Zr0 P_Zr96 *  ;
INTEGER an2d := 12 ;
REAL densur := 20.0 ;
*
EVALUATE RCOMB6 := 0.41 ;
EVALUATE RCOMB1 := 0.4 SQRT RCOMB6 * ;
EVALUATE RCOMB2 := 0.7 SQRT RCOMB6 * ;
EVALUATE RCOMB3 := 0.8 SQRT RCOMB6 * ;
EVALUATE RCOMB4 := 0.9 SQRT RCOMB6 * ;
EVALUATE RCOMB5 := 0.95 SQRT RCOMB6 * ;
GEOM := GEO: :: CARCEL 8
      X- REFL X+ REFL Y- REFL Y+ REFL
      RADIUS 0.0 <<RCOMB1>> <<RCOMB2>> <<RCOMB3>> <<RCOMB4>>
                 <<RCOMB5>> <<RCOMB6>> 0.475 0.6045552
      MIX <<COMB0101>> <<COMB0102>> <<COMB0103>> <<COMB0104>>
          <<COMB0105>> <<COMB0106>> <<GAIN1>> <<MODE1>> <<MODE1>>
      MESHX 0.0 1.26 MESHY 0.0 1.26
          ;
TRACK_SS := SYBILT: GEOM ::
     TITLE 'UO2 ROWLAND S BENCHMARK'
     MAXR 20 QUA2 20 3 DP01 MAXZ 200000 ;
UOX_TBH := G2S: GEOM ;
TRACK TF_EXC := SALT: UOX_TBH ::
  EDIT 3
  ALLG
  TSPC EQW2 <<an2d>> <<densur>> REND
;
LIBRARY := LIB: ::
 EDIT 1
 NMIX 8    (*MAXIMUM OF MATERIAL MIXTURES*)
 CTRA APOL (*APOLLO TYPE TRANSPORT CORRECTION*)
 ANIS 2
 ADED 4 NELAS N4N N2N N3N
 RSE       (*RESONANCE SPECTRUM EXPANSION METHOD*)
*
 MIXS LIB: DRAGON FIL: DLIB_295
 MIX <<COMB0101>> 294.0 (*COMB0101*)
    O16     = O16    4.59036E-2
    U235    = U235   7.90006E-4 1
    U238    = U238   2.08874E-2 CORR 1
    Gd154   = Gd154  3.78440E-5 1
    Gd155   = Gd155  2.55262E-4 1
    Gd156   = Gd156  3.50791E-4 1
    Gd157   = Gd157  2.66479E-4 CORR 1
    Gd158   = Gd158  4.20283E-4 1
    Gd160   = Gd160  3.65230E-4 1
MIX <<COMB0102>> COMB <<COMB0101>> 1.0 (*COMB0102*)
 MIX <<COMB0103>> COMB <<COMB0101>> 1.0 (*COMB0103*)
 MIX <<COMB0104>> COMB <<COMB0101>> 1.0 (*COMB0104*)
 MIX <<COMB0105>> COMB <<COMB0101>> 1.0 (*COMB0105*)
 MIX <<COMB0106>> COMB <<COMB0101>> 1.0 (*COMB0106*)
 MIX <<GAIN1>> 294.0 (*GAIN1*)
    Zr90    = Zr90   <<N_Zr90>> 2
    Zr91    = Zr91   <<N_Zr91>> 2
    Zr92    = Zr92   <<N_Zr92>> 2
    Zr94    = Zr94   <<N_Zr94>>
    Zr96    = Zr96   <<N_Zr96>>
 MIX <<MODE1>> 294.0 (*MODE1*)
    H1      = H1_H2O 4.744E-2
    O16     = O16    2.372E-2
;
LIBRARY2 := USS: LIBRARY TRACK_SS :: EDIT 1 TRAN PASS 3 GRMIN 52 ;
CP := ASM: LIBRARY2 TRACK TF_EXC :: EDIT 1 PIJ ;
CALC := FLU: CP LIBRARY2 TRACK :: EDIT 1 TYPE K ;
assertS CALC :: K-EFFECTIVE 1 0.3291729 ;
QUIT "LIST" .