Initial commit from Polytechnique Montreal

4 files changed, 534 insertions, 0 deletions

diff --git a/Dragon/data/testVVER7_proc/vverBU.c2m b/Dragon/data/testVVER7_proc/vverBU.c2m
new file mode 100644
index 0000000..b5dd7c3
--- /dev/null
+++ b/Dragon/data/testVVER7_proc/vverBU.c2m
@@ -0,0 +1,209 @@
+*******************************************************************************************************
+*                                                                                                     *
+* Procedure :  vverBU.c2m                                                                             *
+* Purpose   :  BU iteration calculus                                                                  *
+* Author    :  L.Fede                                                                                 *
+*                                                                                                     *
+* CALL      :                                                                                         *
+* COMPO  := vverBU LIBRARY TRACK TF_EXC TRACK_SS TF_EXC_SS StepList :: <<Multicompo>> <<name_geom>>   *
+*             <<name_compo>> <<ss>>                                                                   * 
+*                                                                                                     *
+*******************************************************************************************************
+
+* ---
+* INPUT & OUTPUT PARAMETERS
+* ---
+PARAMETER COMPO LIBRARY TRACK TF_EXC TRACK_SS TF_EXC_SS StepList ::
+::: LINKED_LIST COMPO ;
+::: LINKED_LIST LIBRARY ; 
+::: LINKED_LIST TRACK ;
+::: SEQ_BINARY TF_EXC ;
+::: LINKED_LIST TRACK_SS ;
+::: SEQ_BINARY TF_EXC_SS ;
+::: LINKED_LIST StepList ; ;
+INTEGER Multicompo ;
+:: >>Multicompo<< ;
+STRING name_geom name_compo ss ;
+:: >>name_geom<< >>name_compo<< >>ss<< ;
+
+* ---
+* STRUCTURES AND MODULES
+* ---
+MODULE  MAC: DELETE: UTL: AUTO: USS: ASM: FLU: EVO: GREP: EXCELT: PSP:
+        COMPO: EDI: END: ABORT: ;
+LINKED_LIST SYS FLUX BURNUP FIG EDIBU LIBRARY2 ;
+SEQ_ASCII _COMPO :: FILE <<name_compo>> ;
+
+************************************************************************
+*  REFERENCE LOCAL PARAMETERS                                          *
+************************************************************************
+SEQ_ASCII TDT_VVER :: FILE './testVVER_1level_g2s.txt' ;
+SEQ_ASCII FIG_VVER :: FILE './FIG_VVER_1level.ps' ;
+STRING Library := "DLIB_J3p1p1" ;
+REAL Kinf ;
+ECHO "vverBU: Multicompo=" Multicompo ;
+ 
+************************************************************************
+*  BEGIN DECLARATION                                                   *
+************************************************************************
+INTEGER nstep nauto maxcompo ;
+GREP: StepList :: LENGTH ListBU >>nstep<< ;
+GREP: StepList :: LENGTH ListAutop >>nauto<< ;
+GREP: StepList :: LENGTH ListCompo >>maxcompo<< ;
+ECHO "nstep=" nstep "nauto=" nauto "maxcompo=" maxcompo "ss=" ss ;
+************************************************************************
+*  END DECLARATION                                                     *
+************************************************************************
+************************************************************************
+*  BEGIN COMPO INITIALIZATION                                          *
+************************************************************************
+COMPO := COMPO: ::
+    EDIT 10
+    STEP UP 'EDIBU'
+    MAXCAL 5
+    COMM 'Evolution burnup pincell' ENDC
+    PARA 'Burnup' IRRA
+    ISOT 11 U235 U236 U238 Pu239 Pu240 Pu241 Pu242 Gd155 Gd157 Xe135 Sm149
+            
+    INIT
+;
+************************************************************************
+*  END COMPO INITIALIZATION                                            *
+************************************************************************
+
+************************************************************************
+*  NOMINAL REFERENCE CALCULATION                                       *
+************************************************************************
+INTEGER istepNext ;
+REAL BUbeg Tbeg ;
+REAL BU BUautop BUcompo := 0.0 0.0 0.0 ;
+REAL Norm_f2 := 36.8577 ; ! SPECIFIC POWER MW/t
+REAL BUend Tend := 0. 0. ;
+INTEGER istep :=  0 ;
+INTEGER iauto :=  1 ;
+INTEGER iCompo :=  1 ;
+ECHO "start burnup loop" ;
+WHILE istep nstep < DO
+
+ EVALUATE istep := istep 1 + ;
+ ECHO "burnup step: " istep "/" nstep ;
+ 
+ EVALUATE BUbeg Tbeg := BUend Tend ;
+ GREP: StepList :: GETVAL 'ListBU' <<istep>> >>BUend<< ;
+ EVALUATE Tend := BUend Norm_f2 / ;
+ ECHO "Nominal depletion between" Tbeg " and" Tend "days" ;
+
+*----
+* AUTO
+*----
+  IF istep 1 = THEN
+     ECHO ".perform self-shielding at" Tbeg "days" ;
+     IF ss 'auto' = THEN
+       LIBRARY2 := AUTO: LIBRARY TRACK_SS TF_EXC_SS :: EDIT 1 PASS 1 MAXT 60000 SEED 1111
+         CALC REGI W1 U235 ALL
+         ENDC ;
+     ELSEIF ss 'uss' = THEN
+       LIBRARY2 := USS: LIBRARY TRACK_SS TF_EXC_SS :: EDIT 1 PASS 3
+         CALC REGI W1 U235 ALL
+         ENDC ;
+     ELSE
+       ECHO "vverBU: self shielding" ss "not available" ;
+       ABORT: ;
+     ENDIF ;
+  ELSE
+     GREP: StepList :: GETVAL "ListAutop" <<iauto>> >>BUautop<< ;
+     GREP: StepList :: GETVAL "ListBU" <<istep>> >>BU<< ;
+     IF BUautop BU = THEN
+       ECHO "perform self-shielding at" Tbeg "days" ;
+     IF ss 'auto' = THEN
+       LIBRARY2 := AUTO: LIBRARY LIBRARY2 TRACK_SS TF_EXC_SS :: EDIT 1
+         CALC REGI W1 U235 ALL
+         ENDC ;
+     ELSEIF ss 'uss' = THEN
+       LIBRARY2 := USS: LIBRARY LIBRARY2 TRACK_SS TF_EXC_SS :: EDIT 1
+        CALC REGI W1 U235 ALL
+        ENDC ;
+     ELSE
+       ECHO "vverBU: self shielding" ss "not available" ;
+       ABORT: ;
+     ENDIF ;
+       EVALUATE iauto := iauto 1 + ;
+     ENDIF ;
+  ENDIF ;
+
+************************************************************************
+*  BEGIN MOC FLUX CALCULATION                                          *
+************************************************************************
+  SYS := ASM: LIBRARY2 TRACK TF_EXC :: ARM EDIT 1 ;    
+
+  IF istep 1 = THEN     
+     FLUX := FLU: LIBRARY2 SYS TRACK TF_EXC :: 
+     EDIT 1 TYPE K B1 SIGS ;
+  ELSE
+     FLUX := FLU: FLUX LIBRARY2 SYS TRACK TF_EXC :: 
+     EDIT 1 TYPE K B1 SIGS ;
+  ENDIF ;
+ 
+  SYS := DELETE: SYS ;
+
+  IF istep 1 = THEN
+    BURNUP LIBRARY2 := EVO: LIBRARY2 FLUX TRACK ::
+      EDIT 0
+      SAVE <<Tbeg>> DAY POWR <<Norm_f2>>
+    ;
+  ELSE
+    BURNUP LIBRARY2 := EVO: BURNUP LIBRARY2 FLUX TRACK ::
+      EDIT 0
+      SAVE <<Tbeg>> DAY POWR <<Norm_f2>>
+    ;
+  ENDIF ;
+
+  GREP: StepList :: GETVAL "ListCompo" <<iCompo>> >>BUcompo<< ;
+  GREP: StepList :: GETVAL "ListBU" <<istep>> >>BU<< ;
+ 
+    IF BUcompo BU = THEN
+      EDIBU := EDI: FLUX LIBRARY2 TRACK ::
+        EDIT 5
+        MICR 11 U235 U236 U238 Pu239 Pu240 Pu241 Pu242 Gd155 Gd157 Xe135 Sm149
+        MERG MIX 0 0 0 0 0 0 0 0 0 0 1 1 1 1 1 1
+        COND
+        SAVE ON FUEL ;
+      COMPO := COMPO: COMPO EDIBU BURNUP LIBRARY ::
+        EDIT 2
+        STEP UP 'EDIBU'
+        SET <<Tbeg>> DAY ;
+    
+      EDIBU := DELETE: EDIBU ;
+      EVALUATE iCompo := iCompo 1 + ;
+    ENDIF ;
+
+  GREP: FLUX :: GETVAL 'K-INFINITY  ' 1 1 1 >>Kinf<< ;
+  ECHO "+++ Burnup=" BUend " Kinf=" Kinf " at step" istep ;
+
+  IF istep nstep < THEN
+    EVALUATE istepNext := istep 1 + ;
+    GREP: StepList :: GETVAL 'ListBU' <<istepNext>> >>BUend<< ;
+    EVALUATE Tend := BUend Norm_f2 / ;
+  
+    BURNUP LIBRARY2 := EVO: BURNUP LIBRARY2 FLUX TRACK ::
+     EDIT 3 DEPL <<Tbeg>> <<Tend>> DAY POWR <<Norm_f2>> 
+     EXPM 1.0E15 GLOB ;
+  
+  ENDIF ;
+ 
+************************************************************************
+*  END FLUX CALCULATION                                                *
+************************************************************************
+
+ENDWHILE ;
+************************************************************************
+*  END OF REFERENCE BURNUP LOOP WITH DEPLETION                         *
+************************************************************************
+
+************************************************************************
+*  EXPORT MULTICOMPO IN ASCII FORMAT                                   *
+************************************************************************
+_COMPO := COMPO ;
+
+END: ;
+QUIT .
diff --git a/Dragon/data/testVVER7_proc/vverGEO.c2m b/Dragon/data/testVVER7_proc/vverGEO.c2m
new file mode 100644
index 0000000..dd47d4a
--- /dev/null
+++ b/Dragon/data/testVVER7_proc/vverGEO.c2m
@@ -0,0 +1,90 @@
+****************************************************************
+*                                                              *
+* Procedure :  vverGEO.c2m                                     *
+* Purpose   :  Geometry creation                               *
+* Author    :  L.Fede                                          *
+*                                                              *
+* CALL      :                                                  *
+* GEOM GEOM_SS := vverGEO :: <<name_geom>>                     *
+*                                                              *
+****************************************************************
+
+* --------------------------------
+*    INPUT & OUTPUT PARAMETERS
+* --------------------------------
+PARAMETER GEOM GEOM_SS ::
+::: LINKED_LIST GEOM ; 
+::: LINKED_LIST GEOM_SS ; ;
+
+STRING name_geom ;
+:: >>name_geom<< ;
+
+* -------------------------------
+*    STRUCTURES AND MODULES
+* -------------------------------
+MODULE  GEO: END: ABORT: ;
+REAL PITCH RCOMB1 RCOMB2 RCOMB3 RCOMB4 RCOMB5 RCOMB6 RCOMB7 RCOMB8 RCOMB9 RCOMB10 RCOMB11 CLAD ; 
+REAL RMOD1  RMOD2 RMOD3  :=
+     0.5235 0.592 0.6605 ;
+INTEGER COMB0101 COMB0102 COMB0103 COMB0104 COMB0105 COMB0106 COMB0107 COMB0108 COMB0109
+ COMB0110 COMB0111 GAP7 CLAD8 MODE9 ;
+
+* --------------------------------
+*       GEOMETRY DEFINITION
+* -------------------------------
+ECHO "vverGEO: process geometry=" name_geom ;
+
+* ---
+* KHMELNITSKY-2 REACTOR - 439 GT ASSEMBLY - 3.6% UOx CELL + Gd2O3
+* ---
+IF name_geom 'KML2_439GT_36Gd' = THEN
+
+ EVALUATE COMB0101 COMB0102 COMB0103 COMB0104 COMB0105 COMB0106 GAP7 CLAD8 MODE9 :=
+          11 12 13 14 15 16 7 8 9 ; ! DISTRIBUTED SELF-SHIELDING 
+
+ GEOM := GEO: :: HEXCEL 12
+      HBC COMPLETE TRAN
+      RADIUS 0.0 0.075 0.169270 0.239384 0.293185 0.338541 0.368916 0.3785 0.3865 0.455 <<RMOD1>> <<RMOD2>> <<RMOD3>>
+      SIDE 0.7361215932
+      MIX
+      <<GAP7>>
+      <<COMB0101>>
+      <<COMB0102>>
+      <<COMB0103>>
+      <<COMB0104>>
+      <<COMB0105>>
+      <<COMB0106>>
+      <<GAP7>>
+      <<CLAD8>>
+      <<MODE9>>
+      <<MODE9>>
+      <<MODE9>>
+      <<MODE9>>
+      ;
+
+ GEOM_SS := GEO: :: HEXCEL 9
+      HBC COMPLETE ALBE 1.0
+      RADIUS 0.0 0.075 0.169270 0.239384 0.293185 0.338541 0.368916 0.3785 0.3865 0.455
+      SIDE 0.7361215932
+      MIX
+      <<GAP7>>
+      <<COMB0101>>
+      <<COMB0102>>
+      <<COMB0103>>
+      <<COMB0104>>
+      <<COMB0105>>
+      <<COMB0106>>
+      <<GAP7>>
+      <<CLAD8>>
+      <<MODE9>>
+      ;
+
+ELSE
+
+  ECHO "vverGEO: geometry" name_geom "not available" ;
+  ABORT: ;
+
+ENDIF ;
+
+END: ;
+QUIT .
diff --git a/Dragon/data/testVVER7_proc/vverMIX.c2m b/Dragon/data/testVVER7_proc/vverMIX.c2m
new file mode 100644
index 0000000..926898d
--- /dev/null
+++ b/Dragon/data/testVVER7_proc/vverMIX.c2m
@@ -0,0 +1,162 @@
+****************************************************************
+*                                                              *
+* Procedure :  vverMIX.c2m                                     *
+* Purpose   :  Mixture creation                                *
+* Author    :  L.Fede                                          *
+*                                                              *
+* CALL      :                                                  *
+* LIBRARY := vverMIX :: <<Library>> <<name_geom>> <<ss>>       *
+*                                                              *
+****************************************************************
+
+* -----------------------------------
+*     INPUT & OUTPUT PARAMETERS
+* -----------------------------------
+PARAMETER LIBRARY ::
+::: LINKED_LIST LIBRARY ; ;
+
+STRING Library name_geom ss ;
+:: >>Library<< >>name_geom<< >>ss<< ;
+
+* ----------------------------------
+*      STRUCTURES AND MODULES
+* ----------------------------------
+MODULE  LIB: END: ABORT: ;
+
+INTEGER COMB0101 COMB0102 COMB0103 COMB0104 COMB0105 COMB0106 COMB0107 COMB0108 COMB0109 COMB0110 COMB0111 GAP7 CLAD8
+ MODE9 ;
+
+REAL N_Zr90 N_Zr91 N_Zr92 N_Zr94 N_Zr96 ;
+REAL NNb93 N_Hf174 N_Hf176 N_Hf177 N_Hf178 N_Hf179 N_Hf180 ;
+
+* ----------------------------------
+*               MIX
+* ----------------------------------
+
+* ---
+* KHMELNITSKY-2 REACTOR - 439 GT ASSEMBLY - 3.6% UOx CELL + 5.0% Gd2O3
+* ---
+
+  EVALUATE N_Zr90      N_Zr91      N_Zr92       N_Zr94       N_Zr96     :=
+           2.20052E-2  4.74596E-3  7.17541E-3   7.11667E-3   1.12260E-3 ;
+
+  EVALUATE NNb93      N_Hf174    N_Hf176    N_Hf177    N_Hf178    N_Hf179    N_Hf180    :=
+           4.18189E-4 1.07216E-8 3.48463E-7 1.22523E-6 1.78690E-6 8.87146E-7 2.27225E-6 ;
+
+  EVALUATE COMB0101 COMB0102 COMB0103 COMB0104 COMB0105 COMB0106 GAP7 CLAD8 MODE9 :=
+           11 12 13 14 15 16 7 8 9 ; !  DISTRIBUTED SELF-SHIELDING 
+
+IF name_geom 'KML2_439GT_36Gd' = ss 'auto' = * THEN
+
+  LIBRARY := LIB: ::
+    EDIT 0
+    NMIX 16    ! MAXIMUM OF MATERIAL MIXTURES
+    SUBG
+    ANIS 2
+    ADED 4 NELAS N4N N2N N3N
+
+    DEPL LIB: DRAGON FIL: <<Library>>
+
+    MIXS LIB: DRAGON FIL: <<Library>>
+
+    MIX <<COMB0101>> 900.0
+      O16     = O16    4.59021E-2
+      U235    = U235   2.84175E-3 1
+      U238    = U238   2.09525E-2 1
+      Pu239   = Pu239  0.0        1
+      Pu240   = Pu240  0.0        1
+      Pu241   = Pu241  0.0        1
+      Pu242   = Pu242  0.0        1
+      Gd154   = Gd154  3.78440E-6 1
+      Gd155   = Gd155  2.55262E-5 1
+      Gd156   = Gd156  3.50791E-5 1
+      Gd157   = Gd157  2.66479E-5 1
+      Gd158   = Gd158  4.20283E-5 1
+      Gd160   = Gd160  3.65230E-5 1
+    MIX <<COMB0102>> COMB <<COMB0101>> 1.0
+    MIX <<COMB0103>> COMB <<COMB0101>> 1.0
+    MIX <<COMB0104>> COMB <<COMB0101>> 1.0
+    MIX <<COMB0105>> COMB <<COMB0101>> 1.0
+    MIX <<COMB0106>> COMB <<COMB0101>> 1.0
+    MIX <<CLAD8>> 600.0 NOEV
+      Zr90    = Zr90   <<N_Zr90>> 1
+      Zr91    = Zr91   <<N_Zr91>> 1
+      Zr92    = Zr92   <<N_Zr92>> 1
+      Zr94    = Zr94   <<N_Zr94>> 1
+      Zr96    = Zr96   <<N_Zr96>> 1
+      Nb93    = Nb93   <<NNb93>> 
+      Hf174   = Hf174  <<N_Hf174>>
+      Hf176   = Hf176  <<N_Hf176>>
+      Hf178   = Hf178  <<N_Hf178>>
+      Hf179   = Hf179  <<N_Hf179>>
+      Hf180   = Hf180  <<N_Hf180>>
+    MIX <<MODE9>> 560.0 NOEV
+      H1      = H1_H2O 5.082040E-2
+      O16     = O16    2.548710E-2
+      B10     = B10    1.02048E-5
+      B11     = B11    4.10756E-5
+    MIX <<GAP7>> 560.0 NOEV
+      He4     = He4   1.00E-08
+    ;
+
+ELSEIF name_geom 'KML2_439GT_36Gd' = ss 'uss' = * THEN
+
+  LIBRARY := LIB: ::
+    EDIT 0
+    NMIX 16    ! MAXIMUM OF MATERIAL MIXTURES
+    PT
+    ANIS 2
+    ADED 4 NELAS N4N N2N N3N
+
+    DEPL LIB: DRAGON FIL: <<Library>>
+
+    MIXS LIB: DRAGON FIL: <<Library>>
+
+    MIX <<COMB0101>> 900.0
+      O16     = O16    4.59021E-2
+      U235    = U235   2.84175E-3 1
+      U238    = U238   2.09525E-2 1
+      Pu239   = Pu239  0.0        1
+      Pu240   = Pu240  0.0        1
+      Pu241   = Pu241  0.0        1
+      Pu242   = Pu242  0.0        1
+      Gd154   = Gd154  3.78440E-6 1
+      Gd155   = Gd155  2.55262E-5 1
+      Gd156   = Gd156  3.50791E-5 1
+      Gd157   = Gd157  2.66479E-5 1
+      Gd158   = Gd158  4.20283E-5 1
+      Gd160   = Gd160  3.65230E-5 1
+    MIX <<COMB0102>> COMB <<COMB0101>> 1.0
+    MIX <<COMB0103>> COMB <<COMB0101>> 1.0
+    MIX <<COMB0104>> COMB <<COMB0101>> 1.0
+    MIX <<COMB0105>> COMB <<COMB0101>> 1.0
+    MIX <<COMB0106>> COMB <<COMB0101>> 1.0
+    MIX <<CLAD8>> 600.0 NOEV
+      Zr90    = Zr90   <<N_Zr90>> 2 IRSET PT NONE
+      Zr91    = Zr91   <<N_Zr91>> 2 IRSET PT NONE
+      Zr92    = Zr92   <<N_Zr92>> 2 IRSET PT NONE
+      Zr94    = Zr94   <<N_Zr94>> 2 IRSET PT NONE
+      Zr96    = Zr96   <<N_Zr96>> 2 IRSET PT NONE
+      Nb93    = Nb93   <<NNb93>> 
+      Hf174   = Hf174  <<N_Hf174>>
+      Hf176   = Hf176  <<N_Hf176>>
+      Hf178   = Hf178  <<N_Hf178>>
+      Hf179   = Hf179  <<N_Hf179>>
+      Hf180   = Hf180  <<N_Hf180>>
+    MIX <<MODE9>> 560.0 NOEV
+      H1      = H1_H2O 5.082040E-2
+      O16     = O16    2.548710E-2
+      B10     = B10    1.02048E-5
+      B11     = B11    4.10756E-5
+    MIX <<GAP7>> 560.0 NOEV
+      He4     = He4   1.00E-08
+    ; 
+ELSE
+
+  ECHO "vverMIX: geometry" name_geom "and self-shielding" ss "not available" ;
+  ABORT: ;
+
+ENDIF ;
+
+END: ;
+QUIT .
diff --git a/Dragon/data/testVVER7_proc/vverTRACK.c2m b/Dragon/data/testVVER7_proc/vverTRACK.c2m
new file mode 100644
index 0000000..167d7be
--- /dev/null
+++ b/Dragon/data/testVVER7_proc/vverTRACK.c2m
@@ -0,0 +1,73 @@
+************************************************************************************************************************
+*                                                                                                                      *
+* Procedure :  vverTRACK.c2m                                                                                           *
+* Purpose   :  Tracking and figure                                                                                     *
+* Author    :  L.Fede                                                                                                  *
+*                                                                                                                      *
+* CALL      :                                                                                                          *
+* UOX_TBH FIG1.ps TRACK TF_EXC UOX_TBH_SS FIG_SS.ps TRACK_SS TF_EXC_SS := vverTRACK GEOM GEOM_SS                       *
+*                                                                                                                      *
+************************************************************************************************************************
+
+* ---
+* INPUT & OUTPUT PARAMETERS
+* ---
+PARAMETER UOX_TBH    FIG1.ps   TRACK    TF_EXC
+          UOX_TBH_SS FIG_SS.ps TRACK_SS TF_EXC_SS
+          GEOM       GEOM_SS ::
+::: SEQ_ASCII UOX_TBH ;
+::: SEQ_ASCII FIG1.ps ;
+::: LINKED_LIST TRACK ;
+::: SEQ_BINARY TF_EXC ;
+::: SEQ_ASCII UOX_TBH_SS ;
+::: SEQ_ASCII FIG_SS.ps ;
+::: LINKED_LIST TRACK_SS ;
+::: SEQ_BINARY TF_EXC_SS ;
+::: LINKED_LIST GEOM ;
+::: LINKED_LIST GEOM_SS ; ;
+
+* ---
+* STRUCTURES AND MODULES
+* ---
+MODULE G2S: SALT: MCCGT: PSP: END: ;
+
+SEQ_ASCII _BURN :: FILE './_BURN_rowland.txt' ;
+SEQ_ASCII _LIBR :: FILE './_LIB_rowland.txt' ;
+SEQ_ASCII _EDIT :: FILE './_EDIT_rowland.txt' ;
+
+INTEGER an2d := 18 ;  ! ANGULAR QUADRATURE PARAMETER
+REAL densur := 30.0 ; ! DENSITY OF INTEGRATION LINES CM^-1
+
+INTEGER an2d_SS := 18 ;
+REAL densur_SS := 30.0 ;
+
+INTEGER mcu := 50000 ;
+
+* ---
+* FLUX CALC TRACKING
+* ---
+UOX_TBH FIG1.ps := G2S: GEOM :: DRAWMIX ;
+
+TRACK TF_EXC := SALT: UOX_TBH ::
+  EDIT 3
+  ALLG
+  TSPC <<an2d>> <<densur>> REND
+;
+
+TRACK := MCCGT: TRACK TF_EXC ::
+  CACB 4 AAC 80 TMT EPSI 1E-5 MCU <<mcu>> 
+;
+* ---
+* SELF-SHIELDING TRACKING
+* ---
+UOX_TBH_SS FIG_SS.ps := G2S: GEOM_SS :: DRAWMIX ;
+
+TRACK_SS TF_EXC_SS := SALT: UOX_TBH_SS ::
+  EDIT 3
+  ANIS 2
+  ALLG
+  TISO <<an2d_SS>> <<densur_SS>> REND
+;
+
+END: ;
+QUIT .