summaryrefslogtreecommitdiff
path: root/Dragon/data/twinfrith_proc
diff options
context:
space:
mode:
authorstainer_t <thomas.stainer@oecd-nea.org>2025-09-08 13:48:49 +0200
committerstainer_t <thomas.stainer@oecd-nea.org>2025-09-08 13:48:49 +0200
commit7dfcc480ba1e19bd3232349fc733caef94034292 (patch)
tree03ee104eb8846d5cc1a981d267687a729185d3f3 /Dragon/data/twinfrith_proc
Initial commit from Polytechnique Montreal
Diffstat (limited to 'Dragon/data/twinfrith_proc')
-rw-r--r--Dragon/data/twinfrith_proc/TCWW01.c2m115
-rw-r--r--Dragon/data/twinfrith_proc/TCWW02.c2m159
-rw-r--r--Dragon/data/twinfrith_proc/TCWW03.c2m149
-rw-r--r--Dragon/data/twinfrith_proc/TCWW04.c2m151
-rw-r--r--Dragon/data/twinfrith_proc/TCWW05.c2m218
-rw-r--r--Dragon/data/twinfrith_proc/TCWW06.c2m173
-rw-r--r--Dragon/data/twinfrith_proc/TCWW07.c2m162
-rw-r--r--Dragon/data/twinfrith_proc/TCWW08.c2m121
-rw-r--r--Dragon/data/twinfrith_proc/TCWW09.c2m72
-rw-r--r--Dragon/data/twinfrith_proc/TCWW10.c2m78
-rw-r--r--Dragon/data/twinfrith_proc/TCWW11.c2m204
-rw-r--r--Dragon/data/twinfrith_proc/TCWW12.c2m107
-rw-r--r--Dragon/data/twinfrith_proc/TCWW31.c2m211
-rw-r--r--Dragon/data/twinfrith_proc/TCWW41.c2m223
-rw-r--r--Dragon/data/twinfrith_proc/TCWW42.c2m160
-rw-r--r--Dragon/data/twinfrith_proc/TCWW43.c2m242
16 files changed, 2545 insertions, 0 deletions
diff --git a/Dragon/data/twinfrith_proc/TCWW01.c2m b/Dragon/data/twinfrith_proc/TCWW01.c2m
new file mode 100644
index 0000000..2ed3230
--- /dev/null
+++ b/Dragon/data/twinfrith_proc/TCWW01.c2m
@@ -0,0 +1,115 @@
+*----
+* TEST CASE TCWW01
+* MOSTELLER BENCHMARK: 1-D ANNULAR CELL AND 2-D CARTESIAN CELL
+* WIMS-AECL 69 GROUPS LIBRARY FILE WIMSLIB
+*
+* REF: R. Mosteller et al. Nucl. Sci. Eng. 107, 265 (1991)
+*
+*----
+* Define STRUCTURES and MODULES used
+*----
+LINKED_LIST
+ MOSTELA MOSTELC DISCR LIBRARY CP CALC OUT ;
+SEQ_BINARY
+ TRKSPC ;
+MODULE
+ LIB: GEO: SYBILT: EXCELT: SHI: ASM: FLU: EDI: DELETE: END: ;
+PROCEDURE assertS ;
+*----
+* Microscopic cross sections from file WIMSLIB format WIMS-AECL
+*----
+LIBRARY := LIB: ::
+ NMIX 3 CTRA WIMS
+ MIXS LIB: WIMSAECL FIL: WIMSLIB
+ MIX 1 600.0 O16 = O16 4.61309E-2
+ U235 = U235 1.66078E-4 1
+ U238 = U238 2.28994E-2 1
+ MIX 2 600.0
+ Zr91 = ZR91 3.83243E-2
+ MIX 3 600.0
+ H1H2O = H1H2O 4.42326E-2 O16H2O = O16H2O 2.21163E-2
+ BNat = B-NAT 1.02133E-5
+ ;
+*----
+* Geometry MOSTELA : annular 3 region geometry
+* MOSTELC : Cartesian 3 region geometry
+*----
+MOSTELA := GEO: :: TUBE 3
+ R+ REFL RADIUS 0.0 0.39306 0.45802 0.71206 SPLITR 2 1 1
+ MIX 1 2 3 ;
+MOSTELC := GEO: :: CARCEL 2
+ X- REFL X+ REFL MESHX 0.0 1.26209
+ Y- REFL Y+ REFL MESHY 0.0 1.26209
+ RADIUS 0.0 0.39306 0.45802 SPLITR 2 1
+ MIX 1 2 3 ;
+*----
+* Case 1 -- annular
+* Self-Shielding calculation SYBIL
+* Transport calculation SYBIL
+* Flux calculation for K no leakage
+*----
+DISCR := SYBILT: MOSTELA ::
+ TITLE 'TCWW01: MOSTELLER BENCHMARK (SYBIL / SYBIL)'
+ MAXR 4 QUA1 5 ;
+LIBRARY := SHI: LIBRARY DISCR :: EDIT 0 NOLJ ;
+CP := ASM: LIBRARY DISCR ;
+CALC := FLU: CP LIBRARY DISCR ::
+ TYPE K ;
+assertS CALC :: 'K-EFFECTIVE' 1 0.8267476 ;
+OUT := EDI: CALC LIBRARY DISCR ::
+ EDIT 4 MERG MIX 1 2 3 COND 4.0 SAVE ;
+DISCR CP := DELETE: DISCR CP ;
+*----
+* Case 2 -- Cartesian
+* Self-Shielding calculation SYBIL
+* Transport calculation SYBIL
+* Flux calculation for K no leakage
+*----
+DISCR := SYBILT: MOSTELC ::
+ TITLE 'TCWW01: MOSTELLER BENCHMARK (SYBIL / SYBIL)'
+ MAXR 4 QUA1 5 QUA2 6 5 ;
+LIBRARY := SHI: LIBRARY DISCR :: EDIT 0 NOLJ ;
+CP := ASM: LIBRARY DISCR ;
+CALC := FLU: CALC CP LIBRARY DISCR ::
+ TYPE K ;
+assertS CALC :: 'K-EFFECTIVE' 1 0.8268772 ;
+OUT := EDI: OUT CALC LIBRARY DISCR ::
+ EDIT 1 MERG MIX 1 2 3 COND 4.0 STAT ALL REFE 1 ;
+CALC DISCR CP := DELETE: CALC DISCR CP ;
+*----
+* Case 3 -- annular
+* Self-Shielding calculation EXCEL-ISO
+* Transport calculation EXCEL-ISO
+* Flux calculation for K no leakage
+*----
+DISCR TRKSPC := EXCELT: MOSTELC ::
+ TITLE 'TCWW01: MOSTELLER BENCHMARK (EXCELL)'
+ MAXR 4 TRAK TISO 12 20.0 ;
+LIBRARY := SHI: LIBRARY DISCR TRKSPC :: EDIT 0 NOLJ ;
+CP := ASM: LIBRARY DISCR TRKSPC ;
+CALC := FLU: CP LIBRARY DISCR ::
+ TYPE K ;
+assertS CALC :: 'K-EFFECTIVE' 1 0.8278652 ;
+OUT := EDI: OUT CALC LIBRARY DISCR ::
+ EDIT 1 MERG MIX 1 2 3 COND 4.0 STAT ALL REFE 1 ;
+DISCR TRKSPC CP := DELETE: DISCR TRKSPC CP ;
+*----
+* Case 4 -- Cartesian
+* Self-Shielding calculation EXCEL-SPC
+* Transport calculation EXCEL-SPC
+* Flux calculation for K no leakage
+*----
+DISCR TRKSPC := EXCELT: MOSTELC ::
+ TITLE 'TCWW01: MOSTELLER BENCHMARK (EXCELL)'
+ MAXR 4 TRAK TSPC 12 20.0 ;
+LIBRARY := SHI: LIBRARY DISCR TRKSPC :: EDIT 0 NOLJ ;
+CP := ASM: LIBRARY DISCR TRKSPC ;
+CALC := FLU: CALC CP LIBRARY DISCR ::
+ TYPE K ;
+assertS CALC :: 'K-EFFECTIVE' 1 0.8302281 ;
+OUT := EDI: OUT CALC LIBRARY DISCR ::
+ EDIT 1 MERG MIX 1 2 3 COND 4.0 STAT ALL REFE 1 ;
+DISCR TRKSPC CP := DELETE: DISCR TRKSPC CP ;
+ECHO "test TCWW01 completed" ;
+END: ;
+QUIT "LIST" .
diff --git a/Dragon/data/twinfrith_proc/TCWW02.c2m b/Dragon/data/twinfrith_proc/TCWW02.c2m
new file mode 100644
index 0000000..98cd33d
--- /dev/null
+++ b/Dragon/data/twinfrith_proc/TCWW02.c2m
@@ -0,0 +1,159 @@
+*----
+* TEST CASE TCWW02
+* 17 X 17 PWR ASSEMBLY WITHOUT POISON
+* WIMS-AECL 69 GROUPS LIBRARY FILE WIMSLIB
+*
+* REF: none
+*
+*----
+* Define STRUCTURES and MODULES used
+*----
+LINKED_LIST
+ ASSMB DISCR LIBRARY CP CALC OUT DATABASE ISOT SPHGEOM MTRACK ;
+SEQ_ASCII
+ res ;
+MODULE
+ LIB: GEO: SYBILT: BIVACT: SHI: ASM: FLU: EDI: COMPO: SPH: DELETE:
+ END: ;
+PROCEDURE assertS ;
+*----
+* Microscopic cross sections from file WIMSLIB format WIMS-AECL
+*----
+LIBRARY := LIB: ::
+ NMIX 8 CTRA WIMS
+ MIXS LIB: WIMSAECL FIL: WIMSLIB
+ MIX 1 579.9
+ H1H2O = H1H2O 4.76690E-2 O16H2O = O16H2O 2.38345E-2
+ BNat = B-NAT 2.38103E-5
+ MIX 2 579.9 O16 = O16 3.06711E-4
+ Cr52 = CR52 7.54987E-5 Fe56 = FE56A 1.47624E-4
+ Zr91 = ZR91 4.18621E-2
+ MIX 3 579.9
+ H1H2O = H1H2O 4.65292E-2 O16H2O = O16H2O 2.32646E-2
+ Nb93 = NB93 7.07082E-6 Cr52 = CR52 4.79927E-5
+ Fe56 = FE56A 4.45845E-5 Ni58 = NI58 1.13521E-4
+ Co59 = CO59 1.07714E-7 Mo95 = MO95 4.03755E-6
+ Ti48 = TI48 2.33305E-6 Al27 = AL27 2.35231E-6
+ Mn55 = MN55 4.15901E-7
+ BNat = B-NAT 2.32761E-5
+ Zr91 = ZR91 8.92427E-4
+ MIX 4 579.9 O16 = O16 2.87335E-4
+ Cr52 = CR52 7.07291E-5 Fe56 = FE56A 1.38298E-4
+ Zr91 = ZR91 3.92175E-2
+ MIX 5 579.9
+ H1H2O = H1H2O 4.71346E-2 O16H2O = O16H2O 2.35673E-2
+ Nb93 = NB93 3.31482E-6 Cr52 = CR52 2.24991E-5
+ Fe56 = FE56A 2.09013E-5 Ni58 = NI58 5.32188E-5
+ Co59 = CO59 5.04968E-8 Mo95 = MO95 1.89281E-6
+ Ti48 = TI48 1.09374E-6 Al27 = AL27 1.10277E-6
+ Mn55 = MN55 1.94976E-7
+ BNat = B-NAT 2.35598E-5
+ Zr91 = ZR91 4.18372E-4
+ MIX 6 579.9
+ H1H2O = H1H2O 4.71676E-2 O16H2O = O16H2O 2.35838E-2
+ Nb93 = NB93 3.11049E-6 Cr52 = CR52 2.11122E-5
+ Fe56 = FE56A 1.96130E-5 Ni58 = NI58 4.99383E-5
+ Co59 = CO59 4.73842E-8 Mo95 = MO95 1.77614E-6
+ Ti48 = TI48 1.02632E-6 Al27 = AL27 1.03479E-6
+ Mn55 = MN55 1.82957E-7
+ BNat = B-NAT 2.35753E-5
+ Zr91 = ZR91 3.92583E-4
+ MIX 7 579.9
+ H1H2O = H1H2O 4.72020E-2 O16H2O = O16H2O 2.36010E-2
+ Nb93 = NB93 2.89640E-6 Cr52 = CR52 1.96591E-5
+ Fe56 = FE56A 1.82630E-5 Ni58 = NI58 4.65011E-5
+ Co59 = CO59 4.41227E-8 Mo95 = MO95 1.65389E-6
+ Ti48 = TI48 9.55682E-7 Al27 = AL27 9.63569E-7
+ Mn55 = MN55 1.70365E-7
+ BNat = B-NAT 2.35914E-5
+ Zr91 = ZR91 3.65562E-4
+ MIX 8 933.6 O16 = O16 4.49355E-2
+ U235 = U235 7.39237E-4 1
+ U238 = U238 2.17285E-2 1
+ ;
+*----
+* Geometry ASSMB : a 17 X 17 normal PWR assembly
+* contains C1 : cell without fuel
+* C2 : normal fuel cell
+* C3 : peripheral cell
+* C4 : corner cell
+*----
+ASSMB := GEO: :: CAR2D 9 9
+ X- DIAG X+ REFL Y- SYME Y+ DIAG
+ CELL C1 C2 C2 C1 C2 C2 C1 C2 C3
+ C2 C2 C2 C2 C2 C2 C2 C3
+ C2 C2 C2 C2 C2 C2 C3
+ C1 C2 C2 C1 C2 C3
+ C2 C2 C2 C2 C3
+ C1 C2 C2 C3
+ C2 C2 C3
+ C2 C3
+ C4
+ MERGE 1 3 12 11 12 12 11 12 15
+ 4 6 5 6 6 5 6 8
+ 13 5 6 6 5 6 8
+ 2 5 5 10 5 8
+ 13 5 5 6 8
+ 2 5 7 8
+ 13 7 8
+ 14 8
+ 9
+ TURN H H B H H B H H A
+ H G G H G G H A
+ A E E F E E A
+ H H F H H A
+ H E G H A
+ H H A A
+ H A A
+ A A
+ A
+ ::: C1 := GEO: CARCEL 2
+ MESHX 0.0 1.26472 MESHY 0.0 1.26472
+ RADIUS 0.0 0.572435 0.613142 MIX 1 2 3 ;
+ ::: C2 := GEO: C1 RADIUS 0.0 0.412660 0.474364 MIX 8 4 5 ;
+ ::: C3 := GEO: C2 MESHX 0.0 1.31472 MIX 8 4 6 ;
+ ::: C4 := GEO: C3 MESHY 0.0 1.31472 MIX 8 4 7 ;
+ ;
+*----
+* Self-Shielding calculation SYBIL
+* Transport calculation SYBIL
+* Flux calculation for B1 homogeneous leakage
+* Editing using SPH model for transport-diffusion
+*----
+DISCR := SYBILT: ASSMB ::
+ TITLE 'TCWW02: 17 X 17 MULTICELL PWR BENCHMARK WITHOUT POISON'
+ MAXR 400 QUA2 6 3 ;
+LIBRARY := SHI: LIBRARY DISCR :: EDIT 0 NOLJ ;
+CP := ASM: LIBRARY DISCR ;
+CALC := FLU: CP LIBRARY DISCR ::
+ TYPE B B1 PNL ;
+assertS CALC :: 'K-INFINITY' 1 1.252327 ;
+
+OUT := EDI: CALC LIBRARY DISCR ASSMB ::
+ EDIT 3 UPS SAVE MICR RES MERGE CELL COND 4.0
+ ;
+SPHGEOM := OUT :: STEP UP 'MACRO-GEOM' ;
+MTRACK := BIVACT: SPHGEOM :: PRIM 1 2 EDIT 0 ;
+OUT := SPH: OUT MTRACK ;
+SPHGEOM MTRACK := DELETE: SPHGEOM MTRACK ;
+
+DATABASE := COMPO: ::
+ EDIT 5
+ COMM 'Multi-parameter reactor database' ENDC
+ INIT
+ ;
+DATABASE := COMPO: DATABASE OUT ::
+ EDIT 3
+ ;
+res := DATABASE ;
+
+ISOT := DATABASE :: STEP UP default
+ STEP UP MIXTURES STEP AT 5
+ STEP UP CALCULATIONS STEP AT 1
+ STEP UP ISOTOPESLIST STEP AT 1 ;
+assertS ISOT :: 'NWT0' 1 5.242837E-01 ;
+assertS ISOT :: 'NWT0' 2 1.298493E-01 ;
+
+ECHO "test TCWW02 completed" ;
+END: ;
+QUIT "LIST" .
diff --git a/Dragon/data/twinfrith_proc/TCWW03.c2m b/Dragon/data/twinfrith_proc/TCWW03.c2m
new file mode 100644
index 0000000..2d4800b
--- /dev/null
+++ b/Dragon/data/twinfrith_proc/TCWW03.c2m
@@ -0,0 +1,149 @@
+*----
+* TEST CASE TCWW03
+* MULTICELL HEXAGONAL ASSEMBLY WITH POISON
+* WIMS-AECL 69 GROUPS LIBRARY FILE WIMSLIB
+*
+* REF: none
+*
+*----
+* Define STRUCTURES and MODULES used
+*----
+LINKED_LIST
+ ASSMBH DISCR LIBRARY CP CALC OUT DATABASE ISOT SPHGEOM MTRACK ;
+SEQ_ASCII
+ res ;
+MODULE
+ GEO: SYBILT: BIVACT: LIB: SHI: ASM: FLU: EDI: COMPO: SPH: DELETE:
+ END: ;
+PROCEDURE assertS ;
+*----
+* Microscopic cross sections from file WIMSLIB format WIMS-AECL
+*----
+LIBRARY := LIB: ::
+ NMIX 11 CTRA WIMS
+ MIXS LIB: WIMSAECL FIL: WIMSLIB
+ MIX 1 579.9
+ H1H2O = H1H2O 4.76690E-2 O16H2O = O16H2O 2.38345E-2
+ BNat = B-NAT 2.38103E-5
+ MIX 2 579.9 O16 = O16 3.06711E-4
+ Cr52 = CR52 7.54987E-5 Fe56 = FE56A 1.47624E-4
+ Zr91 = ZR91 4.18621E-2
+ MIX 3 579.9
+ H1H2O = H1H2O 4.65292E-2 O16H2O = O16H2O 2.32646E-2
+ Nb93 = NB93 7.07082E-6 Cr52 = CR52 4.79927E-5
+ Fe56 = FE56A 4.45845E-5 Ni58 = NI58 1.13521E-4
+ Co59 = CO59 1.07714E-7 Mo95 = MO95 4.03755E-6
+ Ti48 = TI48 2.33305E-6 Al27 = AL27 2.35231E-6
+ Mn55 = MN55 4.15901E-7
+ BNat = B-NAT 2.32761E-5
+ Zr91 = ZR91 8.92427E-4
+ MIX 4 933.6 O16 = O16 4.49355E-2
+ U235 = U235 7.39237E-4 1
+ U238 = U238 2.17285E-2 1
+ MIX 5 579.9 In115 = IN115 7.57464E-3
+ Cd113 = CD113 2.62493E-3
+ Ag109 = AG109 4.49188E-2
+ MIX 6 579.9 Cr52 = CR52 1.52702E-2
+ Fe56 = FE56A 5.57670E-2 Ni58 = NI58 7.51418E-3
+ Mn55 = MN55 8.02943E-4
+ MIX 7 579.9
+ H1H2O = H1H2O 3.06466E-2 O16H2O = O16H2O 1.53233E-2
+ Fe56 = FE56A 5.27485E-5 Cr52 = CR52 2.69769E-5
+ BNat = B-NAT 1.53077E-5
+ Zr91 = ZR91 1.49580E-2
+ MIX 8 579.9
+ H1H2O = H1H2O 4.65292E-2 O16H2O = O16H2O 2.32646E-2
+ Nb93 = NB93 7.07082E-6 Cr52 = CR52 4.79927E-5
+ Fe56 = FE56A 4.45845E-5 Ni58 = NI58 1.13521E-4
+ Co59 = CO59 1.07714E-7 Mo95 = MO95 4.03755E-6
+ Ti48 = TI48 2.33305E-6 Al27 = AL27 2.35231E-6
+ Mn55 = MN55 4.15901E-7
+ BNat = B-NAT 2.32761E-5
+ Zr91 = ZR91 8.92427E-4
+ MIX 9 579.9 O16 = O16 2.87335E-4
+ Cr52 = CR52 7.07291E-5 Fe56 = FE56A 1.38298E-4
+ Zr91 = ZR91 3.92175E-2
+ MIX 10 579.9
+ H1H2O = H1H2O 4.71346E-2 O16H2O = O16H2O 2.35673E-2
+ Nb93 = NB93 3.31482E-6 Cr52 = CR52 2.24991E-5
+ Fe56 = FE56A 2.09013E-5 Ni58 = NI58 5.32188E-5
+ Co59 = CO59 5.04968E-8 Mo95 = MO95 1.89281E-6
+ Ti48 = TI48 1.09374E-6 Al27 = AL27 1.10277E-6
+ Mn55 = MN55 1.94976E-7 BNat = B-NAT 2.35598E-5
+ Zr91 = ZR91 4.18372E-4
+ MIX 11 579.9
+ H1H2O = H1H2O 4.71676E-2 O16H2O = O16H2O 2.35838E-2
+ Nb93 = NB93 3.11049E-6 Cr52 = CR52 2.11122E-5
+ Fe56 = FE56A 1.96130E-5 Ni58 = NI58 4.99383E-5
+ Co59 = CO59 4.73842E-8 Mo95 = MO95 1.77614E-6
+ Ti48 = TI48 1.02632E-6 Al27 = AL27 1.03479E-6
+ Mn55 = MN55 1.82957E-7
+ BNat = B-NAT 2.35753E-5
+ Zr91 = ZR91 3.92583E-4
+ ;
+*----
+* Geometry ASSMBH : hexagonal assembly with poison
+* contains C1 : cell without fuel
+* C2 : poison cell
+* C3 : normal fuel cell
+* C4 : peripheral cell
+*----
+ASSMBH := GEO: :: HEX 36
+ HBC S30 REFL
+ CELL C1 C3 C3 C3 C3 C3 C2 C3 C3 C3 C2 C3 C3 C3 C3 C3 C3 C2
+ C3 C3 C2 C3 C3 C3 C3 C3 C3 C3 C3 C3 C4 C4 C4 C4 C4 C4
+ TURN A A A A A A A A B D A I A C F J B A
+ F A A E E A A E A A A A A A A A A A
+ MERGE 1 2 3 4 5 4 6 7 8 7 9 8 10 7 7 4 7 11
+ 12 13 14 15 12 16 17 12 16 18 18 19 20 21 21 22 22 23
+ ::: C1 := GEO: HEXCEL 2
+ SIDE 0.707297 RADIUS 0.0 0.412282 0.475917
+ MIX 1 2 3 ;
+ ::: C2 := GEO: HEXCEL 5
+ SIDE 0.707297 RADIUS 0.0 0.25057 0.354359 0.436 0.486 0.6125
+ MIX 5 5 5 6 7 8 ;
+ ::: C3 := GEO: C1 MIX 4 9 10 ;
+ ::: C4 := GEO: C3 MIX 4 9 11 ;
+ ;
+*----
+* Self-Shielding calculation SYBIL
+* Transport calculation SYBIL
+* Flux calculation for B1 homogeneous leakage
+* Editing using SPH model for transport-diffusion
+*----
+DISCR := SYBILT: ASSMBH ::
+ TITLE 'TCWW03: MULTICELL HEXAGONAL ASSEMBLY WITH POISON'
+ MAXR 400 MAXZ 15000 QUA2 6 3 ;
+LIBRARY := SHI: LIBRARY DISCR :: EDIT 0 NOLJ ;
+CP := ASM: LIBRARY DISCR ;
+CALC := FLU: CP LIBRARY DISCR ::
+ TYPE B B1 PNL ;
+assertS CALC :: 'K-INFINITY' 1 0.7105012 ;
+OUT := EDI: CALC LIBRARY DISCR ASSMBH ::
+ EDIT 3 UPS SAVE MICR RES MERGE CELL COND 4.0
+ ;
+SPHGEOM := OUT :: STEP UP 'MACRO-GEOM' ;
+MTRACK := BIVACT: SPHGEOM :: PRIM 1 2 ;
+OUT := SPH: OUT MTRACK ;
+SPHGEOM MTRACK := DELETE: SPHGEOM MTRACK ;
+
+DATABASE := COMPO: ::
+ EDIT 5
+ COMM 'Multi-parameter reactor database' ENDC
+ INIT
+ ;
+DATABASE := COMPO: DATABASE OUT ::
+ EDIT 3
+ ;
+res := DATABASE ;
+
+ISOT := DATABASE :: STEP UP default
+ STEP UP MIXTURES STEP AT 5
+ STEP UP CALCULATIONS STEP AT 1
+ STEP UP ISOTOPESLIST STEP AT 1 ;
+assertS ISOT :: 'NWT0' 1 1.471494E+00 ;
+assertS ISOT :: 'NWT0' 2 1.417598E-01 ;
+
+ECHO "test TCWW03 completed" ;
+END: ;
+QUIT "LIST" .
diff --git a/Dragon/data/twinfrith_proc/TCWW04.c2m b/Dragon/data/twinfrith_proc/TCWW04.c2m
new file mode 100644
index 0000000..d996551
--- /dev/null
+++ b/Dragon/data/twinfrith_proc/TCWW04.c2m
@@ -0,0 +1,151 @@
+*----
+* TEST CASE TCWW04
+* WIMS-AECL 69 GROUPS LIBRARY FILE WIMSLIB
+* ANNULAR MOSTELLER BENCHMARK WITH BURNUP
+*
+* REF: R. Mosteller et al. Nucl. Sci. Eng. 107, 265 (1991)
+*
+*----
+* Define variables
+*----
+INTEGER
+ istep := 1 ;
+REAL
+ evobeg evoend ;
+REAL
+ step2 step3 step4 step5 :=
+ 1.0 27.1739 67.9348 135.8696 ;
+*----
+* Define STRUCTURES and MODULES used
+*----
+LINKED_LIST
+ LIBRARY MOSTELAS MOSTELA TRACKS TRACK SYS FLUX BURNUP
+ EDITION DATABASE ISOT ;
+SEQ_ASCII
+ res ;
+MODULE
+ GEO: SYBILT: LIB: SHI: ASM: FLU: EVO: EDI: COMPO: DELETE: END: ;
+PROCEDURE assertS ;
+*----
+* Depletion data from file WIMSLIB format WIMS-AECL
+* Microscopic cross sections from file WIMSLIB format WIMS-AECL
+*----
+LIBRARY := LIB: ::
+ NMIX 3 CTRA WIMS
+ DEPL LIB: WIMSAECL FIL: WIMSLIB
+ MIXS LIB: WIMSAECL FIL: WIMSLIB
+ MIX 1 600.0 O16 = O16 4.61309E-2
+ U235 = U235 1.66078E-4 1
+ U238 = U238 2.28994E-2 1
+ U236 = U236 0.0 1
+ Pu239 = PU239 0.0 1
+ MIX 2 600.0
+ Zr91 = ZR91 3.83243E-2
+ MIX 3 600.0
+ H1H2O = H1H2O 4.42326E-2 O16H2O = O16H2O 2.21163E-2
+ BNat = B-NAT 1.02133E-5
+ ;
+*----
+* Geometry MOSTELAS : 3 regions annular cell for self-shielding
+* MOSTELA : 4 regions annular cell for transport
+*----
+MOSTELAS := GEO: :: TUBE 3
+ R+ REFL RADIUS 0.0 0.39306 0.45802 0.71206
+ MIX 1 2 3 ;
+MOSTELA := GEO: MOSTELAS ::
+ SPLITR 2 1 1 ;
+*----
+* Create the reactor database
+*----
+DATABASE := COMPO: ::
+ EDIT 5
+ COMM 'Multi-parameter reactor database' ENDC
+ PARA 'BURN' IRRA
+ PARA 'FLUB' FLUB
+ INIT
+ ;
+*----
+* Self-Shielding calculation SYBIL
+* Transport calculation SYBIL
+* Flux calculation for keff with imposed buckling
+* using B1 homogeneous leakage model
+*----
+TRACKS := SYBILT: MOSTELAS ::
+ TITLE 'TCWW04: MOSTELLER BENCHMARK WITH BURNUP'
+ EDIT 1 MAXR 3 ;
+LIBRARY := SHI: LIBRARY TRACKS :: EDIT 0 NOLJ ;
+TRACK := SYBILT: MOSTELA ::
+ TITLE 'TCWW04: MOSTELLER BENCHMARK WITH BURNUP'
+ EDIT 1 MAXR 4 ;
+SYS := ASM: LIBRARY TRACK ;
+FLUX := FLU: SYS LIBRARY TRACK ::
+ TYPE K B1 PNL BUCK 0.2948E-2 ;
+assertS FLUX :: 'K-INFINITY' 1 0.8236607 ;
+EDITION := EDI: FLUX LIBRARY TRACK ::
+ EDIT 3 MICR RES MERG COMP COND 4.0 SAVE ;
+*----
+* Burnup loop: for first step BURNUP is created
+* while for other steps it is modified
+* two burnup per step:
+* 1) get a first approximation of final composition followed
+* by a transport calculation
+* 2) use approximation for final flux distribution to get a
+* better approximation for final composition
+*----
+EVALUATE evoend := 0.0 ;
+WHILE evoend step2 < DO
+ EVALUATE evobeg := evoend ;
+ EVALUATE evoend := step2 ;
+ IF istep 1 = THEN
+ BURNUP LIBRARY := EVO: LIBRARY FLUX TRACK ::
+ SAVE <<evobeg>> DAY POWR 36.8
+ DEPL <<evobeg>> <<evoend>> DAY POWR 36.8
+ SET <<evoend>> DAY ;
+ ELSE
+ BURNUP LIBRARY := EVO: BURNUP LIBRARY FLUX TRACK ::
+ SAVE <<evobeg>> DAY POWR 36.8
+ NOEX DEPL <<evobeg>> <<evoend>> DAY POWR 36.8
+ SET <<evoend>> DAY ;
+ ENDIF ;
+ LIBRARY := SHI: LIBRARY TRACKS :: EDIT 0 NOLJ ;
+ SYS := DELETE: SYS ;
+ SYS := ASM: LIBRARY TRACK ;
+ FLUX := FLU: FLUX SYS LIBRARY TRACK ::
+ TYPE K B1 PNL BUCK 0.2948E-2 ;
+
+ BURNUP LIBRARY := EVO: BURNUP LIBRARY FLUX TRACK ::
+ SAVE <<evoend>> DAY POWR 36.8
+ DEPL <<evobeg>> <<evoend>> DAY POWR 36.8
+ SET <<evoend>> DAY ;
+ LIBRARY := SHI: LIBRARY TRACKS ;
+ SYS := DELETE: SYS ;
+ SYS := ASM: LIBRARY TRACK ;
+ FLUX := FLU: FLUX SYS LIBRARY TRACK ::
+ TYPE K B1 PNL BUCK 0.2948E-2 ;
+
+ EDITION := EDI: EDITION FLUX LIBRARY TRACK ::
+ EDIT 3 SAVE ;
+ BURNUP LIBRARY := EVO: BURNUP LIBRARY FLUX TRACK ::
+ SAVE <<evoend>> DAY POWR 36.8 ;
+ DATABASE := COMPO: DATABASE EDITION BURNUP ::
+ EDIT 3
+ SET <<evoend>> DAY
+ ;
+ EVALUATE step2 step3 step4 step5 :=
+ step3 step4 step5 step2 ;
+ EVALUATE istep := istep 1 + ;
+ENDWHILE ;
+assertS FLUX :: 'K-EFFECTIVE' 1 0.7478188 ;
+
+res := DATABASE ;
+
+ISOT := DATABASE :: STEP UP default
+ STEP UP MIXTURES STEP AT 1
+ STEP UP CALCULATIONS STEP AT 2
+ STEP UP ISOTOPESLIST STEP AT 1 ;
+assertS ISOT :: 'NWT0' 1 3.869777E+01 ;
+assertS ISOT :: 'NWT0' 2 1.692535E+01 ;
+
+ECHO "test TCWW04 completed" ;
+END: ;
+QUIT "LIST" .
diff --git a/Dragon/data/twinfrith_proc/TCWW05.c2m b/Dragon/data/twinfrith_proc/TCWW05.c2m
new file mode 100644
index 0000000..d08481d
--- /dev/null
+++ b/Dragon/data/twinfrith_proc/TCWW05.c2m
@@ -0,0 +1,218 @@
+*----
+* TEST CASE TCWW05
+* CANDU-6 ANNULAR CELL
+* WIMS-AECL 69 GROUPS LIBRARY FILE WIMSLIB
+* POWER (KW) = 615.00000
+* BURN POWER (KW/KG) = 31.97130
+* URANIUM MASS = 19.23600
+* UO2 REAL DENSITY = 10.59300
+* UO2 EFF DENSITY = 10.43750
+* UO2 TEMPERATURE = 941.28998
+* ENRICHMENT = 0.71140
+* COOLANT D2 AT % = 99.222
+* MODERATOR D2 AT % = 99.911
+* NUMBER OF DAYS = 50
+*
+* REF: R. Roy et al. Ann. Nucl. Energy 21, 115 (1994)
+*
+*----
+* Define variables and initialize
+* Burnup paremeters
+* a) Power
+* = 31.9713 kw/kg for 0.0 to 300.0 days
+* b) Burnup time interval Delt
+* = 1 day for 0 to 1 day
+* = 4 days for 1 to 5 days
+* = 5 days for 5 to 10 days
+* = 10 days for 10 to 50 days
+* = 20 days for 50 to 150 days
+* = 50 days for 150 to 300 days
+* c) Days with burnup interval changes
+* = 1.0, 5.0, 10.0, 50.0, 150.0 and 300.0 days
+* d) Burnup control time variables Timei, Timef, TotalTime
+* Timei = initial time
+* Timef = final time
+* TotalTime = Final time reached
+*----
+REAL
+ Power Delt Timec Timei Timef TotalTime :=
+ 31.9713 1.0 1.0 0.0 0.0 300.0 ;
+*----
+* Define STRUCTURES and MODULES used
+*----
+LINKED_LIST
+ LIBRARY CANDU6S CANDU6F VOLMATS VOLMATF PIJ FLUX BURNUP EDITION
+ DATABASE ISOT ;
+SEQ_BINARY
+ INTLINS INTLINF ;
+SEQ_ASCII
+ database ;
+MODULE
+ GEO: EXCELT: LIB: SHI: ASM: FLU: EVO: EDI: COMPO: DELETE: END: ;
+PROCEDURE assertS ;
+*----
+* Depletion data from file WIMSLIB format WIMS-AECL
+* Microscopic cross sections from file WIMSLIB format WIMS-AECL
+*----
+LIBRARY := LIB: ::
+ NMIX 10 CTRA WIMS
+ DEPL LIB: WIMSAECL FIL: WIMSLIB
+ MIXS LIB: WIMSAECL FIL: WIMSLIB
+ MIX 1 560.66 0.81212 O16 = O16 7.99449E-1
+ D2D2O = D2D2O 1.99768E-1 H1H2O = H1H2O 7.83774E-4
+ MIX 2 560.66 6.57 Nb93 = NB93 2.50000
+ BNat = B-NAT 2.10000E-4
+ Zr91 = ZR91 9.75000E+1
+ MIX 3 345.66 0.0014 He4 = HE4 1.00000E+2
+ MIX 4 345.66 6.44 Fe56 = FE56A 1.60000E-1
+ Ni58 = NI58 6.00000E-2 Cr52 = CR52 1.10000E-1
+ BNat = B-NAT 3.10000E-4
+ Zr91 = ZR91 9.97100E+1
+ MIX 5 345.66 1.082885 O16 = O16 7.98895E-1
+ D2D2O = D2D2O 2.01016E-1 H1H2O = H1H2O 8.96000E-5
+ MIX 6 941.29 10.4375010 O16 = O16 1.18473E+1
+ Xe135 = XE135 0.0
+ U235 = U235 6.27118E-1 1
+ U238 = U238 8.75256E+1 1
+ U236 = U236 0.0 1
+ Pu239 = PU239 0.0 1
+ MIX 7 COMB 6 1.0
+ MIX 8 COMB 6 1.0
+ MIX 9 COMB 6 1.0
+ MIX 10 560.66 6.44 Fe56 = FE56A 1.60000E-1
+ Ni58 = NI58 6.00000E-2 Cr52 = CR52 1.10000E-1
+ BNat = B-NAT 3.10000E-4
+ Zr91 = ZR91 9.97100E+1
+ ;
+*----
+* Geometry CANDU6S : 13 regions annular cluster for self-shielding
+* CANDU6F : 31 regions annular cluster for transport
+*----
+CANDU6S := GEO: :: TUBE 5
+ R+ REFL RADIUS 0.00000 5.16890 5.60320 6.44780 6.58750 16.12171
+ MIX 1 2 3 4 5
+ CLUSTER ROD1 ROD2 ROD3 ROD4
+ ::: ROD1 := GEO: TUBE 2 MIX 6 10 NPIN 1 RPIN 0.0000 APIN 0.0000
+ RADIUS 0.00000 0.6122 0.6540 ;
+ ::: ROD2 := GEO: ROD1 MIX 7 10 NPIN 6 RPIN 1.4885 APIN 0.0000 ;
+ ::: ROD3 := GEO: ROD1 MIX 8 10 NPIN 12 RPIN 2.8755 APIN 0.261799 ;
+ ::: ROD4 := GEO: ROD1 MIX 9 10 NPIN 18 RPIN 4.3305 APIN 0.0 ;
+ ;
+CANDU6F := GEO: CANDU6S :: SPLITR 6 1 1 1 10
+ ::: ROD1 := GEO: ROD1 SPLITR 2 1 ;
+ ::: ROD2 := GEO: ROD2 SPLITR 2 1 ;
+ ::: ROD3 := GEO: ROD3 SPLITR 2 1 ;
+ ::: ROD4 := GEO: ROD4 SPLITR 2 1 ;
+ ;
+*----
+* Create the reactor database
+*----
+DATABASE := COMPO: ::
+ EDIT 5
+ STEP UP 'moderator'
+ COMM 'Multi-parameter reactor database for moderator' ENDC
+ INIT
+ STEP UP 'fuel'
+ COMM 'Multi-parameter reactor database for fuel' ENDC
+ PARA 'BURN' IRRA
+ PARA 'FLUB' FLUB
+ INIT
+ ;
+*----
+* Self-Shielding calculation EXCEL
+* Transport calculation EXCEL
+* Flux calculation for keff
+*----
+VOLMATS INTLINS := EXCELT: CANDU6S ::
+ TITLE 'TCWW05: CANDU-6 ANNULAR POWER= 31.971 FUEL TEMP= 941.29'
+ EDIT 0 MAXR 13 TRAK TISO 5 10.0 SYMM 12 ;
+LIBRARY := SHI: LIBRARY VOLMATS INTLINS :: EDIT 0 NOLJ ;
+VOLMATF INTLINF := EXCELT: CANDU6F ::
+ TITLE 'TCWW05: CANDU-6 ANNULAR POWER= 31.971 FUEL TEMP= 941.29'
+ EDIT 0 MAXR 31 TRAK TISO 5 10.0 SYMM 12 ;
+PIJ := ASM: LIBRARY VOLMATF INTLINF ;
+FLUX := FLU: PIJ LIBRARY VOLMATF ::
+ TYPE K ;
+assertS FLUX :: 'K-INFINITY' 1 1.117656 ;
+EDITION := EDI: FLUX LIBRARY VOLMATF ::
+ COND 4.0 MERGE MIX 0 0 0 0 1 0 0 0 0 0 MICR RES SAVE ON 'moderator' ;
+DATABASE := COMPO: DATABASE EDITION ::
+ EDIT 3
+ STEP UP *
+ ;
+EDITION := EDI: EDITION FLUX LIBRARY VOLMATF ::
+ COND 4.0 MERGE COMP MICR 1 Xe135 SAVE ON 'fuel' ;
+*----
+* Burnup loop: for first step BURNUP is created
+* while for other steps it is modified
+*----
+WHILE Timei TotalTime < DO
+ EVALUATE Timef := Timei Delt + ;
+ IF Timei 0.0 = THEN
+ BURNUP LIBRARY := EVO: LIBRARY FLUX VOLMATF ::
+ DEPL <<Timei>> <<Timef>> DAY POWR <<Power>> ;
+ ELSE
+ BURNUP LIBRARY := EVO: BURNUP LIBRARY FLUX VOLMATF ::
+ NOEX DEPL <<Timei>> <<Timef>> DAY POWR <<Power>> ;
+ ENDIF ;
+ LIBRARY := SHI: LIBRARY VOLMATS INTLINS :: EDIT 0 NOLJ ;
+ PIJ := DELETE: PIJ ;
+ PIJ := ASM: LIBRARY VOLMATF INTLINF ;
+ FLUX := FLU: FLUX PIJ LIBRARY VOLMATF ::
+ TYPE K ;
+ EDITION := EDI: EDITION FLUX LIBRARY VOLMATF ::
+ SAVE ON 'fuel' ;
+ BURNUP LIBRARY := EVO: BURNUP LIBRARY FLUX VOLMATF ::
+ SAVE <<Timef>> DAY POWR <<Power>> ;
+ DATABASE := COMPO: DATABASE EDITION BURNUP LIBRARY ::
+ EDIT 3
+ STEP UP *
+ SET <<Timef>> DAY
+ ;
+*----
+* change delta t for burnup and final time if required
+*----
+ IF Timef Timec = THEN
+ IF Timec 150.0 = THEN
+ EVALUATE Delt Timec := 50.0 300.0 ;
+ ENDIF ;
+ IF Timec 50.0 = THEN
+ EVALUATE Delt Timec := 20.0 150.0 ;
+ ENDIF ;
+ IF Timec 10.0 = THEN
+ EVALUATE Delt Timec := 10.0 50.0 ;
+ ENDIF ;
+ IF Timec 5.0 = THEN
+ EVALUATE Delt Timec := 5.0 10.0 ;
+ ENDIF ;
+ IF Timec 1.0 = THEN
+ EVALUATE Delt Timec := 4.0 5.0 ;
+ ENDIF ;
+ ENDIF ;
+ EVALUATE Timei := Timef ;
+ENDWHILE ;
+assertS FLUX :: 'K-INFINITY' 1 0.9566035 ;
+*----
+* Export and access the database
+*----
+database := DATABASE ;
+
+ISOT := DATABASE :: STEP UP fuel
+ STEP UP MIXTURES STEP AT 1
+ STEP UP CALCULATIONS STEP AT 5
+ STEP UP ISOTOPESLIST STEP AT 1 ;
+assertS ISOT :: 'NWT0' 1 9.786811E+00 ;
+assertS ISOT :: 'NWT0' 2 2.550574E+01 ;
+ISOT := DELETE: ISOT ;
+
+ISOT := DATABASE :: STEP UP moderator
+ STEP UP MIXTURES STEP AT 1
+ STEP UP CALCULATIONS STEP AT 1
+ STEP UP ISOTOPESLIST STEP AT 1 ;
+assertS ISOT :: 'NWT0' 1 9.325515E-02 ;
+assertS ISOT :: 'NWT0' 2 3.124018E-01 ;
+
+INTLINF INTLINS := DELETE: INTLINF INTLINS ;
+ECHO "test TCWW05 completed" ;
+END: ;
+QUIT "LIST" .
diff --git a/Dragon/data/twinfrith_proc/TCWW06.c2m b/Dragon/data/twinfrith_proc/TCWW06.c2m
new file mode 100644
index 0000000..86a3abf
--- /dev/null
+++ b/Dragon/data/twinfrith_proc/TCWW06.c2m
@@ -0,0 +1,173 @@
+*----
+* TEST CASE TCWW06
+* CANDU-6 CARTESIAN CELL
+* WIMS-AECL 69 GROUPS LIBRARY FILE WIMSLIB
+* STAINLESS STELL RODS IN 3D SUPERCELL
+*
+* REF: R. Roy et al. Ann. Nucl. Energy 21, 115 (1994)
+*
+*----
+* Define STRUCTURES and MODULES used
+*----
+LINKED_LIST
+ LIBRARY LIBRARY2 CANDU6F CANDU6S TRACK SYS FLUX EDITION BCO BCI
+ SSRODS ;
+SEQ_BINARY
+ INTLIN ;
+MODULE
+ GEO: EXCELT: LIB: SHI: ASM: FLU: EDI: DELETE: END: ;
+PROCEDURE assertS ;
+*----
+* Microscopic cross sections from file WIMSLIB format WIMS-AECL
+*----
+LIBRARY := LIB: ::
+ EDIT 0 NMIX 10 CTRA WIMS
+ MIXS LIB: WIMSAECL FIL: WIMSLIB
+ MIX 1 560.66 0.81212 O16 = O16 7.99449E-1
+ D2D2O = D2D2O 1.99768E-1 H1H2O = H1H2O 7.83774E-4
+ MIX 2 560.66 6.57 Nb93 = NB93 2.50000
+ BNat = B-NAT 2.10000E-4
+ Zr91 = ZR91 9.75000E+1
+ MIX 3 345.66 0.0014 He4 = HE4 1.00000E+2
+ MIX 4 345.66 6.44 Fe56 = FE56A 1.60000E-1
+ Ni58 = NI58 6.00000E-2 Cr52 = CR52 1.10000E-1
+ BNat = B-NAT 3.10000E-4
+ Zr91 = ZR91 9.97100E+1
+ MIX 5 345.66 1.082885 O16 = O16 7.98895E-1
+ D2D2O = D2D2O 2.01016E-1 H1H2O = H1H2O 8.96000E-5
+ MIX 6 941.29 10.4375010 O16 = O16 1.18473E+1
+ U235 = U235 6.27118E-1 1
+ U238 = U238 8.75256E+1 1
+ MIX 7 COMB 6 1.0
+ MIX 8 COMB 6 1.0
+ MIX 9 COMB 6 1.0
+ MIX 10 560.66 6.44 Fe56 = FE56A 1.60000E-1
+ Ni58 = NI58 6.00000E-2 Cr52 = CR52 1.10000E-1
+ BNat = B-NAT 3.10000E-4
+ Zr91 = ZR91 9.97100E+1
+ ;
+*----
+* CELL CALCULATION
+* Geometry CANDU6S : 14 regions Cartesian cluster for self-shielding
+* CANDU6F : 32 regions Cartesian cluster for transport
+* BCO : 48 regions 3D Cartesian geometry
+* BCI : 48 regions 3D Cartesian geometry
+*----
+CANDU6S := GEO: :: CARCEL 5
+ X+ REFL X- REFL MESHX -14.2875 14.2875
+ Y+ REFL Y- REFL MESHY -14.2875 14.2875
+ RADIUS 0.00000 5.16890 5.60320 6.44780 6.58750 14.00
+ MIX 1 2 3 4 5 5
+ CLUSTER ROD1 ROD2 ROD3 ROD4
+ ::: ROD1 := GEO: TUBE 2 MIX 6 10 NPIN 1 RPIN 0.0000 APIN 0.0000
+ RADIUS 0.00000 0.6122 0.6540 ;
+ ::: ROD2 := GEO: ROD1 MIX 7 10 NPIN 6 RPIN 1.4885 APIN 0.0000 ;
+ ::: ROD3 := GEO: ROD1 MIX 8 10 NPIN 12 RPIN 2.8755 APIN 0.261799 ;
+ ::: ROD4 := GEO: ROD1 MIX 9 10 NPIN 18 RPIN 4.3305 APIN 0.0 ;
+ ;
+CANDU6F := GEO: CANDU6S :: SPLITR 6 1 1 1 10
+ ::: ROD1 := GEO: ROD1 SPLITR 2 1 ;
+ ::: ROD2 := GEO: ROD2 SPLITR 2 1 ;
+ ::: ROD3 := GEO: ROD3 SPLITR 2 1 ;
+ ::: ROD4 := GEO: ROD4 SPLITR 2 1 ;
+ ;
+*----
+* Self-Shielding calculation EXCEL
+* Transport calculation EXCEL
+* Flux calculation for keff
+*----
+TRACK INTLIN := EXCELT: CANDU6S ::
+ TITLE 'TCWW06: CANDU-6 CARTESIAN FUEL TEMP= 941.29'
+ EDIT 0 MAXR 14 TRAK TISO 29 20.0 SYMM 4 ;
+LIBRARY := SHI: LIBRARY TRACK INTLIN :: EDIT 0 NOLJ ;
+TRACK INTLIN := DELETE: TRACK INTLIN ;
+TRACK INTLIN := EXCELT: CANDU6F ::
+ TITLE 'TCWW06: CANDU-6 CARTESIAN FUEL TEMP= 941.29'
+ EDIT 0 MAXR 32 TRAK TISO 29 20.0 SYMM 4 ;
+SYS := ASM: LIBRARY TRACK INTLIN ::
+ EDIT 0 ;
+FLUX := FLU: SYS LIBRARY TRACK ::
+ TYPE K ;
+assertS FLUX :: 'K-EFFECTIVE' 1 1.117250 ;
+*----
+* Microscopic cross sections from WIMSLIB for stainless steel
+* MIX 1,2,3 from EDI: : fuel, structure material and moderator
+* MIX 4 stainless steel rods
+*----
+EDITION := EDI: FLUX LIBRARY TRACK ::
+ EDIT 0 MERGE MIX 1 2 2 2 3 1 1 1 1 1 SAVE ON SSRODS ;
+SSRODS := EDITION :: STEP UP SSRODS STEP UP MACROLIB ;
+LIBRARY2 := LIB: SSRODS ::
+ EDIT 0 NMIX 4 CTRA WIMS
+ MIXS LIB: WIMSAECL FIL: WIMSLIB
+ MIX 4 345.66 Fe56 = FE56A 6.19027E-2
+ Cr52 = CR52 1.56659E-3 Ni58 = NI58 6.83337E-3
+ Si29 = SI29 7.79072E-4 C12 = C12 1.46552E-4
+ Mn55 = MN55 1.25431E-3
+ ;
+EDITION TRACK INTLIN SYS FLUX SSRODS := DELETE:
+ EDITION TRACK INTLIN SYS FLUX SSRODS ;
+*----
+* SUPERCELL CALCULATION
+* Geometry BCO : 27 regions 3D Cartesian geometry with rods out
+* BCI : 27 regions 3D Cartesian geometry with rods in
+*----
+BCO := GEO: :: CAR3D 3 2 2
+ X- REFL X+ SYME Y- REFL Y+ SYME Z- REFL Z+ SYME
+ CELL M MX MX MX FXY MXY M MX BX MX FXY BXY
+ TURN A A A F A A A A A F A A
+ ::: M := GEO: CAR3D 1 1 1 MIX 3
+ MESHX 0.0 7.14375
+ MESHY 0.0 7.14375
+ MESHZ -8.25500 8.25500 SPLITZ 2 ;
+ ::: MX := GEO: M MESHX -7.14375 +7.14375 SPLITX 2 ;
+ ::: MXY := GEO: MX MESHY -7.14375 +7.14375 SPLITY 2 ;
+ ::: BX := GEO: CARCELY 2 1 MIX 3 3 3
+ MESHX -7.14375 7.14375 SPLITX 2
+ MESHY 0.0 7.14375
+ MESHZ -8.25500 8.25500 SPLITZ 2
+ RADIUS 0.0 3.5100 3.8100 ;
+ ::: BXY := GEO: BX MESHY -7.14375 +7.14375 SPLITY 2 ;
+ ::: FXY := GEO: CARCELZ 2 1 MIX 1 2 3
+ MESHX -7.14375 7.14375 SPLITX 2
+ MESHY -7.14375 7.14375 SPLITY 2
+ MESHZ -8.25500 8.25500 SPLITZ 2
+ RADIUS 0.0 5.16890 6.58750 ;
+ ;
+BCI := GEO: BCO ::
+ ::: BX := GEO: BX MIX 3 4 3 ;
+ ::: BXY := GEO: BXY MIX 3 4 3 ;
+ ;
+*----
+* Transport calculation EXCEL
+* Flux calculation for keff
+* Homogenized properties for rod out
+*----
+TRACK INTLIN := EXCELT: BCO ::
+ EDIT 0 MAXR 40 TRAK TISO 2 1.0 ;
+SYS := ASM: LIBRARY2 TRACK INTLIN ::
+ EDIT 0 ;
+FLUX := FLU: SYS LIBRARY2 TRACK ::
+ TYPE K ;
+assertS FLUX :: 'K-EFFECTIVE' 1 1.124153 ;
+EDITION := EDI: FLUX LIBRARY2 TRACK ::
+ EDIT 2 MERG COMP COND 4.0 SAVE ON 'NOBC' ;
+SYS TRACK INTLIN := DELETE: SYS TRACK INTLIN ;
+*----
+* Transport calculation EXCEL
+* Flux calculation for keff
+* Homogenized properties for rod in
+*----
+TRACK INTLIN := EXCELT: BCI ::
+ EDIT 0 MAXR 40 TRAK TISO 2 1.0 ;
+SYS := ASM: LIBRARY2 TRACK INTLIN ::
+ EDIT 0 ;
+FLUX := FLU: FLUX SYS LIBRARY2 TRACK ::
+ TYPE K ;
+assertS FLUX :: 'K-EFFECTIVE' 1 1.040033 ;
+EDITION := EDI: EDITION FLUX LIBRARY2 TRACK ::
+ EDIT 2 MERG COMP COND 4.0 STAT DELS REFE 'NOBC' ;
+TRACK INTLIN SYS := DELETE: TRACK INTLIN SYS ;
+ECHO "test TCWW06 completed" ;
+END: ;
+QUIT "LIST" .
diff --git a/Dragon/data/twinfrith_proc/TCWW07.c2m b/Dragon/data/twinfrith_proc/TCWW07.c2m
new file mode 100644
index 0000000..4da9b41
--- /dev/null
+++ b/Dragon/data/twinfrith_proc/TCWW07.c2m
@@ -0,0 +1,162 @@
+*----
+* TEST CASE TCWW07
+* CANDU-6 CARTESIAN CELL
+* WIMS-AECL 69 GROUPS LIBRARY FILE WIMSLIB
+* TEST VARIOUS LEAKAGE OPTIONS
+*
+* REF: R. Roy et al. Ann. Nucl. Energy 21, 115 (1994)
+*
+*----
+* Define STRUCTURES and MODULES used
+*----
+LINKED_LIST
+ LIBRARY CANDU6S CANDU6T CANDU6SV CANDU6TV TRACK
+ SYS FLUX EDITION ;
+MODULE
+ GEO: EXCELT: LIB: SHI: ASM: FLU: EDI: DELETE: END: ;
+SEQ_BINARY
+ INTLIN ;
+PROCEDURE assertS ;
+*----
+* Microscopic cross sections from file WIMSLIB format WIMS-AECL
+*----
+LIBRARY := LIB: ::
+ EDIT 0 NMIX 10 CTRA WIMS
+ MIXS LIB: WIMSAECL FIL: WIMSLIB
+ MIX 1 560.66 0.81212 O16 = O16 7.99449E-1
+ D2D2O = D2D2O 1.99768E-1 H1H2O = H1H2O 7.83774E-4
+ MIX 2 560.66 6.57 Nb93 = NB93 2.50000
+ BNat = B-NAT 2.10000E-4
+ Zr91 = ZR91 9.75000E+1
+ MIX 3 345.66 0.0014 He4 = HE4 1.00000E+2
+ MIX 4 345.66 6.44 Fe56 = FE56A 1.60000E-1
+ Ni58 = NI58 6.00000E-2 Cr52 = CR52 1.10000E-1
+ BNat = B-NAT 3.10000E-4
+ Zr91 = ZR91 9.97100E+1
+ MIX 5 345.66 1.082885 O16 = O16 7.98895E-1
+ D2D2O = D2D2O 2.01016E-1 H1H2O = H1H2O 8.96000E-5
+ MIX 6 941.29 10.4375010 O16 = O16 1.18473E+1
+ U235 = U235 6.27118E-1 1
+ U238 = U238 8.75256E+1 1
+ MIX 7 COMB 6 1.0
+ MIX 8 COMB 6 1.0
+ MIX 9 COMB 6 1.0
+ MIX 10 560.66 6.44 Fe56 = FE56A 1.60000E-1
+ Ni58 = NI58 6.00000E-2 Cr52 = CR52 1.10000E-1
+ BNat = B-NAT 3.10000E-4
+ Zr91 = ZR91 9.97100E+1
+ ;
+*----
+* Geometry CANDU6S : GEOMETRY FOR SELF-SHIELDING (NO VOID)
+* CANDU6F : GEOMETRY FOR TRANSPORT (NO VOID)
+* CANDU6FV: GEOMETRY FOR TRANSPORT (COOLANT VOID)
+* CANDU6FV: GEOMETRY FOR TRANSPORT (COOLANT VOID)
+*----
+CANDU6S := GEO: :: CARCEL 5
+ X+ REFL X- REFL MESHX -14.2875 14.2875
+ Y+ REFL Y- REFL MESHY -14.2875 14.2875
+ RADIUS 0.00000 5.16890 5.60320 6.44780 6.58750 14.00
+ MIX 1 2 3 4 5 5
+ CLUSTER ROD1 ROD2 ROD3 ROD4
+ ::: ROD1 := GEO: TUBE 2 MIX 6 10 NPIN 1 RPIN 0.0000 APIN 0.0000
+ RADIUS 0.00000 0.6122 0.6540 ;
+ ::: ROD2 := GEO: ROD1 MIX 7 10 NPIN 6 RPIN 1.4885 APIN 0.0000 ;
+ ::: ROD3 := GEO: ROD1 MIX 8 10 NPIN 12 RPIN 2.8755 APIN 0.261799 ;
+ ::: ROD4 := GEO: ROD1 MIX 9 10 NPIN 18 RPIN 4.3305 APIN 0.0 ;
+ ;
+CANDU6T := GEO: CANDU6S :: SPLITR 6 1 1 1 10
+ ::: ROD1 := GEO: ROD1 SPLITR 2 1 ;
+ ::: ROD2 := GEO: ROD2 SPLITR 2 1 ;
+ ::: ROD3 := GEO: ROD3 SPLITR 2 1 ;
+ ::: ROD4 := GEO: ROD4 SPLITR 2 1 ;
+ ;
+CANDU6SV := GEO: CANDU6S :: MIX 0 2 3 4 5 5 ;
+CANDU6TV := GEO: CANDU6SV :: SPLITR 6 1 1 1 10
+ ::: ROD1 := GEO: ROD1 SPLITR 2 1 ;
+ ::: ROD2 := GEO: ROD2 SPLITR 2 1 ;
+ ::: ROD3 := GEO: ROD3 SPLITR 2 1 ;
+ ::: ROD4 := GEO: ROD4 SPLITR 2 1 ;
+ ;
+*----
+* CASE WITH NO VOID
+* Self-Shielding calculation EXCEL
+* Transport calculation EXCEL
+* Flux TYPE K AND B WITH VARIOUS LEAKAGE OPTIONS
+*----
+TRACK INTLIN := EXCELT: CANDU6S ::
+ TITLE 'TCWW07: CANDU-6 CARTESIAN FUEL TEMP= 941.29'
+ EDIT 0 MAXR 14 TRAK TISO 7 20.0 SYMM 4 ;
+LIBRARY := SHI: LIBRARY TRACK INTLIN :: EDIT 0 NOLJ ;
+TRACK INTLIN := DELETE: TRACK INTLIN ;
+TRACK INTLIN := EXCELT: CANDU6T ::
+ TITLE 'TCWW07: CANDU-6 CARTESIAN FUEL TEMP= 941.29'
+ EDIT 0 MAXR 32 ANIS 2 TRAK TISO 7 20.0 SYMM 4 ;
+SYS := ASM: LIBRARY TRACK INTLIN ::
+ EDIT 0 PIJK ;
+FLUX := FLU: SYS LIBRARY TRACK ::
+ TYPE K ;
+assertS FLUX :: 'K-EFFECTIVE' 1 1.117214 ;
+EDITION := EDI: FLUX LIBRARY TRACK ::
+ EDIT 3 SAVE COND 4.0 TAKE REGI 1 4 7 10 16 24 ;
+FLUX := FLU: FLUX SYS LIBRARY TRACK ::
+ TYPE B B1 PNL ;
+assertS FLUX :: 'K-INFINITY' 1 1.109208 ;
+EDITION := EDI: EDITION FLUX LIBRARY TRACK ::
+ EDIT 3 SAVE COND 4.0 TAKE REGI 1 4 7 10 16 24 ;
+FLUX := FLU: FLUX SYS LIBRARY TRACK ::
+ TYPE B B1 HETE ;
+assertS FLUX :: 'K-INFINITY' 1 1.108972 ;
+EDITION := EDI: EDITION FLUX LIBRARY TRACK ::
+ EDIT 3 SAVE COND 4.0 TAKE REGI 1 4 7 10 16 24 ;
+FLUX SYS := DELETE: FLUX SYS ;
+SYS := ASM: LIBRARY TRACK INTLIN ::
+ EDIT 0 PIJ ECCO ;
+FLUX := FLU: SYS LIBRARY TRACK ::
+ TYPE B B1 ECCO ;
+assertS FLUX :: 'K-INFINITY' 1 1.108980 ;
+EDITION := EDI: EDITION FLUX LIBRARY TRACK ::
+ EDIT 3 SAVE COND 4.0 TAKE REGI 1 4 7 10 16 24 ;
+FLUX SYS TRACK INTLIN := DELETE: FLUX SYS TRACK INTLIN ;
+*----
+* CASE WITH COOLANT VOIDED
+* Self-Shielding calculation EXCEL
+* Transport calculation EXCEL
+* Flux TYPE K AND B WITH VARIOUS LEAKAGE OPTIONS
+*----
+TRACK INTLIN := EXCELT: CANDU6SV ::
+ TITLE 'TCWW07: CANDU-6 CARTESIAN FUEL TEMP= 941.29'
+ EDIT 0 MAXR 14 TRAK TISO 7 20.0 SYMM 4 ;
+LIBRARY := SHI: LIBRARY TRACK INTLIN :: EDIT 0 NOLJ ;
+TRACK INTLIN := DELETE: TRACK INTLIN ;
+TRACK INTLIN := EXCELT: CANDU6TV ::
+ TITLE 'TCWW07: CANDU-6 CARTESIAN FUEL TEMP= 941.29'
+ EDIT 0 MAXR 32 ANIS 2 TRAK TISO 7 20.0 SYMM 4 ;
+SYS := ASM: LIBRARY TRACK INTLIN ::
+ EDIT 0 PIJK ;
+FLUX := FLU: SYS LIBRARY TRACK ::
+ TYPE K ;
+assertS FLUX :: 'K-EFFECTIVE' 1 1.137481 ;
+EDITION := EDI: EDITION FLUX LIBRARY TRACK ::
+ EDIT 3 SAVE COND 4.0 TAKE REGI 1 4 7 10 16 24 ;
+FLUX := FLU: FLUX SYS LIBRARY TRACK ::
+ TYPE B B1 PNL ;
+assertS FLUX :: 'K-INFINITY' 1 1.129739 ;
+EDITION := EDI: EDITION FLUX LIBRARY TRACK ::
+ EDIT 3 SAVE COND 4.0 TAKE REGI 1 4 7 10 16 24 ;
+FLUX := FLU: FLUX SYS LIBRARY TRACK ::
+ TYPE B B1 HETE ;
+assertS FLUX :: 'K-INFINITY' 1 1.129309 ;
+EDITION := EDI: EDITION FLUX LIBRARY TRACK ::
+ EDIT 3 SAVE COND 4.0 TAKE REGI 1 4 7 10 16 24 ;
+FLUX SYS := DELETE: FLUX SYS ;
+SYS := ASM: LIBRARY TRACK INTLIN ::
+ EDIT 0 PIJ ECCO ;
+FLUX := FLU: SYS LIBRARY TRACK ::
+ TYPE B B1 ECCO ;
+assertS FLUX :: 'K-INFINITY' 1 1.129767 ;
+EDITION := EDI: EDITION FLUX LIBRARY TRACK ::
+ EDIT 3 SAVE COND 4.0 TAKE REGI 1 4 7 10 16 24 ;
+FLUX SYS TRACK INTLIN := DELETE: FLUX SYS TRACK INTLIN ;
+ECHO "test TCWW07 completed" ;
+END: ;
+QUIT "LIST" .
diff --git a/Dragon/data/twinfrith_proc/TCWW08.c2m b/Dragon/data/twinfrith_proc/TCWW08.c2m
new file mode 100644
index 0000000..7ebbcb8
--- /dev/null
+++ b/Dragon/data/twinfrith_proc/TCWW08.c2m
@@ -0,0 +1,121 @@
+*----
+* TEST CASE TCWW08
+* HOMOGENEOUS DEPLETION CASE
+* WIMS-AECL 69 GROUPS LIBRARY FILE WIMSLIB
+*
+* REF: None
+*
+*----
+* Define variables
+* Burnup paremeters
+* a) Power
+* = 600.0 kw/kg for 0.0 to 1000.0 days
+* = 0.0 kw/kg for 1000.0 to 2000.0 days
+* b) Burnup time interval Delt
+* = 10 days for 0 to 50 days
+* = 50 days for 50 to 500 days
+* = 100 days for 500 to 1000 days
+* = 1000 days for 1000 to 2000 days
+* c) Editing time Timec
+* = 0.0, 50.0, 500.0, 1000.0 and 2000.0 days
+* d) Burnup control time variables Timei, Timef, TotalTime
+* Timei = initial time
+* Timef = final time
+* TotalTime = Final time reached
+* d) Print variable Iprint
+* = 1 reduced print
+* = 3 full print
+*----
+REAL
+ Power Delt Timec Timei Timef TotalTime :=
+ 600.0 10.0 50.0 0.0 0.0 2000.0 ;
+INTEGER
+ Iprint := 1 ;
+*----
+* Define STRUCTURES and MODULES used
+*----
+LINKED_LIST
+ LIBRARY HOM TRACK PIJ FLUX BURNUP EDITION ;
+MODULE
+ GEO: SYBILT: LIB: SHI: ASM: FLU: EVO: EDI: DELETE: END: ;
+PROCEDURE assertS ;
+*----
+* Depletion data from file WIMSLIB format WIMS-AECL
+* Microscopic cross sections from file WIMSLIB format WIMS-AECL
+*----
+LIBRARY := LIB: ::
+ NMIX 1 CTRA WIMS
+ DEPL LIB: WIMSAECL FIL: WIMSLIB
+ MIXS LIB: WIMSAECL FIL: WIMSLIB
+ MIX 1 300.0 H1 = H1 2.00000E+1
+ U235 = U235 1.0 1
+ U236 = U236 0.0 1
+ ;
+*----
+* Geometry HOM : Homogeneous geometry
+*----
+HOM := GEO: :: HOMOGE
+ MIX 1 ;
+*----
+* Self-Shielding calculation SYBIL
+* Transport calculation SYBIL
+* Flux calculation for keff
+*----
+TRACK := SYBILT: HOM ::
+ TITLE 'TCWW08: HOMOGENEOUS BENCHMARK WITH BURNUP' ;
+LIBRARY := SHI: LIBRARY TRACK :: EDIT 0 NOLJ ;
+PIJ := ASM: LIBRARY TRACK ;
+FLUX := FLU: PIJ LIBRARY TRACK ::
+ TYPE K ;
+assertS FLUX :: 'K-EFFECTIVE' 1 1.857078 ;
+EDITION := EDI: FLUX LIBRARY TRACK ::
+ COND 4.0 MERGE COMP SAVE ;
+*----
+* Burnup loop: for first step BURNUP is created
+* while for other steps it is modified
+*----
+WHILE Timei TotalTime < DO
+ EVALUATE Timef := Timei Delt + ;
+ IF Timef Timec = THEN
+ EVALUATE Iprint := 3 ;
+ ELSE
+ EVALUATE Iprint := 1 ;
+ ENDIF ;
+ IF Timei 0.0 = THEN
+ BURNUP LIBRARY := EVO: LIBRARY FLUX TRACK ::
+ EDIT <<Iprint>> DEPL <<Timei>> <<Timef>> DAY
+ POWR <<Power>> ;
+ ELSE
+ BURNUP LIBRARY := EVO: BURNUP LIBRARY FLUX TRACK ::
+ EDIT <<Iprint>> NOEX DEPL <<Timei>> <<Timef>> DAY
+ POWR <<Power>> ;
+ ENDIF ;
+ LIBRARY := SHI: LIBRARY TRACK :: EDIT 0 NOLJ ;
+ PIJ := DELETE: PIJ ;
+ PIJ := ASM: LIBRARY TRACK ;
+ FLUX := FLU: FLUX PIJ LIBRARY TRACK ::
+ TYPE K ;
+ IF Iprint 3 = THEN
+ EDITION := EDI: EDITION FLUX LIBRARY TRACK ::
+ SAVE ;
+ ENDIF ;
+*----
+* change delta t for burnup, final time and power if required
+*----
+ IF Timef Timec = THEN
+ IF Timec 1000.0 = THEN
+ EVALUATE Power Delt Timec := 0.0 1000.0 2000.0 ;
+ ENDIF ;
+ IF Timec 500.0 = THEN
+ EVALUATE Delt Timec := 100.0 1000.0 ;
+ ENDIF ;
+ IF Timec 50.0 = THEN
+ EVALUATE Delt Timec := 50.0 500.0 ;
+ ENDIF ;
+ ENDIF ;
+ EVALUATE Timei := Timef ;
+ENDWHILE ;
+assertS FLUX :: 'K-EFFECTIVE' 1 1.265182 ;
+ECHO "test TCWW08 completed" ;
+END: ;
+QUIT "LIST" .
diff --git a/Dragon/data/twinfrith_proc/TCWW09.c2m b/Dragon/data/twinfrith_proc/TCWW09.c2m
new file mode 100644
index 0000000..c6a176f
--- /dev/null
+++ b/Dragon/data/twinfrith_proc/TCWW09.c2m
@@ -0,0 +1,72 @@
+*----
+* TEST CASE TCWW09
+* MOSTELLER BENCHMARK FOR 1-D ANNULAR CELL
+* WIMS-AECL 69 GROUPS LIBRARY FILE WIMSLIB
+* REFLECTIVE AND VOID BC
+*
+* REF: None
+*
+*----
+* Define STRUCTURES and MODULES used
+*----
+LINKED_LIST
+ MOSTELA MOSTELV VOLMAT LIBRARY PIJ FLUX OUT ;
+MODULE
+ LIB: GEO: SYBILT: SHI: ASM: FLU: EDI: DELETE: END: ;
+PROCEDURE assertS ;
+*----
+* Microscopic cross section from file WIMSLIB format WIMS-AECL
+*----
+LIBRARY := LIB: ::
+ NMIX 3 CTRA WIMS
+ MIXS LIB: WIMSAECL FIL: WIMSLIB
+ MIX 1 600.0 O16 = O16 4.61309E-2
+ U235 = U235 1.66078E-4 1
+ U238 = U238 2.28994E-2 1
+ MIX 2 600.0
+ Zr91 = ZR91 3.83243E-2
+ MIX 3 600.0
+ H1H2O = H1H2O 4.42326E-2 O16H2O = O16H2O 2.21163E-2
+ BNat = B-NAT 1.02133E-5
+ ;
+*----
+* Geometry MOSTELA : Annular cell with reflective BC
+* MOSTELV : Annular cell with void BC
+*----
+MOSTELA := GEO: :: TUBE 3
+ RADIUS 0.0 0.39306 0.45802 0.71206
+ SPLITR 2 1 1
+ MIX 1 2 3
+ R+ REFL ;
+MOSTELV := GEO: MOSTELA ::
+ R+ VOID ;
+*----
+* Self-Shielding calculation SYBIL
+* Transport calculation SYBIL
+* Flux calculation for keff
+*----
+VOLMAT := SYBILT: MOSTELA ::
+ TITLE 'TCWW09: SYBIL TRACK MOSTELLER BENCHMARK REFLECTIVE BC '
+ MAXR 4 QUA1 5 ;
+LIBRARY := SHI: LIBRARY VOLMAT :: EDIT 0 NOLJ ;
+PIJ := ASM: LIBRARY VOLMAT ;
+FLUX := FLU: PIJ LIBRARY VOLMAT ::
+ TYPE K ;
+assertS FLUX :: 'K-EFFECTIVE' 1 0.8267476 ;
+OUT := EDI: FLUX LIBRARY VOLMAT ::
+ EDIT 4 MERG MIX 1 2 3 COND 4.0 SAVE ;
+PIJ VOLMAT := DELETE: PIJ VOLMAT ;
+VOLMAT := SYBILT: MOSTELV ::
+ TITLE 'TCWW09: SYBIL TRACK MOSTELLER BENCHMARK VOID BC '
+ MAXR 4 QUA1 5 ;
+PIJ := ASM: LIBRARY VOLMAT ;
+FLUX := FLU: FLUX PIJ LIBRARY VOLMAT ::
+ TYPE K ;
+assertS FLUX :: 'K-EFFECTIVE' 1 1.077951E-02 ;
+OUT := EDI: OUT FLUX LIBRARY VOLMAT ::
+ EDIT 4 MERG MIX 1 2 3 COND 4.0 SAVE ;
+OUT FLUX PIJ LIBRARY VOLMAT := DELETE:
+ OUT FLUX PIJ LIBRARY VOLMAT ;
+ECHO "test TCWW09 completed" ;
+END: ;
+QUIT "LIST" .
diff --git a/Dragon/data/twinfrith_proc/TCWW10.c2m b/Dragon/data/twinfrith_proc/TCWW10.c2m
new file mode 100644
index 0000000..d23f5bf
--- /dev/null
+++ b/Dragon/data/twinfrith_proc/TCWW10.c2m
@@ -0,0 +1,78 @@
+*----
+* TEST CASE TCWW10
+* MOSTELLER BENCHMARK FOR 1-D ANNULAR CELL
+* WIMS-AECL 69 GROUPS LIBRARY FILE WIMSLIB
+* FIXED SOURCE PROBLEM IN MULTIPLICATIVE MEDIA
+*
+* REF: None
+*
+*----
+* Define STRUCTURES and MODULES used
+*----
+LINKED_LIST
+ MOSTELA VOLMAT LIBRARY PIJ FLUX OUT ;
+MODULE
+ LIB: MAC: GEO: SYBILT: SHI: ASM: FLU: EDI: DELETE: END: ;
+PROCEDURE assertS assertV ;
+*----
+* Microscopic cross section from file WIMSLIB format WIMS-AECL
+* Fixed source of 1.0E5 in group 6
+*----
+LIBRARY := LIB: ::
+ EDIT 0 NMIX 3 CTRA WIMS
+ MIXS LIB: WIMSAECL FIL: WIMSLIB
+ MIX 1 600.0 O16 = O16 4.61309E-2
+ U235 = U235 1.66078E-4 1
+ U238 = U238 2.28994E-2 1
+ MIX 2 600.0
+ Zr91 = ZR91 3.83243E-2
+ MIX 3 600.0
+ H1H2O = H1H2O 4.42326E-2 O16H2O = O16H2O 2.21163E-2
+ BNat = B-NAT 1.02133E-5
+ ;
+LIBRARY := MAC: LIBRARY ::
+ EDIT 0
+ READ INPUT
+ MIX 3 FIXE
+ 0.0 0.0 0.0 0.0 0.0 1.0E+5 0.0 0.0 0.0 0.0
+ 0.0 0.0 0.0 0.0 0.0 0.0 0.0 0.0 0.0 0.0
+ 0.0 0.0 0.0 0.0 0.0 0.0 0.0 0.0 0.0 0.0
+ 0.0 0.0 0.0 0.0 0.0 0.0 0.0 0.0 0.0 0.0
+ 0.0 0.0 0.0 0.0 0.0 0.0 0.0 0.0 0.0 0.0
+ 0.0 0.0 0.0 0.0 0.0 0.0 0.0 0.0 0.0 0.0
+ 0.0 0.0 0.0 0.0 0.0 0.0 0.0 0.0 0.0
+ ;
+*----
+* Geometry MOSTELA : Annular cell with reflective BC
+*----
+MOSTELA := GEO: :: TUBE 3
+ RADIUS 0.0 0.39306 0.45802 0.71206
+ SPLITR 2 1 1
+ MIX 1 2 3
+ R+ REFL ;
+*----
+* Self-Shielding calculation SYBIL
+* Transport calculation SYBIL
+* Flux calculation for keff
+*----
+VOLMAT := SYBILT: MOSTELA ::
+ TITLE 'TCWW10: SYBIL TRACK MOSTELLER BENCHMARK'
+ MAXR 4 QUA1 5 ;
+LIBRARY := SHI: LIBRARY VOLMAT :: EDIT 0 NOLJ ;
+PIJ := ASM: LIBRARY VOLMAT ;
+FLUX := FLU: PIJ LIBRARY VOLMAT ::
+ TYPE K ;
+assertS FLUX :: 'K-EFFECTIVE' 1 0.8267476 ;
+OUT := EDI: FLUX LIBRARY VOLMAT ::
+ EDIT 4 MERG MIX 1 2 3 COND 4.0 ;
+FLUX := DELETE: FLUX ;
+FLUX := FLU: PIJ LIBRARY VOLMAT ::
+ TYPE S EXTE 30 UNKT 1.0E-3 ;
+assertV FLUX :: 'FLUX' (*GROUP*) 10 (*REGION*) 4 4.292641E+05 ;
+OUT := EDI: OUT FLUX LIBRARY VOLMAT ::
+ EDIT 4 MERG MIX 1 2 3 COND 4.0 ;
+OUT FLUX PIJ LIBRARY VOLMAT := DELETE:
+ OUT FLUX PIJ LIBRARY VOLMAT ;
+ECHO "test TCWW10 completed" ;
+END: ;
+QUIT "LIST" .
diff --git a/Dragon/data/twinfrith_proc/TCWW11.c2m b/Dragon/data/twinfrith_proc/TCWW11.c2m
new file mode 100644
index 0000000..ea4e5dc
--- /dev/null
+++ b/Dragon/data/twinfrith_proc/TCWW11.c2m
@@ -0,0 +1,204 @@
+*----
+* TEST CASE TCWW11
+* CANDU-6 ANNULAR CELL
+* WIMS-AECL 69 GROUPS LIBRARY FILE WIMSLIB
+* TWO GROUP BURNUP
+* POWER (KW) = 615.00000
+* BURN POWER (KW/KG) = 31.97130
+* URANIUM MASS = 19.23600
+* UO2 REAL DENSITY = 10.59300
+* UO2 EFF DENSITY = 10.43750
+* UO2 TEMPERATURE = 941.28998
+* ENRICHMENT = 0.71140
+* COOLANT D2 AT % = 99.222
+* MODERATOR D2 AT % = 99.911
+* NUMBER OF DAYS = 50
+*
+* REF: R. Roy et al. Ann. Nucl. Energy 21, 115 (1994)
+*
+*----
+* Define variables
+* Burnup paremeters
+* a) Power
+* = 31.9713 kw/kg for 0.0 to 300.0 days
+* b) 69 Groups Burnup time interval Delt
+* = 300 day for 0 to 300 day
+* c) 2 Groups Burnup time interval Delt
+* = 1 day for 0 to 1 day
+* = 4 days for 1 to 5 days
+* = 5 days for 5 to 10 days
+* = 10 days for 10 to 50 days
+* = 20 days for 50 to 150 days
+* = 50 days for 150 to 300 days
+* c) Days with burnup interval changes
+* = 1.0, 5.0, 10.0, 50.0, 150.0 and 300.0 days
+* d) Burnup control time variables Timei, Timef, TotalTime
+* Timei = initial time
+* Timef = final time
+* TotalTime = Final time reached
+*----
+REAL
+ Power Delt Timec Timei Timef TotalTime :=
+ 31.9713 1.0 1.0 0.0 0.0 300.0 ;
+*----
+* Define STRUCTURES and MODULES used
+*----
+LINKED_LIST
+ LIBRARY CANDU6S CANDU6F VOLMATS VOLMATF PIJ FLUX BURNUP EDITION ;
+SEQ_BINARY
+ INTLINS INTLINF ;
+SEQ_ASCII
+ res ;
+MODULE
+ GEO: EXCELT: LIB: SHI: ASM: FLU: EVO: EDI: SPH: DELETE: END: ;
+PROCEDURE assertS ;
+*----
+* Depletion data from file WIMSLIB format WIMS-AECL
+* Microscopic cross sections from file WIMSLIB format WIMS-AECL
+*----
+LIBRARY := LIB: ::
+ NMIX 10 CTRA WIMS
+ DEPL LIB: WIMSAECL FIL: WIMSLIB
+ MIXS LIB: WIMSAECL FIL: WIMSLIB
+ MIX 1 560.66 0.81212 O16 = O16 7.99449E-1
+ D2D2O = D2D2O 1.99768E-1 H1H2O = H1H2O 7.83774E-4
+ MIX 2 560.66 6.57 Nb93 = NB93 2.50000
+ BNat = B-NAT 2.10000E-4
+ Zr91 = ZR91 9.75000E+1
+ MIX 3 345.66 0.0014 He4 = HE4 1.00000E+2
+ MIX 4 345.66 6.44 Fe56 = FE56A 1.60000E-1
+ Ni58 = NI58 6.00000E-2 Cr52 = CR52 1.10000E-1
+ BNat = B-NAT 3.10000E-4
+ Zr91 = ZR91 9.97100E+1
+ MIX 5 345.66 1.082885 O16 = O16 7.98895E-1
+ D2D2O = D2D2O 2.01016E-1 H1H2O = H1H2O 8.96000E-5
+ MIX 6 941.29 10.4375010 O16 = O16 1.18473E+1
+ Xe135 = XE135 0.0
+ U235 = U235 6.27118E-1 1
+ U238 = U238 8.75256E+1 1
+ U236 = U236 0.0 1
+ Pu239 = PU239 0.0 1
+ MIX 7 COMB 6 1.0
+ MIX 8 COMB 6 1.0
+ MIX 9 COMB 6 1.0
+ MIX 10 560.66 6.44 Fe56 = FE56A 1.60000E-1
+ Ni58 = NI58 6.00000E-2 Cr52 = CR52 1.10000E-1
+ BNat = B-NAT 3.10000E-4
+ Zr91 = ZR91 9.97100E+1
+ ;
+*----
+* Geometry CANDU6S : 13 regions annular cluster for self-shielding
+* CANDU6F : 31 regions annular cluster for transport
+*----
+CANDU6S := GEO: :: TUBE 5
+ R+ REFL RADIUS 0.00000 5.16890 5.60320 6.44780 6.58750 16.12171
+ MIX 1 2 3 4 5
+ CLUSTER ROD1 ROD2 ROD3 ROD4
+ ::: ROD1 := GEO: TUBE 2 MIX 6 10 NPIN 1 RPIN 0.0000 APIN 0.0000
+ RADIUS 0.00000 0.6122 0.6540 ;
+ ::: ROD2 := GEO: ROD1 MIX 7 10 NPIN 6 RPIN 1.4885 APIN 0.0000 ;
+ ::: ROD3 := GEO: ROD1 MIX 8 10 NPIN 12 RPIN 2.8755 APIN 0.261799 ;
+ ::: ROD4 := GEO: ROD1 MIX 9 10 NPIN 18 RPIN 4.3305 APIN 0.0 ;
+ ;
+CANDU6F := GEO: CANDU6S :: SPLITR 6 1 1 1 10
+ ::: ROD1 := GEO: ROD1 SPLITR 2 1 ;
+ ::: ROD2 := GEO: ROD2 SPLITR 2 1 ;
+ ::: ROD3 := GEO: ROD3 SPLITR 2 1 ;
+ ::: ROD4 := GEO: ROD4 SPLITR 2 1 ;
+ ;
+*----
+* Self-Shielding calculation EXCEL
+* Transport calculation EXCEL
+* Flux calculation for keff
+*----
+VOLMATS INTLINS := EXCELT: CANDU6S ::
+ TITLE 'TCWW11: FEW GROUP BURNUP / SELF-SHIELDING TRACKING'
+ EDIT 0 MAXR 13 TRAK TISO 5 10.0 SYMM 12 ;
+LIBRARY := SHI: LIBRARY VOLMATS INTLINS :: EDIT 0 NOLJ ;
+VOLMATF INTLINF := EXCELT: CANDU6F ::
+ TITLE 'TCWW11: FEW GROUP BURNUP / TRANSPORT TRACKING'
+ EDIT 0 MAXR 31 TRAK TISO 5 10.0 SYMM 12 ;
+PIJ := ASM: LIBRARY VOLMATF INTLINF ;
+FLUX := FLU: PIJ LIBRARY VOLMATF ::
+ TYPE K ;
+assertS FLUX :: 'K-EFFECTIVE' 1 1.117653 ;
+EDITION := EDI: FLUX LIBRARY VOLMATF CANDU6F ::
+ MERG REGI 6 6 10 7 7 10 1 1 8 8 10 1
+ 1 9 9 10 1 1 2 3 4 5 5 5
+ 5 5 5 5 5 5 5
+ COND 4.0 MICR ALL SAVE
+ MGEO CANDU6F
+ ;
+EDITION := SPH: EDITION VOLMATF INTLINF ;
+*----
+* 69 group Burnup
+*----
+BURNUP LIBRARY := EVO: LIBRARY FLUX VOLMATF ::
+ EDIT 3 EXPM 200.0 DEPL <<Timei>> <<TotalTime>> DAY POWR <<Power>> ;
+LIBRARY := SHI: LIBRARY VOLMATS INTLINS :: EDIT 0 NOLJ ;
+PIJ := DELETE: PIJ ;
+PIJ := ASM: LIBRARY VOLMATF INTLINF ;
+FLUX := FLU: FLUX PIJ LIBRARY VOLMATF ::
+ TYPE K ;
+assertS FLUX :: 'K-EFFECTIVE' 1 0.9408571 ;
+EDITION := EDI: EDITION FLUX LIBRARY VOLMATF CANDU6F ::
+ MGEO CANDU6F
+ ;
+EDITION := SPH: EDITION VOLMATF INTLINF ;
+BURNUP FLUX PIJ LIBRARY INTLINS VOLMATS CANDU6S := DELETE:
+ BURNUP FLUX PIJ LIBRARY INTLINS VOLMATS CANDU6S ;
+*----
+* 2 group Burnup
+*----
+LIBRARY := EDITION :: STEP UP 'REF-CASE0001' ;
+EDITION := DELETE: EDITION ;
+PIJ := ASM: LIBRARY VOLMATF INTLINF ;
+FLUX := FLU: PIJ LIBRARY VOLMATF ::
+ TYPE K ;
+assertS FLUX :: 'K-EFFECTIVE' 1 1.117653 ;
+EDITION := EDI: FLUX LIBRARY VOLMATF ::
+ EDIT 1 MERGE COMP MICR ALL SAVE ;
+WHILE Timei TotalTime < DO
+ EVALUATE Timef := Timei Delt + ;
+ IF Timei 0.0 = THEN
+ BURNUP LIBRARY := EVO: LIBRARY FLUX VOLMATF ::
+ EDIT 3 DEPL <<Timei>> <<Timef>> DAY POWR <<Power>> ;
+ ELSE
+ BURNUP LIBRARY := EVO: BURNUP LIBRARY FLUX VOLMATF ::
+ EDIT 3 NOEX DEPL <<Timei>> <<Timef>> DAY POWR <<Power>> ;
+ ENDIF ;
+ PIJ := DELETE: PIJ ;
+ PIJ := ASM: LIBRARY VOLMATF INTLINF ;
+ FLUX := FLU: FLUX PIJ LIBRARY VOLMATF ::
+ TYPE K ;
+ EDITION := EDI: EDITION FLUX LIBRARY VOLMATF ::
+ SAVE ;
+*----
+* change delta t for burnup and final time if required
+*----
+ IF Timef Timec = THEN
+ IF Timec 150.0 = THEN
+ EVALUATE Delt Timec := 50.0 300.0 ;
+ ENDIF ;
+ IF Timec 50.0 = THEN
+ EVALUATE Delt Timec := 20.0 150.0 ;
+ ENDIF ;
+ IF Timec 10.0 = THEN
+ EVALUATE Delt Timec := 10.0 50.0 ;
+ ENDIF ;
+ IF Timec 5.0 = THEN
+ EVALUATE Delt Timec := 5.0 10.0 ;
+ ENDIF ;
+ IF Timec 1.0 = THEN
+ EVALUATE Delt Timec := 4.0 5.0 ;
+ ENDIF ;
+ ENDIF ;
+ EVALUATE Timei := Timef ;
+ENDWHILE ;
+assertS FLUX :: 'K-EFFECTIVE' 1 0.9489596 ;
+res := EDITION ;
+EDITION BURNUP FLUX PIJ LIBRARY INTLINF VOLMATF CANDU6F := DELETE:
+ EDITION BURNUP FLUX PIJ LIBRARY INTLINF VOLMATF CANDU6F ;
+ECHO "test TCWW11 completed" ;
+END: ;
+QUIT "LIST" .
diff --git a/Dragon/data/twinfrith_proc/TCWW12.c2m b/Dragon/data/twinfrith_proc/TCWW12.c2m
new file mode 100644
index 0000000..2f7ac86
--- /dev/null
+++ b/Dragon/data/twinfrith_proc/TCWW12.c2m
@@ -0,0 +1,107 @@
+*----
+* TEST CASE TCWW12
+* WIMS-AECL 69 GROUPS LIBRARY FILE WIMSLIB
+* GENERATE A LIBRARY USING INFO AND OTHER OPTIONS
+*
+* REF: None
+*
+*----
+* Define variables and initialize
+* Coolant properties
+* a) Input
+* TempCool = Coolant temperature (K)
+* Purity = D2/(D2+H1) Weight % ratio in Coolant
+* b) Output
+* DensCool = Coolant Density (g/cm**3)
+* WH1C = H1 Weight % in Coolant
+* WD2C = D2 Weight % in Coolant
+* WO16C = O16 Weight % in Coolant
+* Fuel properties
+* a) Input
+* TempFuel = Fuel temperature (K)
+* Enrichment = U235/(U235+U238) Weight % ratio in Fuel
+* DensFuel = Fuel Density (g/cm**3)
+* b) Output
+* WU235F = U235 Weight % in Fuel
+* WU238F = U238 Weight % in Fuel
+* WO16F = O16 Weight % in Fuel
+*----
+REAL
+ TempCool Purity TempFuel Enrichment DensFuel :=
+ 560.66 99.95 941.29 0.72 10.437501 ;
+REAL
+ WH1C WD2C WO16C DensCool
+ WU235F WU238F WO16F ;
+*----
+* Define STRUCTURES and MODULES used
+*----
+LINKED_LIST
+ LIBRARY ISOT ;
+MODULE
+ LIB: INFO: END: ;
+PROCEDURE assertS ;
+*----
+* Get Coolant properties
+*----
+ECHO
+ "Input - Coolant temperature (K) " TempCool ;
+ECHO
+ "Input - D2/(D2+H1) Weight % ratio in Coolant" Purity ;
+INFO: ::
+ TMP: <<TempCool>> K
+ PUR: <<Purity>> WGT%
+ CALC DENS WATER >>DensCool<<
+ LIB: WIMSAECL FIL: WIMSLIB
+ ISO: 3 H1H2O D2D2O O16
+ CALC WGT% D2O >>WH1C<< >>WD2C<< >>WO16C<<
+ ;
+ECHO
+ "Output - Coolant Density (g/cm**3)" DensCool ;
+ECHO
+ "Output - H1 Weight % in Coolant " WH1C ;
+ECHO
+ "Output - D2 Weight % in Coolant " WD2C ;
+ECHO
+ "Output - O16 Weight % in Coolant " WO16C ;
+*----
+* Get Fuel properties
+*----
+ECHO
+ "Input - Fuel temperature (K) " TempFuel ;
+ECHO
+ "Input - U235/(U235+U238) Weight % ratio in Fuel" Enrichment ;
+ECHO
+ "Input - Fuel Density (g/cm**3) " DensFuel ;
+INFO: ::
+ ENR: <<Enrichment>> WGT%
+ LIB: WIMSAECL FIL: WIMSLIB
+ ISO: 3 U235 U238 O16
+ CALC WGT% UO2 >>WU235F<< >>WU238F<< >>WO16F<<
+ ;
+ECHO
+ "Output - U235 Weight % in Fuel" WU235F ;
+ECHO
+ "Output - U238 Weight % in Fuel" WU238F ;
+ECHO
+ "Output - O16 Weight % in Fuel " WO16F ;
+*----
+* Microscopic cross sections from file WIMSLIB format WIMS-AECL
+*----
+LIBRARY := LIB: ::
+ NMIX 5 CTRA WIMS
+ MIXS LIB: WIMSAECL FIL: WIMSLIB
+ MIX 1 <<TempCool>> <<DensCool>> O16 = O16 <<WO16C>>
+ D2D2O = D2D2O <<WD2C>> H1H2O = H1H2O <<WH1C>>
+ MIX 2 <<TempFuel>> <<DensCool>> O16 = O16 <<WO16C>>
+ D2D2O = D2D2O <<WD2C>> H1H2O = H1H2O <<WH1C>>
+ MIX 3 <<TempFuel>> <<DensFuel>> O16 = O16 <<WO16F>>
+ U235 = U235 <<WU235F>> 1
+ U238 = U238 <<WU238F>> 1
+ MIX 4 COMB 2 0.5 0 0.5
+ MIX 5 COMB 3 0.1 3 0.9
+ ;
+ISOT := LIBRARY :: STEP UP ISOTOPESLIST STEP AT 15 ; (*U238 0005*)
+assertS ISOT :: NG 35 5.000270E-01 ;
+ECHO "test TCWW12 completed" ;
+END: ;
+QUIT "LIST" .
diff --git a/Dragon/data/twinfrith_proc/TCWW31.c2m b/Dragon/data/twinfrith_proc/TCWW31.c2m
new file mode 100644
index 0000000..e0af5e2
--- /dev/null
+++ b/Dragon/data/twinfrith_proc/TCWW31.c2m
@@ -0,0 +1,211 @@
+*----
+* TEST CASE TCWW31
+* CANDU-6 ANNULAR CELL
+* WIMS-AECL 69 GROUPS LIBRARY FILE WIMSLIB
+* MULTI-PARAMETER COMPO ACCESS FOR MACRO-DEPLETION
+* TWO GROUP BURNUP
+* POWER (KW) = 615.00000
+* BURN POWER (KW/KG) = 31.97130
+* URANIUM MASS = 19.23600
+* UO2 REAL DENSITY = 10.59300
+* UO2 EFF DENSITY = 10.43750
+* UO2 TEMPERATURE = 941.28998
+* ENRICHMENT = 0.71140
+* COOLANT D2 AT % = 99.222
+* MODERATOR D2 AT % = 99.911
+* NUMBER OF DAYS = 50
+*
+* REF: R. Roy et al. Ann. Nucl. Energy 21, 115 (1994)
+*
+*----
+* Define variables
+* Burnup paremeters
+* a) Power
+* = 31.9713 kw/kg for 0.0 to 300.0 days
+* b) 69 Groups Burnup time interval Delt
+* = 300 day for 0 to 300 day
+* c) 2 Groups Burnup time interval Delt
+* = 1 day for 0 to 1 day
+* = 4 days for 1 to 5 days
+* = 5 days for 5 to 10 days
+* = 10 days for 10 to 50 days
+* = 20 days for 50 to 150 days
+* = 50 days for 150 to 300 days
+* c) Days with burnup interval changes
+* = 1.0, 5.0, 10.0, 50.0, 150.0 and 300.0 days
+* d) Burnup control time variables Timei, Timef, TotalTime
+* Timei = initial time
+* Timef = final time
+* TotalTime = Final time reached
+*----
+REAL
+ Power Delt Timec Timei Timef TotalTime :=
+ 31.9713 1.0 1.0 0.0 0.0 300.0 ;
+*----
+* Define STRUCTURES and MODULES used
+*----
+LINKED_LIST
+ LIBRARY CANDU6S CANDU6F VOLMATS VOLMATF PIJ FLUX BURNUP EDITION
+ DATABASE ;
+SEQ_BINARY
+ INTLINS INTLINF ;
+SEQ_ASCII
+ res ;
+MODULE
+ GEO: EXCELT: LIB: SHI: ASM: FLU: EVO: EDI: COMPO: SPH: DELETE: END: ;
+PROCEDURE assertS ;
+*----
+* Depletion data from file WIMSLIB format WIMS-AECL
+* Microscopic cross sections from file WIMSLIB format WIMS-AECL
+*----
+LIBRARY := LIB: ::
+ NMIX 10 CTRA WIMS
+ DEPL LIB: WIMSAECL FIL: WIMSLIB
+ MIXS LIB: WIMSAECL FIL: WIMSLIB
+ MIX 1 560.66 0.81212 O16 = O16 7.99449E-1
+ D2D2O = D2D2O 1.99768E-1 H1H2O = H1H2O 7.83774E-4
+ MIX 2 560.66 6.57 Nb93 = NB93 2.50000
+ BNat = B-NAT 2.10000E-4
+ Zr91 = ZR91 9.75000E+1
+ MIX 3 345.66 0.0014 He4 = HE4 1.00000E+2
+ MIX 4 345.66 6.44 Fe56 = FE56A 1.60000E-1
+ Ni58 = NI58 6.00000E-2 Cr52 = CR52 1.10000E-1
+ BNat = B-NAT 3.10000E-4
+ Zr91 = ZR91 9.97100E+1
+ MIX 5 345.66 1.082885 O16 = O16 7.98895E-1
+ D2D2O = D2D2O 2.01016E-1 H1H2O = H1H2O 8.96000E-5
+ MIX 6 941.29 10.4375010 O16 = O16 1.18473E+1
+ Xe135 = XE135 0.0
+ U235 = U235 6.27118E-1 1
+ U238 = U238 8.75256E+1 1
+ U236 = U236 0.0 1
+ Pu239 = PU239 0.0 1
+ MIX 7 COMB 6 1.0
+ MIX 8 COMB 6 1.0
+ MIX 9 COMB 6 1.0
+ MIX 10 560.66 6.44 Fe56 = FE56A 1.60000E-1
+ Ni58 = NI58 6.00000E-2 Cr52 = CR52 1.10000E-1
+ BNat = B-NAT 3.10000E-4
+ Zr91 = ZR91 9.97100E+1
+ ;
+*----
+* Geometry CANDU6S : 13 regions annular cluster for self-shielding
+* CANDU6F : 31 regions annular cluster for transport
+*----
+CANDU6S := GEO: :: TUBE 5
+ R+ REFL RADIUS 0.00000 5.16890 5.60320 6.44780 6.58750 16.12171
+ MIX 1 2 3 4 5
+ CLUSTER ROD1 ROD2 ROD3 ROD4
+ ::: ROD1 := GEO: TUBE 2 MIX 6 10 NPIN 1 RPIN 0.0000 APIN 0.0000
+ RADIUS 0.00000 0.6122 0.6540 ;
+ ::: ROD2 := GEO: ROD1 MIX 7 10 NPIN 6 RPIN 1.4885 APIN 0.0000 ;
+ ::: ROD3 := GEO: ROD1 MIX 8 10 NPIN 12 RPIN 2.8755 APIN 0.261799 ;
+ ::: ROD4 := GEO: ROD1 MIX 9 10 NPIN 18 RPIN 4.3305 APIN 0.0 ;
+ ;
+CANDU6F := GEO: CANDU6S :: SPLITR 6 1 1 1 10
+ ::: ROD1 := GEO: ROD1 SPLITR 2 1 ;
+ ::: ROD2 := GEO: ROD2 SPLITR 2 1 ;
+ ::: ROD3 := GEO: ROD3 SPLITR 2 1 ;
+ ::: ROD4 := GEO: ROD4 SPLITR 2 1 ;
+ ;
+*----
+* Self-Shielding calculation EXCEL
+* Transport calculation EXCEL
+* Flux calculation for keff
+*----
+VOLMATS INTLINS := EXCELT: CANDU6S ::
+ TITLE 'TCWW31: FEW GROUP BURNUP / SELF-SHIELDING TRACKING'
+ EDIT 0 MAXR 13 TRAK TISO 5 10.0 SYMM 12 ;
+LIBRARY := SHI: LIBRARY VOLMATS INTLINS ::
+ NOLJ EDIT 0 ;
+VOLMATF INTLINF := EXCELT: CANDU6F ::
+ TITLE 'TCWW31: FEW GROUP BURNUP / TRANSPORT TRACKING'
+ EDIT 0 MAXR 31 TRAK TISO 5 10.0 SYMM 12 ;
+PIJ := ASM: LIBRARY VOLMATF INTLINF ;
+FLUX := FLU: PIJ LIBRARY VOLMATF ::
+ TYPE K ;
+assertS FLUX :: 'K-EFFECTIVE' 1 1.117653 ;
+EDITION := EDI: FLUX LIBRARY VOLMATF CANDU6F ::
+ MERG REGI 6 6 10 7 7 10 1 1 8 8 10 1
+ 1 9 9 10 1 1 2 3 4 5 5 5
+ 5 5 5 5 5 5 5
+ COND 4.0 MICR ALL SAVE
+ MGEO CANDU6F
+ ;
+EDITION := SPH: EDITION VOLMATF INTLINF ;
+FLUX PIJ LIBRARY INTLINS VOLMATS CANDU6S VOLMATF CANDU6F
+INTLINF := DELETE: FLUX PIJ LIBRARY INTLINS VOLMATS CANDU6S
+VOLMATF CANDU6F INTLINF ;
+*----
+* 2 group Burnup (macro-depletion)
+*----
+DATABASE := COMPO: ::
+ EDIT 5
+ COMM 'Multi-parameter reactor database' ENDC
+ INIT
+ ;
+DATABASE := COMPO: DATABASE EDITION ::
+ EDIT 3
+ ;
+EDITION := DELETE: EDITION ;
+*
+* COMPO INTERPOLATION
+LIBRARY := SPH: DATABASE ::
+ EDIT 1
+ STEP UP default STEP AT 1
+ MICRO OFF
+ ;
+CANDU6F := DATABASE :: STEP UP default STEP UP 'GEOMETRIES' STEP AT 1 ;
+VOLMATF INTLINF := EXCELT: CANDU6F ::
+ TITLE 'TCWW31: FEW GROUP BURNUP / TRANSPORT TRACKING'
+ EDIT 0 MAXR 31 TRAK TISO 5 10.0 SYMM 12 ;
+PIJ := ASM: LIBRARY VOLMATF INTLINF ;
+FLUX := FLU: PIJ LIBRARY VOLMATF ::
+ TYPE K ;
+assertS FLUX :: 'K-EFFECTIVE' 1 1.117663 ;
+EDITION := EDI: FLUX LIBRARY VOLMATF ::
+ EDIT 1 MERGE COMP MICR ALL SAVE ;
+WHILE Timei TotalTime < DO
+ EVALUATE Timef := Timei Delt + ;
+ IF Timei 0.0 = THEN
+ BURNUP LIBRARY := EVO: LIBRARY FLUX VOLMATF ::
+ EDIT 3 DEPL <<Timei>> <<Timef>> DAY POWR <<Power>> ;
+ ELSE
+ BURNUP LIBRARY := EVO: BURNUP LIBRARY FLUX VOLMATF ::
+ EDIT 3 NOEX DEPL <<Timei>> <<Timef>> DAY POWR <<Power>> ;
+ ENDIF ;
+ PIJ := DELETE: PIJ ;
+ PIJ := ASM: LIBRARY VOLMATF INTLINF ;
+ FLUX := FLU: FLUX PIJ LIBRARY VOLMATF ::
+ TYPE K ;
+ EDITION := EDI: EDITION FLUX LIBRARY VOLMATF ::
+ SAVE ;
+*----
+* change delta t for burnup and final time if required
+*----
+ IF Timef Timec = THEN
+ IF Timec 150.0 = THEN
+ EVALUATE Delt Timec := 50.0 300.0 ;
+ ENDIF ;
+ IF Timec 50.0 = THEN
+ EVALUATE Delt Timec := 20.0 150.0 ;
+ ENDIF ;
+ IF Timec 10.0 = THEN
+ EVALUATE Delt Timec := 10.0 50.0 ;
+ ENDIF ;
+ IF Timec 5.0 = THEN
+ EVALUATE Delt Timec := 5.0 10.0 ;
+ ENDIF ;
+ IF Timec 1.0 = THEN
+ EVALUATE Delt Timec := 4.0 5.0 ;
+ ENDIF ;
+ ENDIF ;
+ EVALUATE Timei := Timef ;
+ENDWHILE ;
+assertS FLUX :: 'K-EFFECTIVE' 1 0.9505190 ;
+res := EDITION ;
+EDITION BURNUP FLUX PIJ LIBRARY INTLINF VOLMATF CANDU6F := DELETE:
+ EDITION BURNUP FLUX PIJ LIBRARY INTLINF VOLMATF CANDU6F ;
+ECHO "test TCWW31 completed" ;
+END: ;
+QUIT "LIST" .
diff --git a/Dragon/data/twinfrith_proc/TCWW41.c2m b/Dragon/data/twinfrith_proc/TCWW41.c2m
new file mode 100644
index 0000000..1605696
--- /dev/null
+++ b/Dragon/data/twinfrith_proc/TCWW41.c2m
@@ -0,0 +1,223 @@
+*---
+* Regression test 1 for MCCG: and MOCC:
+*---
+* TEST CASE TCWW41 (based on TCWW02)
+* 17 X 17 PWR ASSEMBLY WITHOUT POISON
+* WIMS-AECL 69 GROUPS LIBRARY FILE WIMSLIB
+*---
+
+*----
+* Define STRUCTURES and MODULES used
+*----
+LINKED_LIST
+ ASSMB ASSMB2 TRACK TRACK2 LIBRARY SYS FLX EDITION NEWLIB TEMP ;
+SEQ_BINARY
+ TRACK_FIL TRACK_FIL2 ;
+MODULE
+ LIB: GEO: EXCELT: SHI: ASM: FLU: MCCGT: EDI: DELETE: END: ;
+PROCEDURE assertS ;
+*----
+* Microscopic cross sections
+*----
+LIBRARY := LIB: ::
+ NMIX 8 CTRA WIMS
+ MIXS LIB: WIMSAECL FIL: WIMSLIB
+ MIX 1 579.9
+ H1H2O = H1H2O 4.76690E-2 O16H2O = O16H2O 2.38345E-2
+ BNat = B-NAT 2.38103E-5
+ MIX 2 579.9 O16 = O16 3.06711E-4
+ Cr52 = CR52 7.54987E-5 Fe56 = FE56A 1.47624E-4
+ Zr91 = ZR91 4.18621E-2
+ MIX 3 579.9
+ H1H2O = H1H2O 4.65292E-2 O16H2O = O16H2O 2.32646E-2
+ Nb93 = NB93 7.07082E-6 Cr52 = CR52 4.79927E-5
+ Fe56 = FE56A 4.45845E-5 Ni58 = NI58 1.13521E-4
+ Co59 = CO59 1.07714E-7 Mo95 = MO95 4.03755E-6
+ Ti48 = TI48 2.33305E-6 Al27 = AL27 2.35231E-6
+ Mn55 = MN55 4.15901E-7
+ BNat = B-NAT 2.32761E-5
+ Zr91 = ZR91 8.92427E-4
+ MIX 4 579.9 O16 = O16 2.87335E-4
+ Cr52 = CR52 7.07291E-5 Fe56 = FE56A 1.38298E-4
+ Zr91 = ZR91 3.92175E-2
+ MIX 5 579.9
+ H1H2O = H1H2O 4.71346E-2 O16H2O = O16H2O 2.35673E-2
+ Nb93 = NB93 3.31482E-6 Cr52 = CR52 2.24991E-5
+ Fe56 = FE56A 2.09013E-5 Ni58 = NI58 5.32188E-5
+ Co59 = CO59 5.04968E-8 Mo95 = MO95 1.89281E-6
+ Ti48 = TI48 1.09374E-6 Al27 = AL27 1.10277E-6
+ Mn55 = MN55 1.94976E-7
+ BNat = B-NAT 2.35598E-5
+ Zr91 = ZR91 4.18372E-4
+ MIX 6 579.9
+ H1H2O = H1H2O 4.71676E-2 O16H2O = O16H2O 2.35838E-2
+ Nb93 = NB93 3.11049E-6 Cr52 = CR52 2.11122E-5
+ Fe56 = FE56A 1.96130E-5 Ni58 = NI58 4.99383E-5
+ Co59 = CO59 4.73842E-8 Mo95 = MO95 1.77614E-6
+ Ti48 = TI48 1.02632E-6 Al27 = AL27 1.03479E-6
+ Mn55 = MN55 1.82957E-7
+ BNat = B-NAT 2.35753E-5
+ Zr91 = ZR91 3.92583E-4
+ MIX 7 579.9
+ H1H2O = H1H2O 4.72020E-2 O16H2O = O16H2O 2.36010E-2
+ Nb93 = NB93 2.89640E-6 Cr52 = CR52 1.96591E-5
+ Fe56 = FE56A 1.82630E-5 Ni58 = NI58 4.65011E-5
+ Co59 = CO59 4.41227E-8 Mo95 = MO95 1.65389E-6
+ Ti48 = TI48 9.55682E-7 Al27 = AL27 9.63569E-7
+ Mn55 = MN55 1.70365E-7
+ BNat = B-NAT 2.35914E-5
+ Zr91 = ZR91 3.65562E-4
+ MIX 8 933.6 O16 = O16 4.49355E-2
+ U235 = U235 7.39237E-4 1
+ U238 = U238 2.17285E-2 1 ;
+*----
+* Geometry ASSMB : a 17 X 17 normal PWR assembly
+* contains C1 : cell without fuel
+* C2 : normal fuel cell
+* C3 : peripheral cell
+* C4 : corner cell
+*----
+ASSMB := GEO: :: CAR2D 9 9
+ X- DIAG X+ REFL Y- SYME Y+ DIAG
+ CELL C1 C2 C2 C1 C2 C2 C1 C2 C3
+ C2 C2 C2 C2 C2 C2 C2 C3
+ C2 C2 C2 C2 C2 C2 C3
+ C1 C2 C2 C1 C2 C3
+ C2 C2 C2 C2 C3
+ C1 C2 C2 C3
+ C2 C2 C3
+ C2 C3
+ C4
+ MERGE 1 3 12 11 12 12 11 12 15
+ 4 6 5 6 6 5 6 8
+ 13 5 6 6 5 6 8
+ 2 5 5 10 5 8
+ 13 5 5 6 8
+ 2 5 7 8
+ 13 7 8
+ 14 8
+ 9
+ TURN H H B H H B H H A
+ H G G H G G H A
+ A E E F E E A
+ H H F H H A
+ H E G H A
+ H H A A
+ H A A
+ A A
+ A
+ ::: C1 := GEO: CARCEL 2
+ MESHX 0.0 1.26472 MESHY 0.0 1.26472
+ RADIUS 0.0 0.572435 0.613142 MIX 1 2 3 ;
+ ::: C2 := GEO: C1 RADIUS 0.0 0.412660 0.474364 MIX 8 4 5 ;
+ ::: C3 := GEO: C2 MESHX 0.0 1.31472 MIX 8 4 6 ;
+ ::: C4 := GEO: C3 MESHY 0.0 1.31472 MIX 8 4 7 ;
+ ;
+ASSMB2 := GEO: ASSMB ::
+::: C2 := GEO: C2 SPLITR 4 1 ;
+::: C3 := GEO: C3 SPLITR 4 1 ;
+::: C4 := GEO: C4 SPLITR 4 1 ;
+ ;
+*----
+* Tracking calculation for Self-Shielding
+* Self-Shielding calculation
+* Tracking calculation for flux
+*----
+TRACK TRACK_FIL := EXCELT: ASSMB ::
+ EDIT 0
+ MAXR 200
+ TITLE 'TCWW41 : SELF-SHIELDING'
+ TRAK TISO 12 12.0 ;
+LIBRARY := SHI: LIBRARY TRACK TRACK_FIL :: NOLJ ;
+*----
+* MCCG (isotropic BC)
+*----
+TRACK2 TRACK_FIL2 := EXCELT: ASSMB2 ::
+ EDIT 0
+ MAXR 200
+ TITLE 'TCWW41 : INIT AND FLUX'
+ TRAK TISO 12 20.0 ;
+*---
+* Initialisation of the mutigroup flux calculation by a CDD calculation
+*---
+TEMP := TRACK2 ;
+TRACK2 := MCCGT: TRACK2 TRACK_FIL2 ASSMB2 ::
+ EDIT 4 LCMD 2
+ DIFC TMT EPSI 1E-8
+ MAXI 100 KRYL 0 SCR 0 HDD 0.0 ;
+SYS := ASM: LIBRARY TRACK2 TRACK_FIL2 ::
+ EDIT 2 ARM ;
+FLX := FLU: LIBRARY SYS TRACK2 TRACK_FIL2 ::
+ EDIT 1 TYPE K THER 5 5E-5 EXTE 10 1E-5 ;
+assertS FLX :: 'K-EFFECTIVE' 1 1.259025 ;
+TRACK2 := DELETE: TRACK2 ;
+TRACK2 := TEMP ;
+*---
+* Multigroup Flux Calculation
+* Edition
+*---
+TRACK2 := MCCGT: TRACK2 TRACK_FIL2 ASSMB2 ::
+ EDIT 4 LCMD 2
+ AAC 10 TMT EPSI 1E-5 STIS 1
+ MAXI 1 KRYL 0 SCR 0 HDD 0.0 ;
+FLX := FLU: FLX
+ LIBRARY SYS TRACK2 TRACK_FIL2 ::
+ EDIT 1 TYPE K THER 5 5E-5 EXTE 100 1E-5 ;
+assertS FLX :: 'K-EFFECTIVE' 1 1.258883 ;
+EDITION := EDI: FLX LIBRARY TRACK2 ASSMB2 ::
+EDIT 2
+COND 4.0
+MERGE MIX 1 2 3 4 5 6 7 8 ;
+*---
+* Memory Release
+*---
+TRACK TRACK_FIL TRACK2 TRACK_FIL2 ASSMB SYS FLX EDITION TEMP
+ := DELETE:
+TRACK TRACK_FIL TRACK2 TRACK_FIL2 ASSMB SYS FLX EDITION TEMP ;
+*----
+* MOCC (cyclic tracking)
+*----
+TRACK2 TRACK_FIL2 := EXCELT: ASSMB2 ::
+ EDIT 0
+ MAXR 200
+ TITLE 'TCWW02 : INIT AND FLUX'
+ TRAK TSPC 7 20.0 ;
+*---
+* Initialisation of the mutigroup flux calculation by a CDD calculation
+*---
+TEMP := TRACK2 ;
+TRACK2 := MCCGT: TRACK2 TRACK_FIL2 ASSMB2 ::
+ EDIT 1 LCMD 2
+ DIFC TMT EPSI 1E-8 STIS 1
+ MAXI 100 KRYL 0 SCR 0 HDD 100000.0 ;
+SYS := ASM: LIBRARY TRACK2 TRACK_FIL2 ::
+ EDIT 2 ARM ;
+FLX := FLU: LIBRARY SYS TRACK2 TRACK_FIL2 ::
+ EDIT 1 TYPE K THER 5 5E-5 EXTE 10 1E-5 ;
+assertS FLX :: 'K-EFFECTIVE' 1 1.258963 ;
+TRACK2 := DELETE: TRACK2 ;
+TRACK2 := TEMP ;
+*---
+* Multigroup Flux Calculation
+* Edition
+*---
+TRACK2 := MCCGT: TRACK2 TRACK_FIL2 ASSMB2 ::
+ EDIT 1 LCMD 2
+ AAC 80 EPSI 1E-5 STIS 1
+ MAXI 1 KRYL 0 SCR 0 HDD 100000.0 ;
+FLX := FLU: FLX LIBRARY SYS TRACK2 TRACK_FIL2 ::
+ EDIT 1 TYPE K THER 5 5E-5 EXTE 100 1E-5 ;
+assertS FLX :: 'K-EFFECTIVE' 1 1.261892 ;
+EDITION := EDI: FLX LIBRARY TRACK2 ASSMB2 ::
+EDIT 2
+COND 4.0
+MERGE MIX 1 2 3 4 5 6 7 8 ;
+*---
+* Memory Release
+*---
+TRACK2 TRACK_FIL2 LIBRARY ASSMB2 SYS FLX EDITION
+ := DELETE:
+TRACK2 TRACK_FIL2 LIBRARY ASSMB2 SYS FLX EDITION ;
+ECHO "test TCWW41 completed" ;
+END: ;
+QUIT "LIST" .
diff --git a/Dragon/data/twinfrith_proc/TCWW42.c2m b/Dragon/data/twinfrith_proc/TCWW42.c2m
new file mode 100644
index 0000000..f6917cc
--- /dev/null
+++ b/Dragon/data/twinfrith_proc/TCWW42.c2m
@@ -0,0 +1,160 @@
+*---
+* Regression test for MCCG:
+*---
+*---
+* TEST CASE TCWW42 (based on TCWW05)
+* 3D CANDU-6 CARTESIAN CELL
+* WIMS-AECL 69 GROUPS LIBRARY FILE WIMSLIB
+*---
+*----
+* Define STRUCTURES and MODULES used
+*----
+LINKED_LIST
+ LIBRARY CANDU6S CANDU6M CANDU6F VOLMATS VOLMATF TEMP PIJ FLUX
+ EDITION ;
+SEQ_BINARY
+ INTLINS INTLINF ;
+SEQ_ASCII
+ fig.ps ;
+MODULE
+ GEO: NXT: MCCGT: PSP: LIB: SHI: ASM: FLU: EDI: GREP: DELETE: END: ;
+PROCEDURE assertS ;
+REAL k2D kpriz ;
+*----
+* Geometry CANDU6S : 2D geometry for self-shielding
+* CANDU6M : 2D geometry for multigroup flux
+* CANDU6F : 3D geometry for multigroup flux
+*----
+CANDU6S := GEO: :: CARCEL 5
+ X+ REFL X- REFL MESHX -14.2875 14.2875
+ Y+ REFL Y- REFL MESHY -14.2875 14.2875
+ RADIUS 0.00000 5.16890 5.60320 6.44780 6.58750 14.00
+ MIX 1 2 3 4 5 5
+ CLUSTER ROD1 ROD2 ROD3 ROD4
+ ::: ROD1 := GEO: TUBE 2 MIX 6 10 NPIN 1 RPIN 0.0000 APIN 0.0000
+ RADIUS 0.00000 0.6122 0.6540 ;
+ ::: ROD2 := GEO: ROD1 MIX 7 10 NPIN 6 RPIN 1.4885 APIN 0.0000 ;
+ ::: ROD3 := GEO: ROD1 MIX 8 10 NPIN 12 RPIN 2.8755 APIN 0.261799 ;
+ ::: ROD4 := GEO: ROD1 MIX 9 10 NPIN 18 RPIN 4.3305 APIN 0.0 ;
+ ;
+CANDU6M := GEO: CANDU6S :: !SPLITR 6 1 1 1 10
+ ;
+REAL zlength := 50.0 ;
+INTEGER zsplit := 1 ;
+CANDU6F := GEO: :: CARCELZ 5 1 1 1
+ X+ REFL X- REFL MESHX -14.2875 14.2875
+ Y+ REFL Y- REFL MESHY -14.2875 14.2875
+ Z- REFL Z+ REFL MESHZ 0.0 <<zlength>>
+ SPLITZ <<zsplit>>
+ RADIUS 0.00000 5.16890 5.60320 6.44780 6.58750 14.00
+ !SPLITR 6 1 1 1 10
+ MIX 1 2 3 4 5 5
+ CLUSTER ROD1 ROD2 ROD3 ROD4
+ ::: ROD1 := GEO: TUBEZ 2 1 1 1
+ MESHZ 0.0 <<zlength>>
+ SPLITZ <<zsplit>>
+ MIX 6 10
+ NPIN 1 RPIN 0.0000 APIN 0.0000
+ RADIUS 0.00000 0.6122 0.6540 ;
+ ::: ROD2 := GEO: ROD1
+ MIX 7 10
+ NPIN 6 RPIN 1.4885 APIN 0.0000 ;
+ ::: ROD3 := GEO: ROD1
+ MIX 8 10
+ NPIN 12 RPIN 2.8755 APIN 0.261799 ;
+ ::: ROD4 := GEO: ROD1
+ MIX 9 10
+ NPIN 18 RPIN 4.3305 APIN 0.0 ;
+;
+*----
+* Microscopic cross sections from file WIMSLIB format WIMS-AECL
+*----
+LIBRARY := LIB: ::
+ NMIX 10 CTRA WIMS
+ MIXS LIB: WIMSAECL FIL: WIMSLIB
+ MIX 1 560.66 0.81212 O16 = O16 7.99449E-1
+ D2D2O = D2D2O 1.99768E-1 H1H2O = H1H2O 7.83774E-4
+ MIX 2 560.66 6.57 Nb93 = NB93 2.50000
+ BNat = B-NAT 2.10000E-4
+ Zr91 = ZR91 9.75000E+1
+ MIX 3 345.66 0.0014 He4 = HE4 1.00000E+2
+ MIX 4 345.66 6.44 Fe56 = FE56A 1.60000E-1
+ Ni58 = NI58 6.00000E-2 Cr52 = CR52 1.10000E-1
+ BNat = B-NAT 3.10000E-4
+ Zr91 = ZR91 9.97100E+1
+ MIX 5 345.66 1.082885 O16 = O16 7.98895E-1
+ D2D2O = D2D2O 2.01016E-1 H1H2O = H1H2O 8.96000E-5
+ MIX 6 941.29 10.4375010 O16 = O16 1.18473E+1
+ Xe135 = XE135 0.0
+ U235 = U235 6.27118E-1 1
+ U238 = U238 8.75256E+1 1
+ U236 = U236 0.0 1
+ Pu239 = PU239 0.0 1
+ MIX 7 COMB 6 1.0
+ MIX 8 COMB 6 1.0
+ MIX 9 COMB 6 1.0
+ MIX 10 560.66 6.44 Fe56 = FE56A 1.60000E-1
+ Ni58 = NI58 6.00000E-2 Cr52 = CR52 1.10000E-1
+ BNat = B-NAT 3.10000E-4
+ Zr91 = ZR91 9.97100E+1
+ ;
+*----
+* Self-Shielding 2D tracking by NXT
+* Self-Shielding calculation EXCEL
+*----
+VOLMATS INTLINS := NXT: CANDU6S ::
+ EDIT 0 TISO 4 5.0 ;
+LIBRARY := SHI: LIBRARY VOLMATS INTLINS :: EDIT 0 NOLJ ;
+VOLMATS INTLINS := DELETE: VOLMATS INTLINS ;
+*----
+* Flux Calculation 2D tracking by NXT/MCCGT
+* Flux Calculation 3D prismatic tracking by NXT/MCCGT
+*----
+VOLMATS INTLINS := NXT: CANDU6M ::
+ EDIT 0 TISO 4 5.0 ;
+VOLMATS := MCCGT: VOLMATS INTLINS CANDU6M ::
+ EDIT 2 DGAU 2
+ AAC 100 TMT EPSI 1E-5 STIS 1
+ MAXI 1 KRYL 0 SCR 0 HDD 0.0 ;
+VOLMATF INTLINF := NXT: CANDU6F ::
+ EDIT 0 PRIZ 0.5 GAUS 4 TISO 4 5.0 ;
+TEMP := VOLMATF :: STEP UP PROJECTION ;
+fig.ps := PSP: TEMP ;
+VOLMATF := MCCGT: VOLMATF INTLINF CANDU6F ::
+ EDIT 2
+ AAC 100 TMT EPSI 1E-5 STIS 1
+ MAXI 1 KRYL 0 SCR 0 HDD 0.0 ;
+*---
+* 2D Multigroup flux calculation and edition
+*---
+PIJ := ASM: LIBRARY VOLMATS INTLINS ::
+ EDIT 2 ARM ;
+FLUX := FLU: PIJ LIBRARY VOLMATS INTLINS ::
+ EDIT 2 TYPE K THER 5 5E-5 EXTE 10 1E-5 UNKT 1E-4 ;
+assertS FLUX :: 'K-INFINITY' 1 1.125582 ;
+GREP: FLUX :: GETVAL 'K-EFFECTIVE' 1 1 1 >>k2D<< ;
+EDITION := EDI: FLUX LIBRARY VOLMATS ::
+ EDIT 2 COND 4.0 MERGE MIX 1 2 3 4 5 6 7 8 9 10 ;
+PIJ FLUX EDITION := DELETE: PIJ FLUX EDITION ;
+*---
+* 3D prismatic Multigroup flux calculation and edition
+*---
+PIJ := ASM: LIBRARY VOLMATF INTLINF ::
+ EDIT 2 ARM ;
+FLUX := FLU: PIJ LIBRARY VOLMATF INTLINF ::
+ EDIT 2 TYPE K THER 5 5E-5 EXTE 10 1E-5 UNKT 1E-4 ;
+assertS FLUX :: 'K-INFINITY' 1 1.126287 ;
+GREP: FLUX :: GETVAL 'K-EFFECTIVE' 1 1 1 >>kpriz<< ;
+EDITION := EDI: FLUX LIBRARY VOLMATF ::
+ EDIT 2 COND 4.0 MERGE MIX 1 2 3 4 5 6 7 8 9 10 ;
+ECHO "**********************" ;
+ECHO "2D " k2D ;
+ECHO "3D PRIZ" kpriz ;
+ECHO "**********************" ;
+*---
+* Clean up
+*---
+INTLINF INTLINS := DELETE: INTLINF INTLINS ;
+ECHO "test TCWW42 completed" ;
+END: ;
+QUIT "LIST" .
diff --git a/Dragon/data/twinfrith_proc/TCWW43.c2m b/Dragon/data/twinfrith_proc/TCWW43.c2m
new file mode 100644
index 0000000..016eca7
--- /dev/null
+++ b/Dragon/data/twinfrith_proc/TCWW43.c2m
@@ -0,0 +1,242 @@
+*---
+* Regression test for MCCG:
+*---
+* TEST CASE TCWW43 (based on TCWW02)
+* 17 X 17 PWR ASSEMBLY WITHOUT POISON
+* WIMS-AECL 69 GROUPS LIBRARY FILE WIMSLIB
+*---
+
+*----
+* Define STRUCTURES and MODULES used
+*----
+LINKED_LIST
+ ASSMB ASSMB2 TRACK LIBRARY SYS FLX EDITION NEWLIB TEMP ;
+SEQ_BINARY
+ TRACK_FIL ;
+MODULE
+ LIB: GEO: EXCELT: SHI: ASM: FLU: MCCGT: EDI: GREP: DELETE: END: ;
+PROCEDURE assertS ;
+REAL k2D kpriz ;
+*----
+* Microscopic cross sections
+*----
+LIBRARY := LIB: ::
+ NMIX 8 CTRA WIMS
+ MIXS LIB: WIMSAECL FIL: WIMSLIB
+ MIX 1 579.9
+ H1H2O = H1H2O 4.76690E-2 O16H2O = O16H2O 2.38345E-2
+ BNat = B-NAT 2.38103E-5
+ MIX 2 579.9 O16 = O16 3.06711E-4
+ Cr52 = CR52 7.54987E-5 Fe56 = FE56A 1.47624E-4
+ Zr91 = ZR91 4.18621E-2
+ MIX 3 579.9
+ H1H2O = H1H2O 4.65292E-2 O16H2O = O16H2O 2.32646E-2
+ Nb93 = NB93 7.07082E-6 Cr52 = CR52 4.79927E-5
+ Fe56 = FE56A 4.45845E-5 Ni58 = NI58 1.13521E-4
+ Co59 = CO59 1.07714E-7 Mo95 = MO95 4.03755E-6
+ Ti48 = TI48 2.33305E-6 Al27 = AL27 2.35231E-6
+ Mn55 = MN55 4.15901E-7
+ BNat = B-NAT 2.32761E-5
+ Zr91 = ZR91 8.92427E-4
+ MIX 4 579.9 O16 = O16 2.87335E-4
+ Cr52 = CR52 7.07291E-5 Fe56 = FE56A 1.38298E-4
+ Zr91 = ZR91 3.92175E-2
+ MIX 5 579.9
+ H1H2O = H1H2O 4.71346E-2 O16H2O = O16H2O 2.35673E-2
+ Nb93 = NB93 3.31482E-6 Cr52 = CR52 2.24991E-5
+ Fe56 = FE56A 2.09013E-5 Ni58 = NI58 5.32188E-5
+ Co59 = CO59 5.04968E-8 Mo95 = MO95 1.89281E-6
+ Ti48 = TI48 1.09374E-6 Al27 = AL27 1.10277E-6
+ Mn55 = MN55 1.94976E-7
+ BNat = B-NAT 2.35598E-5
+ Zr91 = ZR91 4.18372E-4
+ MIX 6 579.9
+ H1H2O = H1H2O 4.71676E-2 O16H2O = O16H2O 2.35838E-2
+ Nb93 = NB93 3.11049E-6 Cr52 = CR52 2.11122E-5
+ Fe56 = FE56A 1.96130E-5 Ni58 = NI58 4.99383E-5
+ Co59 = CO59 4.73842E-8 Mo95 = MO95 1.77614E-6
+ Ti48 = TI48 1.02632E-6 Al27 = AL27 1.03479E-6
+ Mn55 = MN55 1.82957E-7
+ BNat = B-NAT 2.35753E-5
+ Zr91 = ZR91 3.92583E-4
+ MIX 7 579.9
+ H1H2O = H1H2O 4.72020E-2 O16H2O = O16H2O 2.36010E-2
+ Nb93 = NB93 2.89640E-6 Cr52 = CR52 1.96591E-5
+ Fe56 = FE56A 1.82630E-5 Ni58 = NI58 4.65011E-5
+ Co59 = CO59 4.41227E-8 Mo95 = MO95 1.65389E-6
+ Ti48 = TI48 9.55682E-7 Al27 = AL27 9.63569E-7
+ Mn55 = MN55 1.70365E-7
+ BNat = B-NAT 2.35914E-5
+ Zr91 = ZR91 3.65562E-4
+ MIX 8 933.6 O16 = O16 4.49355E-2
+ U235 = U235 7.39237E-4 1
+ U238 = U238 2.17285E-2 1 ;
+*----
+* Geometry ASSMB2 : a 17 X 17 normal PWR assembly
+* contains C1 : cell without fuel
+* C2 : normal fuel cell
+* C3 : peripheral cell
+* C4 : corner cell
+*----
+ASSMB2 := GEO: :: CAR2D 9 9
+ X- DIAG X+ REFL Y- SYME Y+ DIAG
+ CELL C1 C2 C2 C1 C2 C2 C1 C2 C3
+ C2 C2 C2 C2 C2 C2 C2 C3
+ C2 C2 C2 C2 C2 C2 C3
+ C1 C2 C2 C1 C2 C3
+ C2 C2 C2 C2 C3
+ C1 C2 C2 C3
+ C2 C2 C3
+ C2 C3
+ C4
+ MERGE 1 3 12 11 12 12 11 12 15
+ 4 6 5 6 6 5 6 8
+ 13 5 6 6 5 6 8
+ 2 5 5 10 5 8
+ 13 5 5 6 8
+ 2 5 7 8
+ 13 7 8
+ 14 8
+ 9
+ TURN H H B H H B H H A
+ H G G H G G H A
+ A E E F E E A
+ H H F H H A
+ H E G H A
+ H H A A
+ H A A
+ A A
+ A
+ ::: C1 := GEO: CARCEL 2
+ MESHX 0.0 1.26472 MESHY 0.0 1.26472
+ RADIUS 0.0 0.572435 0.613142 MIX 1 2 3 ;
+ ::: C2 := GEO: C1 RADIUS 0.0 0.412660 0.474364 MIX 8 4 5 ;
+ ::: C3 := GEO: C2 MESHX 0.0 1.31472 MIX 8 4 6 ;
+ ::: C4 := GEO: C3 MESHY 0.0 1.31472 MIX 8 4 7 ;
+ ;
+*----
+* Geometry ASSMB : 3D prismatic extension
+*----
+ASSMB := GEO: :: CAR3D 9 9 1
+ X- DIAG X+ REFL Y- SYME Y+ DIAG
+ Z- REFL Z+ REFL
+ CELL C1 C2 C2 C1 C2 C2 C1 C2 C3
+ C2 C2 C2 C2 C2 C2 C2 C3
+ C2 C2 C2 C2 C2 C2 C3
+ C1 C2 C2 C1 C2 C3
+ C2 C2 C2 C2 C3
+ C1 C2 C2 C3
+ C2 C2 C3
+ C2 C3
+ C4
+ MERGE 1 3 12 11 12 12 11 12 15
+ 4 6 5 6 6 5 6 8
+ 13 5 6 6 5 6 8
+ 2 5 5 10 5 8
+ 13 5 5 6 8
+ 2 5 7 8
+ 13 7 8
+ 14 8
+ 9
+ TURN H H B H H B H H A
+ H G G H G G H A
+ A E E F E E A
+ H H F H H A
+ H E G H A
+ H H A A
+ H A A
+ A A
+ A
+ ::: C1 := GEO: CARCELZ 2 1 1 1
+ MESHX 0.0 1.26472 MESHY 0.0 1.26472 MESHZ 0.0 10.0
+ RADIUS 0.0 0.572435 0.613142 MIX 1 2 3 ;
+ ::: C2 := GEO: C1 RADIUS 0.0 0.412660 0.474364 MIX 8 4 5 ;
+ ::: C3 := GEO: C2 MESHX 0.0 1.31472 MIX 8 4 6 ;
+ ::: C4 := GEO: C3 MESHY 0.0 1.31472 MIX 8 4 7 ;
+ ;
+*----
+* Tracking calculation for Self-Shielding
+* Self-Shielding calculation
+*----
+TRACK TRACK_FIL := EXCELT: ASSMB2 ::
+ EDIT 0 MAXR 200 TITLE 'TCWW43 : SELF-SHIELDING'
+ TRAK TISO 6 10.0 ;
+LIBRARY := SHI: LIBRARY TRACK TRACK_FIL :: NOLJ ;
+*----
+* MCCG 2D calculation
+*----
+* Initialisation of the mutigroup flux calculation by a CDD calculation
+TEMP := TRACK ;
+TRACK := MCCGT: TRACK TRACK_FIL ASSMB2 ::
+ EDIT 1 DGAU 2
+ DIFC TMT EPSI 1E-8
+ MAXI 100 KRYL 0 SCR 0 HDD 0.0 ;
+SYS := ASM: LIBRARY TRACK TRACK_FIL ::
+ EDIT 2 ARM ;
+FLX := FLU: LIBRARY SYS TRACK TRACK_FIL ::
+ EDIT 2 TYPE K THER 5 5E-5 EXTE 10 1E-5 ;
+assertS FLX :: 'K-EFFECTIVE' 1 1.257893 ;
+TRACK := DELETE: TRACK ;
+TRACK := TEMP ;
+* Multigroup Flux Calculation
+* Edition
+TRACK := MCCGT: TRACK TRACK_FIL ASSMB2 ::
+ EDIT 1 DGAU 2
+ AAC 10 TMT EPSI 1E-5 STIS 1
+ MAXI 1 KRYL 0 SCR 0 HDD 0.0 ;
+FLX := FLU: FLX LIBRARY SYS TRACK TRACK_FIL ::
+ EDIT 2 TYPE K THER 5 5E-5 EXTE 100 1E-5 ;
+assertS FLX :: 'K-EFFECTIVE' 1 1.258035 ;
+GREP: FLX :: GETVAL 'K-EFFECTIVE' 1 1 1 >>k2D<< ;
+EDITION := EDI: FLX LIBRARY TRACK ASSMB2 ::
+EDIT 2 COND 4.0
+MERGE MIX 1 2 3 4 5 6 7 8 ;
+TRACK TRACK_FIL ASSMB2 SYS FLX EDITION TEMP
+ := DELETE:
+TRACK TRACK_FIL ASSMB2 SYS FLX EDITION TEMP ;
+*----
+* MCCG 3D PRIZ calculation
+*----
+TRACK TRACK_FIL := EXCELT: ASSMB ::
+ EDIT 0 MAXR 200 TITLE 'TCWW43 : PRIZ'
+ PRIZ 5.0 GAUS 2 TRAK TISO 6 10.0 ;
+* Initialisation of the mutigroup flux calculation by a CDD calculation
+TEMP := TRACK ;
+TRACK := MCCGT: TRACK TRACK_FIL ASSMB ::
+ EDIT 1
+ DIFC TMT EPSI 1E-8
+ MAXI 100 KRYL 0 SCR 0 HDD 0.0 ;
+SYS := ASM: LIBRARY TRACK TRACK_FIL ::
+ EDIT 2 ARM ;
+FLX := FLU: LIBRARY SYS TRACK TRACK_FIL ::
+ EDIT 2 TYPE K THER 5 5E-5 EXTE 10 1E-5 ;
+assertS FLX :: 'K-EFFECTIVE' 1 1.258423 ;
+TRACK := DELETE: TRACK ;
+TRACK := TEMP ;
+* Multigroup Flux Calculation
+* Edition
+TRACK := MCCGT: TRACK TRACK_FIL ASSMB ::
+ EDIT 1
+ AAC 10 TMT EPSI 1E-5 STIS 1
+ MAXI 1 KRYL 0 SCR 0 HDD 0.0 ;
+FLX := FLU: FLX
+ LIBRARY SYS TRACK TRACK_FIL ::
+ EDIT 2 TYPE K THER 5 5E-5 EXTE 100 1E-5 ;
+assertS FLX :: 'K-EFFECTIVE' 1 1.257924 ;
+GREP: FLX :: GETVAL 'K-EFFECTIVE' 1 1 1 >>kpriz<< ;
+EDITION := EDI: FLX LIBRARY TRACK ASSMB ::
+EDIT 2 COND 4.0
+MERGE MIX 1 2 3 4 5 6 7 8 ;
+ECHO "**********************" ;
+ECHO "2D " k2D ;
+ECHO "3D PRIZ" kpriz ;
+ECHO "**********************" ;
+*---
+* Memory Release
+*---
+LIBRARY TRACK TRACK_FIL ASSMB SYS FLX EDITION TEMP
+ := DELETE:
+LIBRARY TRACK TRACK_FIL ASSMB SYS FLX EDITION TEMP ;
+ECHO "test TCWW43 completed" ;
+END: ;
+QUIT "LIST" .
generated by cgit v1.2.3 (git 2.46.0) at 2026-02-16 17:23:41 +0000