*----
*  TEST CASE UOX_5x5_TG6_sym8_multiDom_rt2
*  SIMPLE 5 X 5 PWR ASSEMBLY WITH TRIVAC
*  Input cross section data from Apex
*----
*  Define STRUCTURES and MODULES used
*----
LINKED_LIST ASSMB TRACK MACRO SYS FLUX ;
HDF5_FILE UOX_5x5 :: FILE './UOX_5x5_TG6_sym8_multiDom.h5' ;
MODULE GEO: HUTL: SPH: TRIVAT: TRIVAA: FLUD: END: ;
REAL B2 ;
PROCEDURE assertS ;

REAL side1 := 1.26 ;
REAL side2 := side1 1.26 + ;
REAL side3 := side2 1.26 + ;
ASSMB := GEO: :: CAR2D 3 3 (*ASSEMBLY 5 X 5*)
          X- DIAG X+ REFL
          Y- SYME Y+ DIAG
          MESHX 0.0 <<side1>> <<side2>> <<side3>>
          MIX 1 2 4
                3 5
                  6
;

TRACK := TRIVAT: ASSMB ::
     TITLE 'SIMPLE 5x5 FUEL ASSEMBLY'
     EDIT 0 MAXR 3000 DUAL 3 1 SPN 5 SCAT 1 ;

HUTL: UOX_5x5 :: DIR
  GREP '/calc       1/miscellaneous/B2' 1 >>B2<< ;
ECHO 'buckling B2=' B2 ;
UOX_5x5 := SPH: UOX_5x5 TRACK :: EDIT 6 STEP AT 1
  EQUI 'equivalence_SP3_P0c_rt2' ;
MACRO := SPH: UOX_5x5 :: EDIT 3 STEP AT 1 MACRO SPRD
  EQUI 'equivalence_SP3_P0c_rt2' LEAK <<B2>> ;
SYS := TRIVAA: MACRO TRACK ;
FLUX := FLUD: SYS TRACK :: EDIT 1 ADI 4 ACCE 5 3 ;
assertS FLUX :: 'K-EFFECTIVE' 1 0.9982139 ;

ECHO "UOX_5x5_TG6_sym8_multiDom_rt2 completed" ;
END: ;